C_SlsDocFlfmtMfgOrder

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S

@EndUserText.label: 'Sales Doc Fulfillment: Mfg Order'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'CSOFMFGORD'

define view C_SlsDocFlfmtMfgOrder

as select from I_MfgOrder as MfgOrder

left outer to one join I_MfgOrderItem as MfgOrderItem
on  MfgOrder.ManufacturingOrder = MfgOrderItem.ManufacturingOrder
and MfgOrderItem.ManufacturingOrderItem = '0001'

left outer to one join I_SalesDocumentItem as SalesOrderItem
on MfgOrder.SalesOrder = SalesOrderItem.SalesDocument
and MfgOrder.SalesOrderItem = SalesOrderItem.SalesDocumentItem

 //Extensibility 

  association [0..1] to E_LogisticsOrder  as _Extension on  $projection.ManufacturingOrder = _Extension.OrderID
                                                                                                                         
{
  //Key

  key MfgOrder.ManufacturingOrder,
    
  //Category

  MfgOrder.ManufacturingOrderCategory,
  MfgOrder.ManufacturingOrderType,
 
  //Material

  @Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductStdVH', element: 'Product' }}]
  @ObjectModel.text.element: [ 'MaterialName' ]    
  cast(MfgOrderItem.Material as productnumber preserving type ) as Material, 
  @UI.hidden: true
  MfgOrderItem._Material._Text[1:Language=$session.system_language].MaterialName,
  MfgOrder.ProductionPlant,
  @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
  @DefaultAggregation: #NONE
  MfgOrder.MfgOrderPlannedTotalQty, 
  @ObjectModel.foreignKey.association: '_ProductionUnit'
  @Semantics.unitOfMeasure: true
  MfgOrder.ProductionUnit,
 
  //Sales Order

  MfgOrder.SalesOrder,
  MfgOrder.SalesOrderItem, 
  
  // Quantity Sales Order Item   

  @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
  @DefaultAggregation: #NONE
  SalesOrderItem.OrderQuantity,
  @Semantics.unitOfMeasure: true
  SalesOrderItem.OrderQuantityUnit,
  
  @Semantics.amount.currencyCode: 'TransactionCurrency'
  @DefaultAggregation: #NONE
  SalesOrderItem.NetAmount,
  @Semantics.currencyCode: true
  SalesOrderItem.TransactionCurrency,
 
  //Partner 

  @ObjectModel.text.element:  [ 'ProductionSupervisorName' ]
  MfgOrder.ProductionSupervisor,
  @Semantics.text: true   
  MfgOrder._ProductionSupervisor.ProductionSupervisorName,  
  @ObjectModel.text.element:  [ 'MRPControllerName' ]
  MfgOrder.MRPController,
  @Semantics.text: true   
  MfgOrder._MRPController.MRPControllerName,  
  
  // Dates

  MfgOrder.MfgOrderScheduledStartDate,
  MfgOrder.MfgOrderScheduledEndDate,
  MfgOrder.MfgOrderScheduledReleaseDate,
  
  MfgOrder.MfgOrderActualStartDate,
  case when MfgOrder.MfgOrderActualEndDate = '00000000'
       then MfgOrder.MfgOrderItemActualDeliveryDate
       else MfgOrder.MfgOrderActualEndDate
  end
  as MfgOrderActualEndDate,
  MfgOrder.MfgOrderActualReleaseDate,
  
  MfgOrder.MfgOrderItemActualDeliveryDate, 
  MfgOrder.MfgOrderConfirmedEndDate,
  
  //Criticality

  @UI.hidden: true      
  cast(
  case
      when MfgOrder.MfgOrderActualStartDate = '00000000' 
         and  MfgOrder.MfgOrderScheduledStartDate < $session.system_date then 1
      when MfgOrder.MfgOrderActualStartDate <> '00000000'                then 3
                                                                         else 0 
  end as abap.int1
  )  as MfgOrderActualStartDateCritlty,
  
    @UI.hidden: true      
  cast(
  case
   when MfgOrder.MfgOrderActualReleaseDate = '00000000' 
         and  MfgOrder.MfgOrderScheduledReleaseDate < $session.system_date then 1
   when MfgOrder.MfgOrderActualReleaseDate <> '00000000'                   then 3
                                                                           else 0     
  end as abap.int1
  )  as MfgOrdActualRelDateCriticality,
  
    @UI.hidden: true      
  cast(
  case
    when MfgOrder.MfgOrderActualEndDate = '00000000' 
         and  MfgOrder.MfgOrderScheduledEndDate < $session.system_date then 1
    when MfgOrder.MfgOrderActualEndDate <> '00000000'  and MfgOrder.IsCompletelyDelivered = ' ' then 3
                                                                       else 0     
  end as abap.int1
  )  as MfgOrdActualEndDateCriticality,
   
  //Associations

  MfgOrder._MfgOrderCategory,
  MfgOrder._MfgOrderType,    
  MfgOrder._ProductionUnit,
  MfgOrder._Plant,  
  SalesOrderItem._OrderQuantityUnit,
  SalesOrderItem._TransactionCurrency
       
}