C_SlsContrPartnerForReleaseVH

@VDM.viewType: #CONSUMPTION

@ObjectModel.usageType: {
  dataClass: #CUSTOMIZING,
  serviceQuality: #C,
  sizeCategory: #XL
}

@ObjectModel: {
  dataCategory : #VALUE_HELP,
  representativeKey: 'Customer'
}

@Search.searchable: true

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
  personalData.blocking: #REQUIRED,
  authorizationCheck:#MANDATORY
}

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

@ObjectModel.query.implementedBy:'ABAP:CL_SLS_CONTR_REL_PARTNER_QUERY'
@EndUserText.label: 'Sales Contract Releasing Partner'
define view entity C_SlsContrPartnerForReleaseVH
  as select from           I_Customer                    as Customer
    left outer to one join C_SoldToSalesAreaVH           as CustomerWithRoleSoldToParty on Customer.Customer = CustomerWithRoleSoldToParty.Customer

{
      @UI: {
        lineItem: [{ position: 10, importance: #HIGH }],
        selectionField: [{ position: 10 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.99,
        ranking: #MEDIUM
      }
  key Customer.Customer,

      @UI: {
      lineItem: [{ position:20, importance:#HIGH }],
      selectionField: [{ position: 20 }] }
      @Semantics.text:true
      @Semantics.name.fullName: true
      @EndUserText.label : 'Name'
      Customer.CustomerName,
      
      @UI.hidden: true
      @Search: {
       defaultSearchElement: true,
       ranking: #MEDIUM,
       fuzzinessThreshold: 0.99 }
      Customer.OrganizationBPName1,

      @UI.hidden: true
      @Search: {
       defaultSearchElement: true,
       ranking: #MEDIUM,
       fuzzinessThreshold: 0.99 }
      Customer.OrganizationBPName2,

      @UI: {
      lineItem: [{ position: 30, importance: #LOW }],
      selectionField: [{ position: 30 }]}
      @Semantics.address.zipCode:true
      @EndUserText.label : 'Postal Code'
      Customer._AddressDefaultRepresentation.PostalCode,

      @UI: {
      lineItem: [{ position: 40, importance: #LOW }],
      selectionField: [{ position: 40 }]}
      @Semantics.address.city:true
      Customer._AddressDefaultRepresentation.CityName,

      @UI: {
      lineItem: [{ position: 50, importance: #LOW }],
      selectionField: [{ position: 50 }]}
      @UI.textArrangement: #TEXT_FIRST
      @Semantics.address.country:true
      @ObjectModel.text.element     : ['CountryName']
      Customer._AddressDefaultRepresentation.Country,  


      @UI.hidden: true
      @Semantics.text:true
      Customer._AddressDefaultRepresentation._Country._Text[1:Language=$session.system_language].CountryName as CountryName,


      @UI: {
      lineItem: [{ position: 70, importance: #LOW }],
      selectionField: [{ position: 60 }]}
      @Semantics.address.street:true
      Customer._AddressDefaultRepresentation.StreetName,

      @UI: {
        lineItem: [{ position: 80, importance: #HIGH, hidden: true }],
        selectionField: [{ position: 70 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.99,
        ranking: #HIGH
      }
      @EndUserText.label : 'Sales Contract'
      cast( '          ' as vbeln preserving type ) as SalesContract,
      
      // DCL relevant fields

      @Consumption.hidden: true
      Customer.CustomerAccountGroup,
      @Consumption.hidden: true
      Customer.AuthorizationGroup,
      @Semantics.booleanIndicator
      @Consumption.hidden: true
      Customer.IsBusinessPurposeCompleted,
      //Added for DPP Data Controller

      @Consumption.hidden:true
      Customer.DataControllerSet,
      @Consumption.hidden:true
      Customer.DataController1,
      @Consumption.hidden:true
      Customer.DataController2,
      @Consumption.hidden:true
      Customer.DataController3,
      @Consumption.hidden:true
      Customer.DataController4,
      @Consumption.hidden:true
      Customer.DataController5,
      @Consumption.hidden:true
      Customer.DataController6,
      @Consumption.hidden:true
      Customer.DataController7,
      @Consumption.hidden:true
      Customer.DataController8,
      @Consumption.hidden:true
      Customer.DataController9,
      @Consumption.hidden:true
      Customer.DataController10

}
where
  CustomerWithRoleSoldToParty.Customer is not null