C_ShrtTrmCshPosActualFlow

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Overdue Actual Flows'
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}

@UI.presentationVariant: [{requestAtLeast: ['AmountInTransactionCurrency','TransactionCurrency','BankAccountCurrency']}]

@UI.headerInfo: {
  typeName: 'Cash Flow',
  typeNamePlural: 'Cash Flows',
  title: {  type: #STANDARD, value: 'TransactionDate' }
}

@VDM.viewType: #CONSUMPTION
define view entity C_ShrtTrmCshPosActualFlow
  as select from I_CashPositionFlow    as flow
    cross join   I_CashPositionProfile as profile
    cross join   I_Currency            as Currency
    cross join   I_CalendarDate        as KeyDate
    cross join   I_CalendarDate        as CashBalanceDate
    cross join   I_CashSnapshot        as Snapshot
  association [0..*] to I_CshPosCurrencySourceText as _CshPosCurSoucText on $projection.CashPositionCurrencySource = _CshPosCurSoucText.CashPositionCurrencySource
{
      @UI.facet: [{
                    id: 'GenInfoSec',
                    type: #COLLECTION,
                    purpose: #STANDARD,
                    position: 10,
                    label: 'General Information'
                                             },
                    //General Info field group

                    {
                    id: 'GenInfo',
                    parentId: 'GenInfoSec',
                    type: #FIELDGROUP_REFERENCE,
                    position: 10,
                    targetQualifier: 'GenInfo',
                    label: 'General Information'

                                             }]
      @UI.hidden: true
  key profile.CashPositionProfile,
      @EndUserText:{label: 'Display Currency'}
      @UI.hidden: true
  key Currency.Currency                                                        as CashPositionDisplayCurrency,
  key flow.OriginSystem,
      @UI.fieldGroup: [{position: 20, qualifier: 'GenInfo' }]
      /* start suppress warning shlporigin_not_inherited */
  key flow.OriginApplication,
      @UI.fieldGroup: [{position: 30, qualifier: 'GenInfo' }]
      @UI.lineItem: [{position: 10, importance: #HIGH }]
  key flow.OriginDocument,
  key flow.OriginTransaction,
  key flow.OriginTransactionQualifier,
  key flow.CashFlow,
      @UI.hidden: true
  key CashBalanceDate.CalendarDate                                             as CashBalanceDate,
      @UI.hidden: true
  key KeyDate.CalendarDate                                                     as KeyDate,
      @UI.hidden: true
  key Snapshot.CashSnapshot,
      //  key KeyDate.CalendarDate                                                     as KeyDate,

      //  key CashBalanceDate.CalendarDate                                             as CashBalanceDate,

      @UI.hidden: true
      @UI.lineItem: [{position: 20, importance: #HIGH}]
      @UI.fieldGroup: [{position: 10, qualifier: 'GenInfo' }]
      flow.TransactionDate,

      flow.BankAccountInternalID,

      @Consumption.semanticObject: 'CompanyCode'
      @ObjectModel.text.element: [ 'CompanyCodeName' ]
      @UI.textArrangement: #TEXT_LAST
      flow.CompanyCode,

      @UI.lineItem: [{position:30, importance: #HIGH }]
      @Semantics.amount.currencyCode: 'BankAccountCurrency'
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FCLM_STCP_CALCULATE_AMOUNT'
      @UI.fieldGroup: [{position: 40, qualifier: 'GenInfo' }]
      cast(cast(0 as abap.curr(23,2)) as fclm_amount_bnkcrcy preserving type ) as AmountInBankAccountCurrency,
      @EndUserText:{label: 'Bank Account Currency'}
      @UI.hidden: true
      flow._BankAccount.BankAccountCurrency,

      @UI.lineItem: [{position: 40, importance: #HIGH }]
      @Semantics.amount.currencyCode: 'CashPositionDisplayCurrency'
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FCLM_STCP_CALCULATE_AMOUNT'
      @EndUserText:{label: 'Amount in Target Currency', quickInfo: 'Amount in Target Currency'}
      @UI.fieldGroup: [{position: 50, qualifier: 'GenInfo' }]
      cast(cast(0 as abap.curr(23,2)) as fqm_amount preserving type )          as AmountInDisplayCurrency,

      @UI.hidden                   : true
      profile. CashPositionCurrencySource,

      @UI.lineItem: [{position: 70, importance: #HIGH}]
      @UI.fieldGroup: [{position: 80, qualifier: 'GenInfo' }]
      @EndUserText:{label: 'Cash Position Currency Source', quickInfo: 'Cash Position Currency Source'}
      _CshPosCurSoucText[1:Language = $session.system_language].CashPositionCurrencySourceText,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FCLM_STCP_CALCULATE_AMOUNT'
      @UI.fieldGroup: [{position: 60, qualifier: 'GenInfo' }]
      @EndUserText:{label: 'Amount in Transaction Currency', quickInfo: 'Amount in Transaction Currency'}
      flow.AmountInTransactionCurrency                                         as CshPosScaledAmountInTransCrcy,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @UI.hidden: true
      flow.AmountInTransactionCurrency,
      @EndUserText:{label: 'Transaction Currency'}
      @UI.hidden: true
      flow.TransactionCurrency,
      /* end suppress warning shlporigin_not_inherited */
      @Semantics.text: true
      flow._CompanyCode.CompanyCodeName,

      @UI.hidden: true
      cast('' as fclm_balance_clav_source)                                     as CashClosingAvailBalanceSource


}
where
      flow.ValidFrom               <= Snapshot.CreationDateTime
  and flow.ValidTo                 >= Snapshot.CreationDateTime
  and flow.CertaintyLevel          =  'ACTUAL'
  and flow.CashTransactionOwner    <> 'IBU'
  and flow.CashTransactionOwner    <> 'AGG'
  and KeyDate.CalendarDate         >  flow.TransactionDate
  and CashBalanceDate.CalendarDate <  flow.TransactionDate

union all select from I_CashPositionFlow    as flow
  cross join          I_CashPositionProfile as profile
  cross join          I_Currency            as Currency
  cross join          I_CalendarDate        as KeyDate
  cross join          I_CalendarDate        as CashBalanceDate
association [0..*] to I_CshPosCurrencySourceText as _CshPosCurSoucText on $projection.CashPositionCurrencySource = _CshPosCurSoucText.CashPositionCurrencySource
{
  key profile.CashPositionProfile,
  key Currency.Currency                                                        as CashPositionDisplayCurrency,
  key flow.OriginSystem,
      /* start suppress warning shlporigin_not_inherited */
  key flow.OriginApplication,
  key flow.OriginDocument,
  key flow.OriginTransaction,
  key flow.OriginTransactionQualifier,
  key flow.CashFlow,
  key CashBalanceDate.CalendarDate                                             as CashBalanceDate,
  key KeyDate.CalendarDate                                                     as KeyDate,
  key cast('0000000000' as fclm_snapshot_id)                                   as CashSnapshot,
      //  key KeyDate.CalendarDate                                                     as KeyDate,

      //  key CashBalanceDate.CalendarDate                                             as CashBalanceDate,

      flow.TransactionDate,

      flow.BankAccountInternalID,


      flow.CompanyCode,


      cast(cast(0 as abap.curr(23,2)) as fclm_amount_bnkcrcy preserving type ) as AmountInBankAccountCurrency,

      flow._BankAccount.BankAccountCurrency,

      cast(cast(0 as abap.curr(23,2)) as fqm_amount preserving type )          as AmountInDisplayCurrency,

      profile. CashPositionCurrencySource,


      _CshPosCurSoucText[1:Language = $session.system_language].CashPositionCurrencySourceText,

      flow.AmountInTransactionCurrency                                         as CshPosScaledAmountInTransCrcy,
      flow.AmountInTransactionCurrency,
      flow.TransactionCurrency,
      /* end suppress warning shlporigin_not_inherited */
      flow._CompanyCode.CompanyCodeName,

      cast('' as fclm_balance_clav_source)                                     as CashClosingAvailBalanceSource


}
where
      flow.ValidFrom               <= tstmp_current_utctimestamp( )
  and flow.ValidTo                 >= tstmp_current_utctimestamp( )
  and flow.CertaintyLevel          =  'ACTUAL'
  and flow.CashTransactionOwner    <> 'IBU'
  and flow.CashTransactionOwner    <> 'AGG'
  and KeyDate.CalendarDate         >  flow.TransactionDate
  and CashBalanceDate.CalendarDate <  flow.TransactionDate;