C_ShipToPartyValueHelp

@ClientHandling.algorithm:#SESSION_VARIABLE
@AbapCatalog: {
  preserveKey: true,
  sqlViewName: 'CSHIPPTYVH',
  compiler.compareFilter: true
}
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
//@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@EndUserText.label: 'Ship to Party'
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@Consumption.ranked: true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
@ObjectModel.dataCategory:#VALUE_HELP
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@ObjectModel.representativeKey: 'Customer'

define view C_ShipToPartyValueHelp
  as select from I_Customer as Customer
{

      @UI.lineItem: [{position:10, importance:#HIGH}]
      @UI.selectionField: [{ position: 10 }]
      @EndUserText.label : 'Customer'
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH }
      @Search.fuzzinessThreshold: 0.9
      @ObjectModel.text.element:  [ 'CustomerName' ]
  key Customer.Customer,
      @UI.hidden: true
  key Customer.AddressID,
  
      @UI.lineItem: [{position:20, importance:#HIGH}]
      @UI.selectionField: [{ position: 20 }]
      @EndUserText.label : 'Name'
      @Semantics.text:true
      @Semantics.name.fullName: true
      Customer._AddressRepresentation.AddresseeFullName as CustomerName,
      
//      @UI.hidden: true

//      Customer._AddressRepresentation.OrganizationName1 as BusinessPartnerName1,

//      @UI.hidden: true

//      Customer._AddressRepresentation.OrganizationName2 as BusinessPartnerName2,


      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      Customer._AddressRepresentation.StreetName as StreetName,

      @UI.lineItem: [{position:30, importance:#LOW}]
      @UI.selectionField: [{ position: 30 }]
      @Semantics.address.zipCode:true
      @Search: {
        defaultSearchElement: true,       
        ranking: #LOW,
        fuzzinessThreshold: 0.9
      }
      Customer._AddressRepresentation.PostalCode as PostalCode,

      @UI.lineItem: [{position:40, importance:#LOW}]
      @UI.selectionField: [{ position: 40 }]
      @Semantics.address.city:true
      @Search: {
        defaultSearchElement: true,       
        ranking: #LOW,
        fuzzinessThreshold: 0.9
      }
      Customer._AddressRepresentation.CityName as CityName,

      @UI.lineItem: [{position:50, importance:#LOW}]
      @UI.selectionField: [{ position: 50 }]
      @Semantics.address.country:true
      @Search: {
        defaultSearchElement: true,       
        ranking: #LOW,
        fuzzinessThreshold: 0.9
      }
      Customer._AddressRepresentation.Country as Country,

      //For access control

      @Consumption.hidden: true
      @UI.hidden: true
      Customer.AuthorizationGroup,
      @Consumption.hidden: true
      @UI.hidden: true
      Customer.CustomerAccountGroup,
      @Consumption.hidden: true
      @UI.hidden: true
      Customer.IsBusinessPurposeCompleted,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      Customer.DataController10
}