C_ServiceCostRateDEX

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@EndUserText.label: 'Service Cost Rate'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #D,
        dataClass: #MIXED
    }
    ,supportedCapabilities: [#EXTRACTION_DATA_SOURCE]
    ,modelingPattern: #ANALYTICAL_FACT
    ,sapObjectNodeType.name: 'AccountingCostRate'
}

@VDM.viewType: #CONSUMPTION

@Analytics:{
    dataCategory: #FACT,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
          mapping: [
            {
            role: #MAIN,
            table: 'ACCOSTRATE',
            tableElement: [ 'RATEUUID' ],
            viewElement: [ 'AccountingCostRateUUID' ]
            },
            {
            role: #LEFT_OUTER_TO_ONE_JOIN,
            table: 'PRPS',
            tableElement: [ 'PSPNR' ],
            viewElement: [ 'WBSElementInternalID' ]
            },
            {
            role: #LEFT_OUTER_TO_ONE_JOIN,
            table: 'CSSL',
            tableElement: [ 'KOKRS', 'KOSTL','LSTAR','GJAHR' ],
            viewElement: [ 'ControllingArea','CostCenter','ActivityType','ValidityStartFiscalYear' ]
            }
          ]
        }
    }
}

@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'CRT',
  dataSources: ['_Rate'],
  quota: {
    maximumFields: 340,
    maximumBytes: 10000
  }
}

define view entity C_ServiceCostRateDEX
  as select from I_ServiceCostRate_2 as _Rate
  association [1..1] to E_AccountingCostRate as _Extension on $projection.AccountingCostRateUUID = _Extension.AccountingCostRateUUID
{
  key AccountingCostRateUUID,
      _Rate.Ledger,
      CurrencyRole,
      CompanyCode,
      ControllingArea,
      CostCenter,
      ActivityType,
      IsIntercompanyRate,
      ReceivingCompanyCode,
      ServiceCostLevel,
      PersonnelNumber,
      WBSElementInternalID,
      WBSElementExternalID,
      WorkItem,
      TimeSheetOvertimeCategory,
      @Semantics.fiscal.year: true
      ValidityStartFiscalYear,
      @Semantics.fiscal.period: true
      ValidityStartFiscalPeriod,
      @Semantics.fiscal.yearPeriod: true
      ValidityStartFiscalYearPeriod,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      @Semantics.fiscal.year: true
      ValidityEndFiscalYear,
      @Semantics.fiscal.period: true
      ValidityEndFiscalPeriod,
      @Semantics.fiscal.yearPeriod: true
      ValidityEndFiscalYearPeriod,
      @Semantics.businessDate.to: true
      ValidityEndDate,
      CostCtrActivityTypeQtyUnit,
      Currency,
      @Semantics.amount.currencyCode: 'Currency'
      CostRateVarblAmount,
      CostRateScaleFactor
}