@EndUserText.label: 'Sales Quotation Item'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Metadata: {
allowExtensions: true,
ignorePropagatedAnnotations: true
}
@ObjectModel: {
modelingPattern: #TRANSACTIONAL_QUERY,
supportedCapabilities: [#TRANSACTIONAL_PROVIDER],
usageType: {
serviceQuality: #C,
sizeCategory: #L,
dataClass: #TRANSACTIONAL
},
semanticKey: ['SalesQuotation', 'SalesQuotationItem'],
query.implementedBy: 'ABAP:CL_S4RAP_STICKY_QRY'
}
@VDM: {
viewType: #CONSUMPTION,
usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}
@AbapCatalog.extensibility: {
extensible: true,
elementSuffix: 'SDI',
dataSources: ['SalesQuotationItem'],
allowNewDatasources: true,
quota: {
maximumFields: 1000,
maximumBytes: 100000
}
}
//@Search.searchable: true
define view entity C_SalesQuotationItemManageTP
as projection on R_SalesQuotationItemTP as SalesQuotationItem
association [0..1] to I_ProductStdVH as _Product on $projection.Product = _Product.Product
association [1] to E_SalesDocumentItemBasic as _Extension on $projection.SalesQuotation = _Extension.SalesDocument
and $projection.SalesQuotationItem = _Extension.SalesDocumentItem
association [0..1] to I_PlantStdVH as _Plant on $projection.Plant = _Plant.Plant
{
key SalesQuotationItem.SalesQuotation,
key SalesQuotationItem.SalesQuotationItem,
@Semantics.valueRange.maximum: '100'
@Semantics.valueRange.minimum: '0'
SalesQuotationItem.ItemOrderProbabilityInPercent,
@ObjectModel.foreignKey.association: '_ItemCategory'
SalesQuotationItem.SalesQuotationItemCategory,
SalesQuotationItem.ItemCategoryGroup,
SalesQuotationItem.SDDocumentItemUsage,
SalesQuotationItem.HigherLevelItemCategory,
@Semantics.text: true
SalesQuotationItem.SalesQuotationItemText,
@ObjectModel.foreignKey.association: '_SalesDocumentRjcnReason'
SalesQuotationItem.SalesDocumentRjcnReason,
@ObjectModel.foreignKey.association: '_Product'
SalesQuotationItem.Product,
SalesQuotationItem.MaterialByCustomer,
@ObjectModel.foreignKey.association: '_ProductGroup'
SalesQuotationItem.ProductGroup,
@Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
@Semantics.valueRange.minimum: '0'
SalesQuotationItem.RequestedQuantity,
@Semantics.unitOfMeasure: true
SalesQuotationItem.RequestedQuantityUnit,
@ObjectModel.foreignKey.association: '_Plant'
SalesQuotationItem.Plant,
@Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
SalesQuotationItem.ItemGrossWeight,
@Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
SalesQuotationItem.ItemNetWeight,
SalesQuotationItem.ItemWeightUnit,
@Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
SalesQuotationItem.ItemVolume,
@ObjectModel.foreignKey.association: '_ItemVolumeUnit'
SalesQuotationItem.ItemVolumeUnit,
@ObjectModel.foreignKey.association: '_CustomerPriceGroup'
SalesQuotationItem.CustomerPriceGroup,
SalesQuotationItem.PricingDate,
@Semantics.currencyCode: true
SalesQuotationItem.TransactionCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
SalesQuotationItem.NetAmount,
@ObjectModel.foreignKey.association: '_SDPricingProcedure'
SalesQuotationItem.SDPricingProcedure,
@ObjectModel.foreignKey.association: '_IncotermsClassification'
SalesQuotationItem.IncotermsClassification,
SalesQuotationItem.IncotermsLocation1,
SalesQuotationItem.IncotermsLocation2,
@ObjectModel.foreignKey.association: '_IncotermsVersion'
SalesQuotationItem.IncotermsVersion,
@ObjectModel.foreignKey.association: '_StorageLocation'
SalesQuotationItem.StorageLocation,
@ObjectModel.foreignKey.association: '_Route'
SalesQuotationItem.Route,
SalesQuotationItem.RequestedDeliveryDate,
@ObjectModel.foreignKey.association: '_ShippingPoint'
SalesQuotationItem.ShippingPoint,
@ObjectModel.foreignKey.association: '_ShippingType'
SalesQuotationItem.ShippingType,
@ObjectModel.foreignKey.association: '_ReferenceSDDocumentItem'
SalesQuotationItem.ReferenceSDDocumentItem,
@ObjectModel.foreignKey.association: '_ReferenceSDDocument'
SalesQuotationItem.ReferenceSDDocument,
@ObjectModel.foreignKey.association: '_CustomerPaymentTerms'
SalesQuotationItem.CustomerPaymentTerms,
@ObjectModel.foreignKey.association: '_SDProcessStatus'
SalesQuotationItem.SDProcessStatus,
@ObjectModel.foreignKey.association: '_SDDocReferenceStatus'
SalesQuotationItem.SDDocReferenceStatus,
@ObjectModel.foreignKey.association: '_ItemGeneralIncompletionStatus'
SalesQuotationItem.ItemGeneralIncompletionStatus,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
virtual ItmGenIncompltnStsCriticality : int1,
@ObjectModel.foreignKey.association: '_SDDocumentRejectionStatus'
SalesQuotationItem.SDDocumentRejectionStatus,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
virtual SDDocRejectionStsCriticality : int1,
@ObjectModel.foreignKey.association: '_TrdCmplncEmbargoSts'
SalesQuotationItem.TrdCmplncEmbargoSts,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
virtual TrdCmplncEmbargoStsCritlty : int1,
@ObjectModel.foreignKey.association: '_ChmlCmplncStatus'
SalesQuotationItem.ChmlCmplncStatus,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
virtual ChmlCmplncStsCriticality : int1,
@ObjectModel.foreignKey.association: '_DangerousGoodsStatus'
SalesQuotationItem.DangerousGoodsStatus,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
virtual DngrsGdsStsCriticality : int1,
@ObjectModel.foreignKey.association: '_SafetyDataSheetStatus'
SalesQuotationItem.SafetyDataSheetStatus,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
virtual SftyDataShtStatCriticality : int1,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
virtual PartnerDeterminationProcedure : pargr,
@ObjectModel.text.element: [ 'ProfitCenterName' ]
SalesQuotationItem.ProfitCenter,
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
@Semantics.text: true
virtual ProfitCenterName : fis_prctr_shorttext,
SalesQuotationItem.ControllingArea,
/* For Access control */
@UI.hidden: true
SalesQuotationItem.SalesQuotationType,
@UI.hidden: true
SalesQuotationItem.OrganizationDivision,
@UI.hidden: true
SalesQuotationItem.SalesOrganization,
@UI.hidden: true
SalesQuotationItem.DistributionChannel,
/* Associations */
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._SalesQuotation : redirected to parent C_SalesQuotationManageTP,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ItemPartner : redirected to composition child C_SlsQtanItemPartnerManageTP,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ItemText : redirected to composition child C_SlsQuotationItemTextManageTP,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ItemPricingElement : redirected to composition child C_SlsQtanItmPrgElmManageTP,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ChmlCmplncStatus,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._CustomerPaymentTerms,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._CustomerPriceGroup,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._DangerousGoodsStatus,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._IncotermsClassification,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._IncotermsVersion,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ItemCategory,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ItemGeneralIncompletionStatus,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ItemVolumeUnit,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ItemWeightUnit,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
_Plant,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
_Product,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ProductGroup,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._RequestedQuantityUnit,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._Route,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._SafetyDataSheetStatus,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
SalesQuotationItem._TrdCmplncEmbargoSts,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._SalesDocumentRjcnReason,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._SDDocReferenceStatus,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._SDDocumentRejectionStatus,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._SDProcessStatus,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ShippingPoint,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ShippingType,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ReferenceSDDocumentItem,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ReferenceSDDocument,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._StorageLocation,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._TransactionCurrency,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._SDPricingProcedure,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
//@Search.defaultSearchElement: false
SalesQuotationItem._ControllingArea
}