C_SalesOrderTypeValueHelp

DDL: C_SALESORDERTYPEVALUEHELP Type: view CONSUMPTION Package: ODATA_SD_SALESORDER_UI

Sales Order Type

C_SalesOrderTypeValueHelp is a Consumption CDS View that provides data about "Sales Order Type" in SAP S/4HANA. It reads from 1 data source (I_SalesDocumentType) and exposes 7 fields with key field SalesOrderType. Part of development package ODATA_SD_SALESORDER_UI.

1 data source(s) 7 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesDocumentType _SalesDocumentType from

Annotations (16)

NameValueLevelField
AbapCatalog.sqlViewName CSALESORTYPEVH view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
ClientHandling.algorithm #SESSION_VARIABLE view
AccessControl.authorizationCheck #NOT_REQUIRED view
VDM.viewType #CONSUMPTION view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.representativeKey SalesOrderType view
UI.headerInfo.typeName Sales Order Type view
UI.headerInfo.typeNamePlural Sales Order Types view
Search.searchable true view
Consumption.ranked true view
Consumption.valueHelpDefault.fetchValues #AUTOMATICALLY_WHEN_DISPLAYED view
EndUserText.label Sales Order Type view

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY SalesOrderType
SalesDocumentTypeLangDepdnt
SalesDocumentTypeName
SalesDocumentProcessingType SalesDocumentProcessingType
NumberRangeForIntIDAssignment NumberRangeForIntIDAssignment
NumberRangeForExtIDAssignment NumberRangeForExtIDAssignment
IsLocked IsLocked 
@AbapCatalog: {
   sqlViewName: 'CSALESORTYPEVH',
   compiler.compareFilter: true,
   preserveKey: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #NOT_REQUIRED

@VDM: {
  viewType: #CONSUMPTION
}

@ObjectModel: { 
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #A,
    sizeCategory: #S
  },
  representativeKey: 'SalesOrderType'
}

@UI.headerInfo:{ 
  typeName:       'Sales Order Type',
  typeNamePlural: 'Sales Order Types'
}

@Search.searchable: true

@Consumption: {
  ranked: true,
  valueHelpDefault.fetchValues:#AUTOMATICALLY_WHEN_DISPLAYED
}

@EndUserText.label: 'Sales Order Type'
define view C_SalesOrderTypeValueHelp as select from I_SalesDocumentType as _SalesDocumentType

{   
    @Search: {
      defaultSearchElement: true,
      ranking: #HIGH
    }
    @UI.lineItem: [{ position: 10, importance: #HIGH }]
    @ObjectModel.text.element: ['SalesDocumentTypeName']  
    key cast( SalesDocumentType as sales_order_type preserving type ) as SalesOrderType,

    @UI.hidden: true
    @Search: {
      defaultSearchElement: true,
      ranking: #HIGH
    }
    @UI.textArrangement: #TEXT_SEPARATE
    _SalesDocumentType._SalesDocumentTypeLangDepdnt[1:Language=$session.system_language].SalesDocumentTypeLangDepdnt,

    @Search: {
      defaultSearchElement: true,
      ranking: #LOW,
      fuzzinessThreshold: 0.9
    }
    @UI.lineItem: [{ position: 20, importance: #HIGH }]
    _SalesDocumentType._Text[1:Language=$session.system_language].SalesDocumentTypeName,
    
    @UI.hidden: true
    SalesDocumentProcessingType,
    @UI.hidden: true
    NumberRangeForIntIDAssignment,
    @UI.hidden: true
    NumberRangeForExtIDAssignment, 
    @UI.hidden: true
    IsLocked
}
where SDDocumentCategory = 'C'

Learn More