C_SalesOrderScheduleLine

DDL: C_SALESORDERSCHEDULELINE SQL: CSOSCHEDLINES Type: view CONSUMPTION Package: ODATA_SD_SALESORDER_UI

Schedule Lines of Sales Order Item Factsheet

C_SalesOrderScheduleLine is a Consumption CDS View that provides data about "Schedule Lines of Sales Order Item Factsheet" in SAP S/4HANA. It reads from 1 data source (I_SalesOrderScheduleLine) and exposes 15 fields with key fields SalesOrder, SalesOrderItem, ScheduleLine. Part of development package ODATA_SD_SALESORDER_UI.

1 data source(s) 15 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesOrderScheduleLine ScheduleLine from

Annotations (9)

NameValueLevelField
AbapCatalog.sqlViewName CSOSCHEDLINES view
AccessControl.authorizationCheck #CHECK view
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #CONSUMPTION view
AbapCatalog.compiler.compareFilter true view
Search.searchable true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XL view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY SalesOrder I_SalesOrderScheduleLine SalesOrder
KEY SalesOrderItem I_SalesOrderScheduleLine SalesOrderItem
KEY ScheduleLine ScheduleLine
RequestedDeliveryDate
ConfirmedDeliveryDate I_SalesOrderScheduleLine ConfirmedDeliveryDate Confirmed Delivery Date
ScheduleLineOrderQuantity I_SalesOrderScheduleLine ScheduleLineOrderQuantity Requested Quantity
ConfdOrderQtyByMatlAvailCheck I_SalesOrderScheduleLine ConfdOrderQtyByMatlAvailCheck
DeliveredQtyInOrderQtyUnit I_SalesOrderScheduleLine DeliveredQtyInOrderQtyUnit
OpenConfdDelivQtyInOrdQtyUnit I_SalesOrderScheduleLine OpenConfdDelivQtyInOrdQtyUnit
OrderQuantityUnit I_SalesOrderScheduleLine OrderQuantityUnit
int1asDeliveryBlockCriticality
DelivBlockReasonForSchedLine I_SalesOrderScheduleLine DelivBlockReasonForSchedLine
_OrderQuantityUnit _OrderQuantityUnit
_DelivBlockReasonForSchedLine _DelivBlockReasonForSchedLine
_SalesOrder _SalesOrder 
@AbapCatalog.sqlViewName: 'CSOSCHEDLINES'
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ClientHandling.algorithm:#SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@Search.searchable: true

@ObjectModel: {
   semanticKey: ['SalesOrder', 'SalesOrderItem', 'ScheduleLine'],
   usageType.dataClass: #TRANSACTIONAL,
   usageType.serviceQuality: #B,
   usageType.sizeCategory: #XL
}

define view C_SalesOrderScheduleLine
  as select from I_SalesOrderScheduleLine as ScheduleLine
{
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @UI.hidden: true
  key ScheduleLine.SalesOrder,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @UI.hidden: true
  key ScheduleLine.SalesOrderItem,
      
      @UI.hidden: true
  key ScheduleLine,

      @Semantics.businessDate.at: true
      @UI.lineItem: [{position: 10, importance: #HIGH, type: #STANDARD}]
      cast(ScheduleLine.RequestedDeliveryDate as reqd_delivery_date) as RequestedDeliveryDate,   
      
      @Semantics.businessDate.at: true
      @UI.lineItem: [{position: 30, importance: #HIGH, type: #STANDARD}]
      @EndUserText.label: 'Confirmed Delivery Date'
      ScheduleLine.ConfirmedDeliveryDate,
      
      @DefaultAggregation: #NONE
      @UI.lineItem: [{position: 20, importance: #HIGH, type: #STANDARD}]
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      @EndUserText.label: 'Requested Quantity'
      ScheduleLine.ScheduleLineOrderQuantity,

      @DefaultAggregation: #NONE
      @UI.lineItem: [{position: 40, importance: #HIGH, type: #STANDARD}]
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ScheduleLine.ConfdOrderQtyByMatlAvailCheck,

      @DefaultAggregation: #NONE
      @UI.lineItem: [{position: 50, importance: #HIGH, type: #STANDARD}]
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ScheduleLine.DeliveredQtyInOrderQtyUnit,

      @DefaultAggregation: #NONE
      @UI.lineItem: [{position: 60, importance: #LOW, type: #STANDARD}]
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ScheduleLine.OpenConfdDelivQtyInOrdQtyUnit,
      
      @Semantics.unitOfMeasure:true
      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      ScheduleLine.OrderQuantityUnit,
      
      @UI.hidden: true
      cast(
      case
        when ScheduleLine.DelivBlockReasonForSchedLine != '' then 1
        else 0
      end  as abap.int1
      )                                                                         as DeliveryBlockCriticality,
      
      @UI.lineItem: {position: 70, criticality: 'DeliveryBlockCriticality'}
      ScheduleLine.DelivBlockReasonForSchedLine,

      _OrderQuantityUnit,
      _DelivBlockReasonForSchedLine,
      _SalesOrder
}

Learn More