C_SalesOrderEnhancedValueHelp

@VDM.viewType: #CONSUMPTION
@AccessControl: {
  authorizationCheck:#MANDATORY,
  personalData.blocking:#REQUIRED
}

@ObjectModel: {
  representativeKey: 'SalesOrder',
  dataCategory: #VALUE_HELP,
  usageType: {
    serviceQuality: #B,
    sizeCategory:   #XL,
    dataClass:      #TRANSACTIONAL
  },
  supportedCapabilities: [#VALUE_HELP_PROVIDER],
  modelingPattern:#NONE,
  text.control: #('ASSOCIATED_TEXT_UI_HIDDEN')
}

@Search.searchable: true
@Consumption:{
  ranked: true,
  valueHelpDefault.fetchValues:#ON_EXPLICIT_REQUEST
}

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Sales Order'
define root view entity C_SalesOrderEnhancedValueHelp
  as select from I_SalesOrder as SalesOrder
 
  association [0..*] to I_SalesDocumentTypeText      as _SalesOrderTypeText         on $projection.SalesOrderType = _SalesOrderTypeText.SalesDocumentType
  association [0..*] to I_SalesOrganizationText      as _SalesOrganizationText      on $projection.SalesOrganization = _SalesOrganizationText.SalesOrganization
  association [0..*] to I_DistributionChannelText    as _DistributionChannelText    on $projection.DistributionChannel = _DistributionChannelText.DistributionChannel
  association [0..*] to I_DivisionText               as _DivisionText               on $projection.OrganizationDivision = _DivisionText.Division
  association [0..*] to I_OverallSDProcessStatusText as _OverallSDProcessStatusText on $projection.OverallSDProcessStatus = _OverallSDProcessStatusText.OverallSDProcessStatus
  
{
  
  @UI:{ 
    lineItem: [{ position: 10, importance: #HIGH }],
    selectionField: [{ position: 10}] 
  }
  @Search: {
    defaultSearchElement: true,
    fuzzinessThreshold: 0.9,
    ranking: #HIGH
  }
  key SalesOrder.SalesOrder,
  
   @UI:{
    lineItem: [{ position: 20, importance: #HIGH  }],
    selectionField: [{ position: 20}], 
    textArrangement: #TEXT_FIRST
  } 
  @Search:{
    defaultSearchElement: true,
    fuzzinessThreshold: 0.8,
    ranking: #LOW
  }
  @Consumption.valueHelpDefinition: [{ entity: {name: 'C_SoldToValueHelp', element: 'Customer' }}]
  @ObjectModel.text.element: ['SoldToPartyName']    
  SalesOrder.SoldToParty,
  
  @Semantics.text:true
  @ObjectModel.virtualElement: true
  @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSORD_UI_PARTNER_UTIL' 
  cast('' as ad_namtext )  as SoldToPartyName,   
  
    @UI:{ 
    lineItem: [{ position: 30, importance: #HIGH }],
    selectionField: [{ position: 30}]
  }
  @Search: {
    defaultSearchElement: true,
    fuzzinessThreshold: 0.8,
    ranking: #LOW
  }
  SalesOrder.PurchaseOrderByCustomer,
  
  @UI:{
    lineItem: [{ position: 40, importance: #LOW  }],
    selectionField: [{ position: 40}],
    textArrangement: #TEXT_FIRST
  }  
  @Consumption.valueHelpDefinition: [{entity:{name:'C_SalesOrderTypeValueHelp', element:'SalesOrderType'} }]
  @ObjectModel.text.association: '_SalesOrderTypeText'
  SalesOrder.SalesOrderType,

  @UI:{ 
    lineItem: [{ position: 50, importance: #HIGH }],
    selectionField: [{ position: 50}], 
    textArrangement: #TEXT_ONLY
  }
  @Search: {
    defaultSearchElement: true,
    fuzzinessThreshold: 0.8,
    ranking: #LOW
  }
  @Consumption.valueHelpDefinition: [{
    entity: {
      name:    'I_OverallSDProcessStatus',
      element: 'OverallSDProcessStatus' 
      }
  }]
  @ObjectModel.text.element: ['OverallSDProcessStatusDesc']
  SalesOrder.OverallSDProcessStatus,
  
  @UI.hidden: true
  @Semantics.text: true
  _OverallSDProcessStatusText[1: Language=$session.system_language].OverallSDProcessStatusDesc,
      
  @UI:{ 
    lineItem: [{ position: 60, importance: #HIGH }],
    selectionField: [{ position: 60}]
  }
  @Search: {
    defaultSearchElement: true,
    fuzzinessThreshold: 0.8,
    ranking: #LOW
  }
  @Consumption.filter: {
    selectionType: #INTERVAL
  }
  SalesOrder.SalesOrderDate,
  
   @UI:{ 
    lineItem: [{ position: 70, importance: #LOW  }],
    selectionField: [{ position: 70 }],
    textArrangement: #TEXT_FIRST
  }  
  @Consumption.valueHelpDefinition: [{entity:{name:'C_SalesDocSalesOrganizationVH', element:'SalesOrganization'} }]
  @ObjectModel.text.association: '_SalesOrganizationText'
  SalesOrder.SalesOrganization,
  
  @UI:{
    lineItem: [{ position: 80, importance: #LOW  }],
    selectionField: [{ position: 80 }],
    textArrangement: #TEXT_FIRST } 
  @Consumption.valueHelpDefinition: [{entity:{name:'C_Dischannelvaluehelp', element:'DistributionChannel'},
                                      additionalBinding: [{element: 'SalesOrganization', localElement: 'SalesOrganization', usage: #FILTER_AND_RESULT}] }]
  @ObjectModel.text.association: '_DistributionChannelText'
  SalesOrder.DistributionChannel,
  
  @UI:{
    lineItem: [{ position: 90, importance: #LOW  }],
    selectionField: [{ position: 90}],
    textArrangement: #TEXT_FIRST }        
  @Consumption.valueHelpDefinition: [{entity:{name:'C_OrgDivisionValueHelp', element:'Division'},
                                      additionalBinding: [{element: 'SalesOrganization', localElement: 'SalesOrganization', usage: #FILTER_AND_RESULT},
                                                          {element: 'DistributionChannel',localElement: 'DistributionChannel', usage: #FILTER_AND_RESULT}] }]
  @ObjectModel.text.association: '_DivisionText'
  SalesOrder.OrganizationDivision,
  
 
  
  @Consumption.filter.hidden: true
  _SalesOrderTypeText, 
  @Consumption.filter.hidden: true
  _SalesOrganizationText,
  @Consumption.filter.hidden: true
  _DistributionChannelText,
  @Consumption.filter.hidden: true
  _DivisionText
}