C_SalesDocumentStandardPartner

DDL: C_SALESDOCUMENTSTANDARDPARTNER Type: view_entity CONSUMPTION Package: ODATA_SD_S4H_COMMON

Sales Document Standard Partners

C_SalesDocumentStandardPartner is a Consumption CDS View that provides data about "Sales Document Standard Partners" in SAP S/4HANA. It reads from 2 data sources (I_SalesDocumentBasic, I_SDDocStandardPartner) and exposes 13 fields with key field SalesDocument. It is exposed through 3 OData services (C_SALESORDERMANAGE_SD, UI_SALESDOCUMENTMANAGE, UI_SLSORDERWITHOUTCHARGEMANAGE). Part of development package ODATA_SD_S4H_COMMON.

2 data source(s) Exposed by 3 service(s) 13 fields

Data Sources (2)

SourceAliasJoin Type
I_SalesDocumentBasic SalesDocument inner
I_SDDocStandardPartner SalesDocumentStandardPartner from

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
VDM.viewType #CONSUMPTION view
EndUserText.label Sales Document Standard Partners view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view

OData Services (3)

ServiceBindingVersionContractRelease
C_SALESORDERMANAGE_SD C_SALESORDERMANAGE_SRV V4 C1 NOT_RELEASED
UI_SALESDOCUMENTMANAGE UI_SALESDOCUMENTMANAGE V4 C1 NOT_RELEASED
UI_SLSORDERWITHOUTCHARGEMANAGE UI_SLSORDERWITHOUTCHARGEMANAGE V4 C1 NOT_RELEASED

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY SalesDocument I_SalesDocumentBasic SalesDocument
SoldToParty I_SDDocStandardPartner SoldToParty
SoldToPartyName
ShipToParty I_SDDocStandardPartner ShipToParty
ShipToPartyName
BillToParty I_SDDocStandardPartner BillToParty
BillToPartyName
PayerParty I_SDDocStandardPartner PayerParty
PayerPartyName
SalesEmployee I_SDDocStandardPartner SalesEmployee
SalesEmployeeName
ResponsibleEmployee I_SDDocStandardPartner ResponsibleEmployee
ResponsibleEmployeeName 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Sales Document Standard Partners'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
define view entity C_SalesDocumentStandardPartner
  as select from I_SDDocStandardPartner as SalesDocumentStandardPartner
    inner join     I_SalesDocumentBasic as SalesDocument  on SalesDocument.SalesDocument = SalesDocumentStandardPartner.SDDocument
{
  key SalesDocument.SalesDocument,
  
      @ObjectModel.text.element:  [ 'SoldToPartyName' ]
      @Consumption: {
        semanticObject: 'Customer',
        semanticObjectMapping: {
          element: 'Customer'
        },
        valueHelpDefinition: [{ entity: { name: 'C_SoldToValueHelp', element: 'Customer' } } ]
      }
      SalesDocumentStandardPartner.SoldToParty,
      
      @UI.hidden: true
      @Semantics.text:true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSDOC_UI_PARTNER_UTIL'
      cast('' as ad_namtext )  as SoldToPartyName,
      
      
      @ObjectModel.text.element:  [ 'ShipToPartyName' ]
      @Consumption: {
        semanticObject: 'Customer',
        semanticObjectMapping: {
          element: 'Customer'
        },
        valueHelpDefinition: [{ entity: { name: 'C_SoldToValueHelp', element: 'Customer' } } ]
      }
      SalesDocumentStandardPartner.ShipToParty,
      
      @UI.hidden: true
      @Semantics.text:true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSDOC_UI_PARTNER_UTIL'
      cast('' as ad_namtext )  as ShipToPartyName,
      
      
      @ObjectModel.text.element:  [ 'BillToPartyName' ]
      @Consumption: {
        semanticObject: 'Customer',
        semanticObjectMapping: {
          element: 'Customer'
        },
        valueHelpDefinition: [{ entity: { name: 'C_SoldToValueHelp', element: 'Customer' } } ]
      }
      SalesDocumentStandardPartner.BillToParty,
      
      @UI.hidden: true
      @Semantics.text:true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSDOC_UI_PARTNER_UTIL'
      cast('' as ad_namtext )  as BillToPartyName,
      
      
      @ObjectModel.text.element:  [ 'PayerPartyName' ]
      @Consumption: {
        semanticObject: 'Customer',
        semanticObjectMapping: {
          element: 'Customer'
        },
        valueHelpDefinition: [{ entity: { name: 'C_SoldToValueHelp', element: 'Customer' } } ]
      }
      SalesDocumentStandardPartner.PayerParty,
      
      @UI.hidden: true
      @Semantics.text:true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSDOC_UI_PARTNER_UTIL'
      cast('' as ad_namtext )  as PayerPartyName,
      
      
      @ObjectModel.text.element:  [ 'SalesEmployeeName' ]
      @Consumption: {
        semanticObject: 'Employee',
        valueHelpDefinition: [{ entity: { name: 'C_SalesDocumentPersonnelVH', element: 'PersonnelNumber' } } ]
      }
      SalesDocumentStandardPartner.SalesEmployee,
      
      @UI.hidden: true
      @Semantics.text:true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSDOC_UI_PARTNER_UTIL'
      cast('' as ad_namtext )  as SalesEmployeeName,
      
      
      @ObjectModel.text.element:  [ 'ResponsibleEmployeeName' ]
      @Consumption: {
        semanticObject: 'Employee',
        valueHelpDefinition: [{ entity: { name: 'C_SalesDocumentPersonnelVH', element: 'PersonnelNumber' } } ]
      }  
      SalesDocumentStandardPartner.ResponsibleEmployee,
      
      @UI.hidden: true
      @Semantics.text:true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSDOC_UI_PARTNER_UTIL'
      cast('' as ad_namtext )  as ResponsibleEmployeeName

};

Learn More