C_SI_OpnSupplierInvoiceItemC

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@Analytics.dataCategory: #CUBE
@Analytics.internalName:#LOCAL
@EndUserText.label: 'Epobot Slovenia - Cube'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations: true

define view entity C_SI_OpnSupplierInvoiceItemC
  as select from    I_OperationalAcctgDocItem as Item

    left outer to many join I_StRpJournalEntryLog as Log on Log.AccountingDocument = Item.AccountingDocument
                                                        and Log.CompanyCode        = Item.CompanyCode
                                                        and Log.FiscalYear         = Item.FiscalYear
                                                 
    left outer to one join I_BusinessPartnerSupplier as BPSupplier on BPSupplier.Supplier = Item.Supplier
    
    left outer to one join I_Businesspartnertaxnumber as BPTaxNumber1 on BPTaxNumber1.BusinessPartner = BPSupplier.BusinessPartner
                                                                     and BPTaxNumber1.BPTaxType = 'SI1'
                                                                     
{
  key Item.CompanyCode,
  key Item.AccountingDocument,
  key Item.AccountingDocumentItem,
  key Item.FiscalYear,
  key Log.StatryRptCategory,
  key Log.StatryRptRunID,
  key Log.StatryRptgEntity,
      Item.FiscalPeriod,
      Item.PostingDate,
      Item.DocumentDate, //racuna

      Item.DueCalculationBaseDate, //zapadlosti

      Item.NetDueDate, //nastanka

      Item.DebitCreditCode,
      Item.CompanyCodeCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      case Item.DebitCreditCode
        when 'H' then -1 * Item.AmountInCompanyCodeCurrency
        else Item.AmountInCompanyCodeCurrency
      end as AmountInCompanyCodeCurrency,
      Item.Reference1IDByBusinessPartner,
      Item.Reference2IDByBusinessPartner,
      Item.Reference3IDByBusinessPartner,
      Item._JournalEntry.DocumentReferenceID,
      BPTaxNumber1.BPTaxNumber as SupplierVATRegistration,
      Item.Supplier,
      Item.CustomerSupplierCountry,
      Item._Supplier.Country,
      Item.InvoiceReference,
      Item.InvoiceReferenceFiscalYear,
      Item.InvoiceItemReference,
      Item.GLAccount,
      Item.PaymentBlockingReason
}
where
  //Open vendor items:

      Item.FinancialAccountType       =  'K'
  and Item.ClearingJournalEntry       =  ''
  and Item.AccountingDocumentCategory <> 'D'
  and Item.AccountingDocumentCategory <> 'M'
  //excluding partial payments without link to invoice

  and (Item.DebitCreditCode = 'H' or 
      (Item.DebitCreditCode = 'S' and Item.InvoiceReference is not initial))
  and (Item.PaymentBlockingReason is initial or Item.PaymentBlockingReason = ' ')
  and Item.SpecialGLCode <> 'F' //Down Payment request