C_ReturnsReferenceSalesOrderVH

@VDM.viewType: #CONSUMPTION

@ObjectModel: {
  dataCategory:#VALUE_HELP,
  representativeKey: 'SalesOrder',
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory: #L
  }
}

@Search.searchable: true
@Consumption.ranked: true

@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@UI.presentationVariant: [{
  sortOrder: [{
    by: 'SalesOrder',
    direction: #DESC
  }]
}]
@EndUserText.label: 'Return Reference Sales Order'
define view entity C_ReturnsReferenceSalesOrderVH

  as select from I_SalesOrder as SalesOrder

  association [0..*] to I_OverallSDProcessStatusText   as _OverallSDProcessStatusText   on $projection.OverallSDProcessStatus      = _OverallSDProcessStatusText.OverallSDProcessStatus
  association [0..1] to C_SalesOrganizationVH          as _SalesOrganization on $projection.SalesOrganization = _SalesOrganization.SalesOrganization

{
      @UI: {
        lineItem: [{ position: 10,  importance: #HIGH }],
        selectionField: [{ position: 10 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #HIGH
      }
  key SalesOrder.SalesOrder,
      @UI: {
        selectionField: [{ position: 20 }],
        textArrangement: #TEXT_FIRST,
        lineItem: [{ position: 20, importance: #HIGH }]
      }
      @ObjectModel.foreignKey.association: '_SalesOrderType'  
      @Consumption.valueHelpDefinition: [{ 
        association: '_SalesOrderType' 
      }]
      SalesOrder.SalesOrderType,
      
      @UI: {
        lineItem: [{ position: 30,  importance: #HIGH }],
        selectionField: [{ position: 30 }],
        textArrangement: #TEXT_FIRST
      }

      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'D_SlsDocSoldToPartyCVH',
        element: 'Customer' } }]
      }
      @ObjectModel.text.element: ['SoldToPartyName']
      SalesOrder.SoldToParty,

      @Semantics.text: true
      @UI.hidden: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSORD_UI_PARTNER_UTIL'
      cast('' as ad_namtext )                                                        as SoldToPartyName,

      @UI: {
        selectionField: [{ position: 40 }],
        lineItem: [{ position: 40,  importance: #HIGH }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #MEDIUM
      }
      SalesOrder.PurchaseOrderByCustomer,

      @UI: {
        lineItem: [{ position: 50,  importance: #HIGH }],
        selectionField: [{ position: 50 }]
      }
      @Consumption.filter: {
        selectionType: #INTERVAL
      }
      SalesOrder.SalesOrderDate,

      @UI: {
        lineItem: [{ position: 60,  importance: #HIGH }],
        selectionField: [{ position: 60 }],
        textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDProcessStatus',
          element: 'OverallSDProcessStatus'
        }
      }]
      @ObjectModel.text.element: ['OverallSDProcessStatusDesc']
      SalesOrder.OverallSDProcessStatus,

      @UI.hidden: true
      @Semantics.text: true
      _OverallSDProcessStatusText[1: Language=$session.system_language].OverallSDProcessStatusDesc,

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      @Consumption.valueHelpDefinition: [{ 
        association: '_SalesOrganization' 
      }]
      @UI.textArrangement: #TEXT_FIRST
      SalesOrder.SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      @UI.textArrangement: #TEXT_FIRST
      @Consumption.valueHelpDefinition: [{ 
        association: '_DistributionChannel' 
      }]
      SalesOrder.DistributionChannel,
      @UI.textArrangement: #TEXT_FIRST
      @ObjectModel.foreignKey.association: '_OrganizationDivision'
      @Consumption.valueHelpDefinition: [{ 
        association: '_OrganizationDivision' 
      }]
      SalesOrder.OrganizationDivision,

     //association

      _SalesOrderType,
      _SalesOrganization,
      _DistributionChannel,
      _OrganizationDivision
}
 where
     SalesDocApprovalStatus        <> 'A' and  // In Approval

     SalesDocApprovalStatus        <> 'C' and  // Rejected

     SalesDocApprovalStatus        <> 'D'      // To Be Reworked