C_ReturnsReferenceInvoiceItem

DDL: C_RETURNSREFERENCEINVOICEITEM Type: view_entity CONSUMPTION Package: ODATA_SD_RETURN_V2

Customer Return Reference Invoice Item

C_ReturnsReferenceInvoiceItem is a Consumption CDS View that provides data about "Customer Return Reference Invoice Item" in SAP S/4HANA. It reads from 2 data sources (I_BillingDocumentItem, C_ReturnsReferenceInvoice) and exposes 17 fields with key fields ReferenceDocument, ReferenceSDDocumentItem. It is exposed through 1 OData service (UI_CUSTOMERRETURNMANAGE). Part of development package ODATA_SD_RETURN_V2.

2 data source(s) Exposed by 1 service(s) 17 fields

Data Sources (2)

SourceAliasJoin Type
I_BillingDocumentItem BillingDocumentItem from
C_ReturnsReferenceInvoice ReferenceDocument inner

Annotations (11)

NameValueLevelField
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Customer Return Reference Invoice Item view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.modelingPattern #NONE view
Search.searchable true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_CUSTOMERRETURNMANAGE UI_CUSTOMERRETURNMANAGE V4 C1 NOT_RELEASED

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY ReferenceDocument
KEY ReferenceSDDocumentItem I_BillingDocumentItem BillingDocumentItem
SDDocumentCategory I_BillingDocumentItem SDDocumentCategory
Product I_BillingDocumentItem Product
ProductName
ReturnableQuantity
BillingQuantityUnit I_BillingDocumentItem BillingQuantityUnit
BillingQuantity I_BillingDocumentItem BillingQuantity
NetAmount I_BillingDocumentItem NetAmount
ReturnQuantity
ReturnQuantityUnit I_BillingDocumentItem BillingQuantityUnit
TransactionCurrency I_BillingDocumentItem TransactionCurrency
HigherLevelItem I_BillingDocumentItem HigherLevelItem
BillingDocumentType C_ReturnsReferenceInvoice BillingDocumentType
Division C_ReturnsReferenceInvoice Division
SalesOrganization C_ReturnsReferenceInvoice SalesOrganization
DistributionChannel C_ReturnsReferenceInvoice DistributionChannel 
@VDM.viewType: #CONSUMPTION
@AccessControl:{
  authorizationCheck: #MANDATORY,
  personalData.blocking: #NOT_REQUIRED
  }
@EndUserText.label: 'Customer Return Reference Invoice Item'
@Metadata: {
  allowExtensions: true,
  ignorePropagatedAnnotations: true
}
@ObjectModel:{
  updateEnabled,
  usageType: {
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
  },
  supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
  modelingPattern: #NONE
}
@Search.searchable: true
define view entity C_ReturnsReferenceInvoiceItem 
as select from I_BillingDocumentItem as BillingDocumentItem
    inner join C_ReturnsReferenceInvoice as ReferenceDocument on BillingDocumentItem.BillingDocument = ReferenceDocument.BillingDocument
{
        @Search.defaultSearchElement: true
  key cast( BillingDocumentItem.BillingDocument as vdm_invoice preserving type ) as ReferenceDocument,
  key BillingDocumentItem.BillingDocumentItem as ReferenceSDDocumentItem,
      BillingDocumentItem.SDDocumentCategory,
      
      @ObjectModel.text.element: ['ProductName']
      BillingDocumentItem.Product,
      
      @Semantics.text: true
      BillingDocumentItem._ProductText[1: Language=$session.system_language].ProductName,

      @Semantics.quantity.unitOfMeasure: 'BillingQuantityUnit'
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_CUSTRETURN_V4_UI_UTIL'
      cast(0 as returnable_quantity)          as ReturnableQuantity,

      BillingDocumentItem.BillingQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'BillingQuantityUnit'
      BillingDocumentItem.BillingQuantity,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      BillingDocumentItem.NetAmount,
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_CUSTRETURN_V4_UI_UTIL'
      @Semantics.valueRange.minimum: '0'
      @Semantics.quantity.unitOfMeasure: 'ReturnQuantityUnit'
      cast(0 as return_quantity)              as ReturnQuantity,

      BillingDocumentItem.BillingQuantityUnit                     as ReturnQuantityUnit,
      BillingDocumentItem.TransactionCurrency,
      BillingDocumentItem.HigherLevelItem,

      //ACL

      @UI.hidden:true
      ReferenceDocument.BillingDocumentType,
      @Consumption.hidden:true
      ReferenceDocument.Division,
      @Consumption.hidden:true
      ReferenceDocument.SalesOrganization,
      @Consumption.hidden:true
      ReferenceDocument.DistributionChannel

}

Learn More