C_RelForBillgListRptAndObjPg

@AbapCatalog.sqlViewName: 'CSRVORDRELBILNG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'List of all Service Orders which can be Released for Billing'
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true

@VDM: {
  viewType: #CONSUMPTION
}

@ObjectModel: {
   representativeKey: 'ServiceOrder',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Consumption.semanticObject: 'ServiceOrder'

@Metadata: {
    allowExtensions: true
}

define view C_RelForBillgListRptAndObjPg
  as select from I_ServiceOrderEnhcd

    inner join   P_SrvcDocReleasedForBilling as _SrvcDocReleasedForBilling on ServiceOrder = _SrvcDocReleasedForBilling.ServiceDocument
  association [1..*] to C_SrvcOrdItemListRptAndObjPg   as _SrvcOrdItemListRptAndObjPg   on  $projection.ServiceOrder = _SrvcOrdItemListRptAndObjPg.ServiceOrder
  association [0..1] to I_StatusObjectUUIDStatus       as _SrvcDocSystemStatus          on  $projection.ServiceDocumentUUID     = _SrvcDocSystemStatus.StatusObjectUUID
                                                                                        and (
                                                                                           _SrvcDocSystemStatus.StatusCode      = 'I1002'
                                                                                           or _SrvcDocSystemStatus.StatusCode   = 'I1003'
                                                                                           or _SrvcDocSystemStatus.StatusCode   = 'I1004'
                                                                                           or _SrvcDocSystemStatus.StatusCode   = 'I1005'
                                                                                         )
                                                                                        and _SrvcDocSystemStatus.StatusIsActive = 'X'
  association [0..1] to I_CustMgmtLifecycleUserStsText as _CustMgmtLifecycleUserStsText on  $projection.ServiceOrderStatus         = _CustMgmtLifecycleUserStsText.CustMgmtLifecycleUserStatus
                                                                                        and _CustMgmtLifecycleUserStsText.Language = $session.system_language
  association [0..1] to E_ServiceDocument              as _ServiceDocumentExt           on  $projection.ServiceObjectType = _ServiceDocumentExt.ServiceCategory
                                                                                        and $projection.ServiceOrder      = _ServiceDocumentExt.ServiceOrder

  association [0..1] to I_SitnInstceIndicator          as _SitnInstceIndicator          on  _SitnInstceIndicator.SitnInstceAnchorObjectKey = $projection.ServiceOrderUUID
                                                                                        and _SitnInstceIndicator.SitnDefAnchorObject       = 'ServiceDocumentUUID'
  association [0..1] to I_DeliveryPriorityText         as _DeliveryPriorityText         on  _DeliveryPriorityText.DeliveryPriority = I_ServiceOrderEnhcd.DeliveryPriority
  association [0..1] to I_ShippingCondition            as _ShippingCondition            on  _ShippingCondition.ShippingCondition = $projection.ShippingCondition

{
       @ObjectModel.readOnly: true
       @Search.defaultSearchElement: true
       //  @Search.fuzzinessThreshold: 0.8

       @Search.ranking: #HIGH
  key  ServiceOrder,

       ServiceDocumentType,

       @ObjectModel.readOnly: true
       @Search.defaultSearchElement: true
       ServiceObjectType,

       @Search.defaultSearchElement: true
       ServiceOrderDescription,

       //@Consumption.valueHelp:'_SoldToParty'

       @ObjectModel.foreignKey.association: '_SrvcDocBPSoldToParty'
       @ObjectModel.text.element: ['SoldToPartyName']
       SoldToParty,

       _SoldToParty.BusinessPartnerName                                                                                                   as BusinessPartnerName,
       _SoldToParty.BusinessPartnerName                                                                                                   as SoldToPartyName,

       //@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }

       //_SoldToParty.FirstName,


       //@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }

       //_SoldToParty.LastName,


       //@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }

       //_SoldToParty.GroupBusinessPartnerName1,


       //@Search: {defaultSearchElement: true, ranking: #HIGH,fuzzinessThreshold: 0.8 }

       //_SoldToParty.GroupBusinessPartnerName2,


       //@Search: {defaultSearchElement: true,  ranking: #HIGH, fuzzinessThreshold: 0.8 }

       //_SoldToParty.OrganizationBPName1,


       //@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }

       //_SoldToParty.OrganizationBPName2,


       @ObjectModel.foreignKey.association: '_SrvcDocBPShipToParty'
       @ObjectModel.text.element: ['ShipToPartyName']
       ShipToParty,

       @Semantics.text: true
       _ShippingCondition._Text[1:Language = $session.system_language].ShippingConditionName                                              as ShippingConditionName,
       @ObjectModel.text.element: ['ShippingConditionName']
       @Consumption.valueHelp: '_ShippingCondition'
       ShippingCondition,

       @ObjectModel.foreignKey.association: '_SrvcDocBPBillToParty'
       @ObjectModel.text.element: ['BillToPartyName']
       BillToParty,

       @ObjectModel.foreignKey.association: '_SrvcDocBPPayerParty'
       @ObjectModel.text.element: ['PayerPartyName']
       PayerParty,

       _BillToParty.BusinessPartnerName                                                                                                   as BillToPartyName,
       _ShipToParty.BusinessPartnerName                                                                                                   as ShipToPartyName,
       _PayerParty.BusinessPartnerName                                                                                                    as PayerPartyName,
       _ContactPerson.BusinessPartnerName                                                                                                 as CompanyContactPersonFullName,

       CustMgmtExtRefID,

       ServiceOrderPriority,

       PostingDate,

       ServiceOrdErrorStsCriticality,

       ServiceDocumentHasError,

       //       @ObjectModel.readOnly: true

       //

       //       Priority,


       @Semantics.amount.currencyCode: 'TransactionCurrency'
       ServiceDocGrossAmount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       ServiceDocNetAmount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       ServiceDocTaxAmount,

       @Semantics.currencyCode: true
       TransactionCurrency,

       _ServiceDocumentNotes.ServiceDocNoteText                                                                                           as ServiceOrderNoteText,


       @Consumption.filter.hidden: true
       @ObjectModel.text.element: [ 'ServiceOrderStatusName' ]
       ServiceOrderStatus,
       TechObjIsEquipOrFuncnlLoc,

       TechnicalObject,

       //@ObjectModel.text.element: ['EquipmentName']

       Equipment,

       // for equipment ID navigation

       EquipmentName,


       // @ObjectModel.text.element: ['FunctionalLocationName']

       FunctionalLocation,

       FunctionalLocationName,

       ReferenceProduct,


       ProductID,

       ProductName,


       BusinessActivityCategory,

       RequestedServiceStartDate,

       RequestedServiceEndDate,

       //       tstmp_to_dats( RequestedServiceStartDateTime,

       //                      abap_system_timezone( $session.client,'NULL' ),

       //                      $session.client,

       //                      'NULL' )                                                                                                                                                  as   RequestedServiceStartDate,

       //

       //

       //       tstmp_to_dats( RequestedServiceEndDateTime,

       //                      abap_system_timezone( $session.client,'NULL' ),

       //                      $session.client,

       //                      'NULL' )                                                                                                                                                  as   RequestedServiceEndDate,


       @Consumption.valueHelp:'_RespEmployee'
       ResponsibleEmployee,

       // @ObjectModel.foreignKey.association: '_ServiceTeamHeader'

       I_ServiceOrderEnhcd.RespyMgmtServiceTeam,

       _ServiceTeamHeader._TeamDescription.TeamDescription                                                                                as RespyMgmtServiceTeamDesc,

       @ObjectModel.text.element:['RespyMgmtServiceTeamDesc']
       _ServiceTeamHeader.TeamName                                                                                                        as RespyMgmtServiceTeamName,

       @Consumption.valueHelp:'_ServiceTeam'
       ServiceTeam,

       RefBusinessSolutionOrder,

       SoldToPartyCountry,

       SoldToPartyRegion,

       PurchaseOrderByCustomer,

       ServiceEmployee,


       @ObjectModel.foreignKey.association: '_SrvcDocBPContactCard'
       @ObjectModel.text.element: ['CompanyContactPersonFullName']
       ContactPerson,

       ServiceDocumentUUID,
       ServiceOrderUUID,

       @ObjectModel.foreignKey.association: '_SrvcDocIsQuotation'
       @Semantics.booleanIndicator: true
       ServiceDocumentIsQuotation,
       ServiceDocumentIsReleased,
       ServiceDocumentIsOpen,
       ServiceDocumentIsRejected,

       ServiceDocBillingStatusName,
       ServiceDocIsRelForBillCritlty,
       ServiceDocOvrlBillgBlkStsName,
       SrvcDocOvrlBillgBlkStsCritlty,
       ServiceDocOvrlBillingStsName,
       ServiceDocOvrlBillgBlkSts,
       ServiceDocOvrlBillingStsCritl,
       ServiceDocOvrlBillingSts,
       PriceIsFixed,
       OverallCompletionPercent,
       SrvcConfGrossAmount,
       ServiceDocDuration,
       ActualDurationInHours,

       @ObjectModel.foreignKey.association: '_SalesOrganization'
       SalesOrganization,

       @ObjectModel.foreignKey.association: '_DistributionChannel'
       DistributionChannel,

       @ObjectModel.foreignKey.association: '_Division'
       Division,

       @ObjectModel.foreignKey.association: '_SalesOffice'
       SalesOffice,

       @ObjectModel.foreignKey.association: '_SalesGroup'
       SalesGroup,

       @ObjectModel.text.element: ['MaintenancePlanDesc']
       MaintenancePlan,
       MaintenancePlanDesc,

       @ObjectModel.text.element: ['MaintenanceItemDescription']
       MaintenanceItem,
       MaintenanceItemDescription,

       @ObjectModel.foreignKey.association: '_SrvcDocCreditStatus'
       SrvcOrdCreditStatus,

       @Consumption.filter.hidden: true
       PaymentTerms,
       //       _SrvcOrdItemListRptAndObjPg.PaymentTerms                                                                                           as PaymentTerms,


       case SrvcOrdCreditStatus
          when 'A' then 0
          when 'B' then 3
          when 'C' then 1
          when 'D' then 2
          else 0
       end                                                                                                                                as SrvcOrdCrdtStsCriticality,
       _SrvcDocSystemStatus.StatusCode                                                                                                    as SystemStatus,

       case
          when _ServiceDocumentType.StatusProfile <> '' and _CustMgmtLifecycleUserStsText.CustMgmtLifecycleUserStatus <> ''
           then _CustMgmtLifecycleUserStsText.CustMgmtLifecycleUserStsName
          when _ServiceDocumentType.StatusProfile = ''
           then _ServiceDocumentStatus._ServiceDocumentStatusText[1:Language = $session.system_language].ServiceDocumentStatusName
          else _ServiceDocumentStatus._ServiceDocumentStatusText[1:Language = $session.system_language].ServiceDocumentStatusName
       end                                                                                                                                as ServiceOrderStatusName,

       @ObjectModel.text.element: ['SrvcDocBslnCostPostgStatusText']
       @Consumption.valueHelp:'_SrvcDocBslnCostPostgStatus'
       SrvcDocBslnCostPostgStatus,
       _SrvcDocBslnCostPostgStatus._Text[1:Language = $session.system_language].SrvcDocBslnCostPostgStatusText,

       @ObjectModel.text.element: ['SrvcDocContnsCostPostgStsText']
       @Consumption.valueHelp:'_SrvcDocContinuousCostStatus'
       SrvcDocContinuousCostStatus,
       _SrvcDocContinuousCostStatus._Text[1:Language = $session.system_language].SrvcDocBslnCostPostgStatusText                           as SrvcDocContnsCostPostgStsText,

       @ObjectModel.text.element: ['SrvcDocTransferStatusText']
       @Consumption.valueHelp:'_SrvcDocTransferStatus'
       SrvcDocTransferStatus,
       _SrvcDocTransferStatus._ServiceDocTransferStatusText[1:Language = $session.system_language].SrvcDocTransferStatusText,

       //       @ObjectModel.text.element: ['SrvcDocTransferStatusText']

       @ObjectModel.text.element: ['SrvcDocExecutionStatusText']
       @Consumption.valueHelp:'_SrvcDocExecutionStatus'
       SrvcDocExecutionStatus,
       _SrvcDocExecutionStatus._Text[1:Language =$session.system_language and ServiceDocumentIsQuotation = ''].SrvcDocExecutionStatusText as SrvcDocExecutionStatusText,

       Customer,

       // Situations

       @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_MANG_SRVHDR_CALC_EXIT'
       cast ( 0 as sit_de_inst_count )                                                                                                    as SitnNumberOfInstances,

       @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_MANG_SRVHDR_CALC_EXIT'
       cast ( 0 as sit_de_inst_count )                                                                                                    as SitnNmbrOfInstceInHierarchy,

       @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_MANG_SRVHDR_CALC_EXIT'
       cast ('' as val_text)                                                                                                              as SrvcDocSituationStatusText,

       @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_MANG_SRVHDR_CALC_EXIT'
       @ObjectModel.filter.transformedBy:'ABAP:CL_CRMS4_MANG_SRVHDR_FLTR_EXIT'
       @ObjectModel.text.element: ['SrvcDocSituationStatusText']
       @Semantics.booleanIndicator:true
       cast( '' as crmt_boolean )                                                                                                         as SrvcDocSituationStatus,

       @ObjectModel.virtualElement
       @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_MANG_SRVHDR_CALC_EXIT'
       @Semantics.booleanIndicator:true
       cast( '' as crmt_boolean )                                                                                                         as ServiceOrderIsEditable, //determine whether Service Order is editable based on authorization


       @Semantics.text: true
       _DeliveryPriorityText[1:Language = $session.system_language].DeliveryPriorityDesc                                                  as DeliveryPriorityDesc,
       @ObjectModel.text.element: ['DeliveryPriorityDesc']
       DeliveryPriority,
       IncotermsPart1,
       IncotermsPart2,
       @Consumption.valueHelp:'_SrvcMgmtDocRejectionStatus'
       @ObjectModel.foreignKey.association: '_SrvcMgmtDocRejectionStatus'
       SrvcDocRejectionStatus,
       
       @ObjectModel.foreignKey.association: '_SrvcDocumentRejectionReason'
       ServiceDocumentRejectionReason,
       
       @Semantics.text: true
       @ObjectModel.virtualElement
       @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_MANG_SRVHDR_CALC_EXIT'
       cast( '' as ddtext80 )                                                                                                           as   SrvcDocDeliveryStatusText,
       
       @ObjectModel.virtualElement
       @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_MANG_SRVHDR_CALC_EXIT'
       @ObjectModel.text.element: ['SrvcDocDeliveryStatusText']
       cast( '' as crmt_status_h_delivered )                                                                                            as   SrvcDocDeliveryStatus,
       
       @Semantics.text: true
       @ObjectModel.virtualElement
       @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_MANG_SRVHDR_CALC_EXIT'
       cast( '' as ddtext80 )                                                                                                           as DeliveryBlockStatusDesc,
 
       @ObjectModel.virtualElement
       @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CRMS4_MANG_SRVHDR_CALC_EXIT'
       @ObjectModel.text.element: ['DeliveryBlockStatusDesc']
       cast( '' as gbstk )                                                                                                              as DeliveryBlockStatus,
       
       // Associations

       _SoldToParty,

       _ShipToParty,

       _BillToParty,

       _PayerParty,

       _RespEmployee,

       _ServiceTeam,

       _ServiceEmployee,

       _ContactPerson,

       _ServiceDocumentType,

       _ServiceDocumentPriority,

       _ServiceDocumentStatus,

       _ServiceDocHasError,

       _ActivityCategory,

       _ServiceDocRefObj,

       _ServiceDocumentNotes,

       @ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]
       _SrvcOrdItemListRptAndObjPg,

       //@ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]

       //_SrvcOrdFUPSrvcConfTransHist,


       @ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]
       _ServiceDocumentErrorLog,

       _SalesOrganization,

       _SalesOffice,

       _SalesGroup,

       _Division,

       _DistributionChannel,

       SalesOrganizationOrgUnitID,
       SalesOfficeOrgUnitID,
       SalesGroupOrgUnitID,
       ServiceOrganization,
       _SalesOrganizationOrgUnit,
       _SalesOfficeOrgUnit,
       _SalesGroupOrgUnit,
       _ServiceOrganizationOrgUnit,

       @ObjectModel.association.type:  [#TO_COMPOSITION_CHILD]
       _PartiesInvolved,

       _ServiceOrderPriceDets,
       //_ServiceTeamHeader,

       _ServiceOrderType,

       _SrvcDocBPSoldToParty,
       _SrvcDocBPShipToParty,
       _SrvcDocBPBillToParty,
       _SrvcDocBPContactCard,
       _SrvcDocBPPayerParty,
       _SrvcDocCreditStatus,
       _SrvcDocSystemStatus,
       _CustMgmtLifecycleUserStsText,
       // Baseline Cost Posting Status

       _SrvcDocBslnCostPostgStatus,
       // Continuous Cost Calculation Status

       _SrvcDocContinuousCostStatus,
       _SitnInstceIndicator,
       _SrvcDocTransferStatus,
       _SrvcDocExecutionStatus,
       _SrvcDocIsQuotation,
       _SrvcDocumentRejectionReason,
       _SrvcMgmtDocRejectionStatus

}
where
      ServiceObjectType           =  'BUS2000116'
  and ServiceDocumentIsQuotation != 'X'
  and ServiceDocumentTemplateType <> 'D'
  and RefInHouseRepairIsExisting  =  ' '