C_RejectedSalesOrder

DDL: C_REJECTEDSALESORDER Type: view CONSUMPTION Package: ODATA_SD_CUSTOMER360

Rejected Sales Orders

C_RejectedSalesOrder is a Consumption CDS View that provides data about "Rejected Sales Orders" in SAP S/4HANA. It reads from 1 data source (I_SalesOrder) and exposes 12 fields with key field SalesOrder. Part of development package ODATA_SD_CUSTOMER360.

1 data source(s) 12 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesOrder I_SalesOrder from

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName CREJCTDSLSORD view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
VDM.viewType #CONSUMPTION view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Rejected Sales Orders view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY SalesOrder SalesOrder
OverallSDDocumentRejectionSts OverallSDDocumentRejectionSts
NumberOfRejectedSalesOrderItms
CreationDate CreationDate
SoldToParty SoldToParty
SalesOrganization SalesOrganization
DistributionChannel DistributionChannel
OrganizationDivision OrganizationDivision
SalesOffice SalesOffice
SalesGroup SalesGroup
SalesOrderType SalesOrderType
OvrlSDDocumentRejectionStsDesc 
@AbapCatalog : { sqlViewName: 'CREJCTDSLSORD',
                 compiler.compareFilter: true,
                 preserveKey: true
               }

@AccessControl: { authorizationCheck: #CHECK,
                  personalData.blocking: #BLOCKED_DATA_EXCLUDED
                }

@VDM: {
  viewType: #CONSUMPTION
      }

@ObjectModel: { usageType.dataClass: #MIXED,
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #M
              }

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Rejected Sales Orders'

@Metadata:{ allowExtensions: true,
            ignorePropagatedAnnotations: true
          }


define view C_RejectedSalesOrder
  as select from I_SalesOrder

     //association [0..1] to I_Customer as _Customer on $projection.SoldToParty = _Customer.Customer


     association to I_CalendarDate    as _CreationDate on _CreationDate.CalendarDate = $projection.CreationDate
     association to I_CalendarDate    as _CurrentDate  on _CurrentDate.CalendarDate  = $session.system_date
{

  key SalesOrder,

      @ObjectModel.text.element:  [ 'OvrlSDDocumentRejectionStsDesc' ]
      OverallSDDocumentRejectionSts,

      @DefaultAggregation: #SUM
      cast( 1 as number_of_sales_orders) as NumberOfRejectedSalesOrderItms,
      
      CreationDate,
      /* Filters */
      SoldToParty,
      SalesOrganization,
      DistributionChannel,
      OrganizationDivision,
      SalesOffice,
      SalesGroup,
      //commented as a part of UserStory:FXUBLR07-27, it could be added in the future release

      //    _Customer.CustomerClassification,

      //    CreatedByUser,

      //    LastChangedByUser,


      /* Field added for DCL*/
      @Consumption.hidden: true
      SalesOrderType,

      _OverallSDDocumentRejectionSts._Text[1: Language = $session.system_language ].OvrlSDDocumentRejectionStsDesc

}
where
  SalesOrderProcessingType      <> 'P'
  and(
       OverallSDDocumentRejectionSts =  'B'
    or OverallSDDocumentRejectionSts =  'C'
  )
  and _CreationDate.YearMonth > left(dats_add_months(_CurrentDate.CalendarDate, -6, 'FAIL'), 6) // Last six months records

Learn More