C_RO_SAFTReportedItemsLog

@AbapCatalog.sqlViewName:'CROSAFRPTILOG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'GL Entry for Reported Items Log'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking: #NOT_REQUIRED

define view C_RO_SAFTReportedItemsLog

  with parameters

    P_StatryRptgEntity           : srf_reporting_entity,
    P_StatryRptCategory          : srf_rep_cat_id,
    P_StatryRptRunID             : srf_report_run_id,
    P_AlternativeGLAccountIsUsed : saft_ro_alt_gl_account_flag

  as select distinct from  P_RO_SAFTJournalEntryItemExc(P_AlternativeGLAccountIsUsed: $parameters.P_AlternativeGLAccountIsUsed) as Document

    inner join             I_RO_SAFTDocumentTypeMap                                                                             as DocType   on  DocType.CompanyCode            = Document.CompanyCode
                                                                                                                                             and DocType.AccountingDocumentType = Document.AccountingDocumentType
  //exclusion by document status

    left outer to one join I_RO_SAFTDocStatusForExclusion                                                                       as StatusExc on  Document.AccountingDocumentCategory = StatusExc.AccountingDocumentCategory
                                                                                                                                             and Document.CompanyCode                = StatusExc.CompanyCode


{
  key $parameters.P_StatryRptgEntity  as StatryRptgEntity,
  key $parameters.P_StatryRptCategory as StatryRptCategory,
  key $parameters.P_StatryRptRunID    as StatryRptRunID,
  key Document.SourceLedger,
  key Document.CompanyCode,
  key Document.FiscalYear,
  key Document.AccountingDocument,
  key Document.Ledger,
      Document.PostingDate,
      Document.ReferenceDocumentType
}
where
  StatusExc.CompanyCode is null

union select distinct from P_RO_SAFTJournalEntryItemExc(P_AlternativeGLAccountIsUsed: $parameters.P_AlternativeGLAccountIsUsed) as Document

  inner join               I_RO_SAFTPaymentMapping                                                                              as PaymentDocType on  PaymentDocType.CompanyCode            = Document.CompanyCode
                                                                                                                                                  and PaymentDocType.AccountingDocumentType = Document.AccountingDocumentType
//exclusion by document status

  left outer to one join   I_RO_SAFTDocStatusForExclusion                                                                       as StatusExc      on  Document.AccountingDocumentCategory = StatusExc.AccountingDocumentCategory
                                                                                                                                                  and Document.CompanyCode                = StatusExc.CompanyCode

{
  key $parameters.P_StatryRptgEntity  as StatryRptgEntity,
  key $parameters.P_StatryRptCategory as StatryRptCategory,
  key $parameters.P_StatryRptRunID    as StatryRptRunID,
  key Document.SourceLedger,
  key Document.CompanyCode,
  key Document.FiscalYear,
  key Document.AccountingDocument,
  key Document.Ledger,
      Document.PostingDate,
      Document.ReferenceDocumentType
}
where
      StatusExc.CompanyCode    is null
  and PaymentDocType.GLAccount = ''


union select distinct from P_RO_SAFTJournalEntryItemExc(P_AlternativeGLAccountIsUsed: $parameters.P_AlternativeGLAccountIsUsed) as Document

  inner join               I_RO_SAFTPaymentMapping                                                                              as PayMap    on  PayMap.CompanyCode            = Document.CompanyCode
                                                                                                                                             and PayMap.AccountingDocumentType = Document.AccountingDocumentType
                                                                                                                                             and PayMap.GLAccount              = Document.ActiveGLAccount


//exclusion by document status

  left outer to one join   I_RO_SAFTDocStatusForExclusion                                                                       as StatusExc on  Document.AccountingDocumentCategory = StatusExc.AccountingDocumentCategory
                                                                                                                                             and Document.CompanyCode                = StatusExc.CompanyCode
{
  key $parameters.P_StatryRptgEntity  as StatryRptgEntity,
  key $parameters.P_StatryRptCategory as StatryRptCategory,
  key $parameters.P_StatryRptRunID    as StatryRptRunID,
  key Document.SourceLedger,
  key Document.CompanyCode,
  key Document.FiscalYear,
  key Document.AccountingDocument,
  key Document.Ledger,
      Document.PostingDate,
      Document.ReferenceDocumentType
}
where
      StatusExc.CompanyCode is null
  and PayMap.GLAccount      <> ''