C_RO_GLAccountLineItemC

@EndUserText.label: 'Romania G/L Account Line Items - Cube'
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@Metadata.allowExtensions:true
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@Analytics.internalName:#LOCAL

define view entity C_RO_GLAccountLineItemC

  as select from           I_GLAccountLineItemRawData   as AccountingDocument

    left outer to one join I_GLAccountInCompanyCode     as AltAcct     on  AccountingDocument.CompanyCode = AltAcct.CompanyCode
                                                                       and AccountingDocument.GLAccount   = AltAcct.GLAccount

    left outer to one join I_GlAccountTextInCompanycode as AltAcctText on  AccountingDocument.CompanyCode = AltAcctText.CompanyCode
                                                                       and AltAcct.AlternativeGLAccount   = AltAcctText.GLAccount
                                                                       and AltAcctText.Language           = $session.system_language

  association [0..1] to I_StRpJournalEntryLog     as _StRpLog  on  $projection.CompanyCode        = _StRpLog.CompanyCode
                                                               and $projection.AccountingDocument = _StRpLog.AccountingDocument
                                                               and $projection.FiscalYear         = _StRpLog.FiscalYear

  association [0..1] to I_OperationalAcctgDocItem as _BsegItem on  $projection.CompanyCode            = _BsegItem.CompanyCode
                                                               and $projection.AccountingDocument     = _BsegItem.AccountingDocument
                                                               and $projection.FiscalYear             = _BsegItem.FiscalYear
                                                               and $projection.AccountingDocumentItem = _BsegItem.AccountingDocumentItem



{
  key AccountingDocument.CompanyCode                                                                                       as CompanyCode,
  key AccountingDocument.SourceLedger                                                                                      as SourceLedger,
  key AccountingDocument.AccountingDocument                                                                                as AccountingDocument,
  key AccountingDocument.LedgerGLLineItem                                                                                  as LedgerGLLineItem,
  key AccountingDocument.FiscalYear                                                                                        as FiscalYear,
  key _StRpLog.StatryRptCategory                                                                                           as StatryRptCategory,
  key _StRpLog.StatryRptRunID                                                                                              as StatryRptRunID,
  key _StRpLog.StatryRptgEntity                                                                                            as StatryRptgEntity,
      AccountingDocument.ReferenceDocumentItem                                                                             as ReferenceDocumentItem,
      AccountingDocument.DocumentDate                                                                                      as DocumentDate,
      AccountingDocument.PostingDate                                                                                       as PostingDate,
      AccountingDocument.FiscalPeriod                                                                                      as FiscalPeriod,
      AccountingDocument.TaxCode                                                                                           as TaxCode,
      AccountingDocument.FinancialAccountType                                                                              as FinancialAccountType,
      cast( case
        when AccountingDocument.Customer is not initial then AccountingDocument.Customer
        else AccountingDocument.Supplier
      end as bu_partner )                                                                                                  as BusinessPartner,
      cast( case
        when AccountingDocument._Customer.Customer is not initial then AccountingDocument._Customer.CustomerName
        else AccountingDocument._Supplier.SupplierName
      end as business_partner_name )                                                                                       as BusinessPartnerName,
      AccountingDocument.GLAccount                                                                                         as GLAccount,
      AccountingDocument._GLAccountInChartOfAccounts._Text[1: Language = $session.system_language ].GLAccountLongName      as GLAccountLongName,
      AccountingDocument.DebitCreditCode                                                                                   as DebitCreditCode,
      AccountingDocument.AccountingDocumentType                                                                            as AccountingDocumentType,
      AccountingDocument.TransactionCurrency                                                                               as TransactionCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      AccountingDocument.AmountInTransactionCurrency                                                                       as AmountInTransactionCurrency,
      AccountingDocument.CompanyCodeCurrency                                                                               as CompanyCodeCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AccountingDocument.AmountInCompanyCodeCurrency                                                                       as AmountInCompanyCodeCurrency,
      AccountingDocument.ClearingAccountingDocument                                                                        as ClearingAccountingDocument,
      AccountingDocument.AccountingDocumentItem                                                                            as AccountingDocumentItem, //buzei

      AccountingDocument.TransactionTypeDetermination                                                                      as TransactionTypeDetermination, //ktosl

      AccountingDocument.SpecialGLCode                                                                                     as SpecialGLCode, //umskz

      _BsegItem.AccountingDocumentItemType                                                                                 as AccountingDocumentItemType, //buzid

      _BsegItem.IsNegativePosting                                                                                          as IsNegativePosting, //xnegp

      AltAcct.AlternativeGLAccount                                                                                         as AlternativeGLAccount,
      AltAcctText.GLAccountLongName                                                                                        as AlternativeGLAccountLongName,
      AccountingDocument._JournalEntry.AccountingDocumentHeaderText                                                        as AccountingDocumentHeaderText, //Explanation

      AccountingDocument._JournalEntry.DocumentReferenceID                                                                 as DocumentReferenceID,          //ID of a reference document

      AccountingDocument._AccountingDocumentType._Text[1: Language = $session.system_language ].AccountingDocumentTypeName as AccountingDocumentTypeName,    //Description of document type

      AccountingDocument._JournalEntry.ReferenceDocumentType                                                               as ReferenceDocumentType //AWTYP

}
where
  AccountingDocument.FiscalPeriod <> '000'