C_REOutputRequestTP

@EndUserText.label: 'Real Estate Output Request'
@AccessControl.authorizationCheck: #MANDATORY
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
@AccessControl: {
                  privilegedAssociations: [ '_OutputRequest' ]
                }
@ObjectModel: {
                usageType: {  serviceQuality:#D,
                              sizeCategory: #L,
                              dataClass: #MIXED
                           }
              }
              
@Metadata.allowExtensions: true
define root view entity C_REOutputRequestTP
  provider contract transactional_query
  as projection on R_REOutputRequestTP as REOutputRequest
  association [1..1] to C_REOutpReqContract         as _REOutputRequestContract   on  $projection.RealEstateContract = _REOutputRequestContract.RealEstateContract
                                                                                  and $projection.CompanyCode        = _REOutputRequestContract.CompanyCode
  association [1..1] to C_REOutpReqProcess          as _REOutputRequestProcess    on  $projection.RealEstateProcess = _REOutputRequestProcess.RealEstateProcess

  association [1..*] to C_REOutpReqAdjustmentRecord as _REOutpReqAdjustmentRecord on  $projection.RealEstateProcess  = _REOutpReqAdjustmentRecord.RealEstateProcess
                                                                                  and $projection.RealEstateContract = _REOutpReqAdjustmentRecord.RealEstateContract
                                                                                  and $projection.CompanyCode        = _REOutpReqAdjustmentRecord.CompanyCode
  association [1..*] to C_REOutpReqInvoice          as _REInvoice                 on  $projection.RealEstateProcess  = _REInvoice.RealEstateProcess
                                                                                  and $projection.RealEstateContract = _REInvoice.RealEstateContract
                                                                                  and $projection.CompanyCode        = _REInvoice.CompanyCode                                                                               
  association [1..*] to C_REOutpReqSalesCalcResult as _REOutpReqSalesCalcResult   on $projection.RealEstateProcess   = _REOutpReqSalesCalcResult.RealEstateProcess
                                                                                  and $projection.RealEstateContract = _REOutpReqSalesCalcResult.RealEstateContract
                                                                                  and $projection.CompanyCode        = _REOutpReqSalesCalcResult.CompanyCode
{
  key     OutputRequestUUID,

          _ApplicationObjectType._Text.OCApplObjectTypeDescription as OCApplObjectTypeDescription : localized,
          @ObjectModel.text.element: [ 'OCApplObjectTypeDescription' ]
          @Consumption.valueHelpDefinition: [ { entity: {name: 'C_REOutpReqApplObjTypeVH', element: 'OutputControlApplObjectType' } } ]
          OutputControlApplObjectType,

          @ObjectModel.filter.enabled: false
          OutputControlApplicationObject,

          @Consumption.valueHelpDefinition: [{   entity: {name: 'I_REContractVH', element: 'RealEstateContract' },
                                  additionalBinding: [ { element: 'CompanyCode', localElement: 'CompanyCode' } ] }]
          @ObjectModel.text.element: ['REContractName']
          @Consumption.semanticObject: 'REContract'
          RealEstateContract,

          @ObjectModel.text.element: ['REProcessDescription']
          @Consumption.valueHelpDefinition: [{entity: {name: 'I_REOutputRequestProcessIdVH', element: 'RealEstateProcess' } }]
          //@Consumption.semanticObject: 'RECostSettlementProcess'

          RealEstateProcess,

          _REProcess.RealEstateProcessExternal,

          @ObjectModel.text.element: ['CompanyCodeName']
          @Consumption.valueHelpDefinition: [
            { entity: {name: 'I_CompanyCodeStdVH', element: 'CompanyCode' },
              additionalBinding: [
                { element: 'CompanyCodeName', localElement: 'CompanyCodeName', usage: #RESULT }
             ]
          }]
          @Consumption.semanticObject: 'CompanyCode'
          @Search.defaultSearchElement: true
          @Search.fuzzinessThreshold : 0.7
          _REContract.CompanyCode                                  as CompanyCode,
          
          REContractType,
          REAuthorizationGroup,
          
          @Consumption.filter.hidden: true
          _REContract.REContractName                               as REContractName, 

          @Consumption.filter.hidden: true
          _CompanyCode.CompanyCodeName                             as CompanyCodeName,

          OutputParameterText,
          CreationDateTime,
          CreatedByUser,
          LastChangeDateTime,
          LastChangedByUser,
          REOutpReqAdjustmentIsHidden,
          REOutpReqInvoiceIsHidden,
          REOutpReqSalesRentIsHidden,
          _REProcess.REProcessDescription,

          @ObjectModel.virtualElement:true
          @ObjectModel.virtualElementCalculatedBy:'ABAP:CL_REOM_F7482_ROOT_CALC_EXIT'
          @Semantics.text: true
  virtual REOutpReqStatusName            : recpoutpreqstatusname,

          @ObjectModel.virtualElement:true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_REOM_F7482_ROOT_CALC_EXIT'
  virtual REOutpReqStatusCriticality     : abap.int1,

          @ObjectModel.virtualElement:true
          @ObjectModel.virtualElementCalculatedBy:'ABAP:CL_REOM_F7482_ROOT_CALC_EXIT'
          @Semantics.text: true
  virtual REOutpReqUserActionName        : recpoutprequseraction,

          @ObjectModel.virtualElement:true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_REOM_F7482_ROOT_CALC_EXIT'
  virtual REOutpReqUserActionCriticality : abap.int1,

          /* Associations */
          _REOutputRequestContract,
          _REOutputRequestProcess,
          _REOutpReqAdjustmentRecord,
          _REInvoice,
          _REOutpReqSalesCalcResult,

          _OutputRequest : redirected to C_OutputRequestStandard
}