C_RAContractPriceAllocationTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_CreatedByUserContactCard' ]

@EndUserText.label: 'Price Allocation RA Contract'

@Metadata.allowExtensions: true

@ObjectModel.semanticKey: [ 'RevenueAccountingContract' ]
@ObjectModel.usageType: { sizeCategory: #XXL, serviceQuality: #C, dataClass: #TRANSACTIONAL }

@Search.searchable: true

@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.viewType: #CONSUMPTION

define root view entity C_RAContractPriceAllocationTP
  provider contract transactional_query
  as projection on R_RevenueAccountingContractTP

{
      @Consumption.semanticObject: 'RevenueAccountingContract'
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
  key RevenueAccountingContract,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      @ObjectModel.text.element: [ 'CompanyCodeName' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      CompanyCode,

      _CompanyCode.CompanyCodeName,


      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_AccountingPrinciple', element: 'AccountingPrinciple' } } ]
      @ObjectModel.text.element: [ 'AccountingPrincipleName' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      AccountingPrinciple,

      _AccountingPrinciple._Text.AccountingPrincipleName                               : localized,

      @Consumption.semanticObject: 'BusinessPartner'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessPartnerVH', element: 'BusinessPartner' } } ]
      @ObjectModel.text.element: [ 'BusinessPartnerName' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7 }
      BusinessPartner,

      _BusinessPartner.BusinessPartnerName,

      @Consumption.semanticObject: 'Customer'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'D_CustomerCVH', element: 'Customer' } } ]
      @ObjectModel.text.element: [ 'CustomerName' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7 }
      Customer,

      _Customer.CustomerName                            as CustomerName,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'C_SalesOrganizationVH', element: 'SalesOrganization' } } ]
      @ObjectModel.text.element: [ 'SalesOrganizationName' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7 }
      RevnAcctgSalesOrganization,

      _SalesOrganization._Text.SalesOrganizationName                                   : localized,

      @Consumption.filter.hidden: true
      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      TotContractualPrcInSlsDocCrcy,

      @Consumption.filter.hidden: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      SalesDocumentCurrency,

      @Consumption.filter.hidden: true
      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      AllocEffctAmountInSalesDocCrcy,

      @Consumption.filter.hidden: true
      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      ContrToBeAllcdAmtInSlsDocCrcy,

      @Consumption.filter.hidden: true
      NumberOfPerformanceObligations,

      RAContractIsManuallyAllocated,

      RAContractHasAllocationEffect,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_RAContractStatusVH', element: 'RevnAcctgContractStatus' } } ]
      @ObjectModel.text.element: [ 'RevnAcctgContractStatusName' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      RevnAcctgContractStatus,

      @Consumption.filter.hidden: true
      _RAContractStatusText.RevnAcctgContractStatusName as RevnAcctgContractStatusName : localized,

      RAContractStatusCriticality,

      RAContractLastSavedDateTime,

      @Consumption.filter.hidden: true
      RevnAcctgContractCreationDate,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_RAContractCreatedByUserVH', element: 'RevnAcctgContractCreatedByUser' } } ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      RevnAcctgContractCreatedByUser,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7 }
      CreatedByUserDescription,

      IsBusinessPurposeCompleted,

      @Consumption.filter.hidden: true
      RAContractCompletionDate,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_RAContractChangedByUserVH', element: 'RAContractLastChangedByUsr' } } ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      RAContractLastChangedByUsr,

      LastChangedByUserDescription,

      @Consumption.filter.selectionType: #INTERVAL
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      RAContractLastChangeDate,

      RAContractIsSetToSystemAlloc,

      RAContrHasMnlPrcAllocConflict,

      RAAttributeHasConflict,

      @Consumption.filter.hidden: true
      PerfOblgnHasSprdgConflict,

      @EndUserText.label: 'Universal Revenue Contract'
      @Feature: 'FINS_TRR_URR_SALES_FROM_STOCK'
      RAContractIsUniversal,

      /* Associations */
      _CreatedByUserContactCard,

      _PerformanceObligation : redirected to composition child C_RAPerfOblgnPrcAllocTP,
      _Mapping               : redirected to composition child C_RAContrPrcAllocMappgOplDocTP,
      _BusinessPartner,
      _Customer

}
where
  RAContractHasAssetsImpairment = ''