C_QualityControlChartTrack

DDL: C_QUALITYCONTROLCHARTTRACK Type: view_entity CONSUMPTION Package: ODATA_QM_INSPECTION_ANALYTICS

Quality Control Chart Track

C_QualityControlChartTrack is a Consumption CDS View that provides data about "Quality Control Chart Track" in SAP S/4HANA. It reads from 2 data sources (I_QualityCtrlChartTrackTP, I_QualityCtrlChartTP) and exposes 18 fields with key fields QualityControlChart, QualityControlChartTrack. It has 2 associations to related views. Part of development package ODATA_QM_INSPECTION_ANALYTICS.

2 data source(s) 18 fields

Data Sources (2)

SourceAliasJoin Type
I_QualityCtrlChartTrackTP _QualityControlChartTrack from
I_QualityCtrlChartTP I_QualityCtrlChartTP inner

Associations (2)

CardinalityTargetAliasCondition
[0..*] C_QltyControlChartTrackValue _ControlChartTrackValue $projection.QualityControlChart = _ControlChartTrackValue.QualityControlChart and $projection.QualityControlChartTrack = _ControlChartTrackValue.QualityControlChartTrack
[1..1] I_QltyControlChartTypeTrack _QltyControlChartTypeTrack $projection.QualityControlChartType = _QltyControlChartTypeTrack.QualityControlChartType and $projection.QualityControlChartTrack = _QltyControlChartTypeTrack.QualityControlChartTrack

Annotations (6)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Quality Control Chart Track view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view

Fields (18)

KeyFieldSource TableSource FieldDescription
KEY QualityControlChart I_QualityCtrlChartTrackTP QualityControlChart
KEY QualityControlChartTrack I_QualityCtrlChartTrackTP QualityControlChartTrack
QualityControlChartType I_QualityCtrlChartTP QualityControlChartType
QltyCtrlChartTrackShowLimits _QltyControlChartTypeTrack QltyCtrlChartTrackShowLimits
QltyControlChartTypeTrackText
CtrlChartMeanValue I_QualityCtrlChartTrackTP CtrlChartMeanValue
CtrlChartUpperActionLimit I_QualityCtrlChartTrackTP CtrlChartUpperActionLimit
CtrlChartLowerActionLimit I_QualityCtrlChartTrackTP CtrlChartLowerActionLimit
CtrlChartUpperWarningLimit I_QualityCtrlChartTrackTP CtrlChartUpperWarningLimit
CtrlChartLowerWarningLimit I_QualityCtrlChartTrackTP CtrlChartLowerWarningLimit
CtrlChartHasMeanValue I_QualityCtrlChartTrackTP CtrlChartHasMeanValue
CtrlChartHasUpperActionLimit I_QualityCtrlChartTrackTP CtrlChartHasUpperActionLimit
CtrlChartHasLowerActionLimit I_QualityCtrlChartTrackTP CtrlChartHasLowerActionLimit
CtrlChartHasUpperWarningLimit I_QualityCtrlChartTrackTP CtrlChartHasUpperWarningLimit
CtrlChartHasLowerWarningLimit I_QualityCtrlChartTrackTP CtrlChartHasLowerWarningLimit
Plant I_QualityCtrlChartTrackTP Plant
QltyCtrlChartAggrgnCriterion I_QualityCtrlChartTrackTP QltyCtrlChartAggrgnCriterion
_ControlChartTrackValue _ControlChartTrackValue 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Quality Control Chart Track'

@ObjectModel: {
    usageType: { serviceQuality: #C, sizeCategory: #S, dataClass: #MIXED },
    semanticKey:  [ 'QualityControlChart', 'QualityControlChartTrack']
}

@VDM.viewType: #CONSUMPTION


define view entity C_QualityControlChartTrack
  as select from I_QualityCtrlChartTrackTP as _QualityControlChartTrack
    inner join   I_QualityCtrlChartTP on _QualityControlChartTrack.QualityControlChart = I_QualityCtrlChartTP.QualityControlChart

  association [0..*] to C_QltyControlChartTrackValue as _ControlChartTrackValue    on  $projection.QualityControlChart      = _ControlChartTrackValue.QualityControlChart
                                                                                   and $projection.QualityControlChartTrack = _ControlChartTrackValue.QualityControlChartTrack
  association [1..1] to I_QltyControlChartTypeTrack  as _QltyControlChartTypeTrack on  $projection.QualityControlChartType  = _QltyControlChartTypeTrack.QualityControlChartType
                                                                                   and $projection.QualityControlChartTrack = _QltyControlChartTypeTrack.QualityControlChartTrack
{
  key _QualityControlChartTrack.QualityControlChart,
  key _QualityControlChartTrack.QualityControlChartTrack,
      I_QualityCtrlChartTP.QualityControlChartType,
      _QltyControlChartTypeTrack.QltyCtrlChartTrackShowLimits,
      @UI:{
          lineItem: [{position:10,importance: #HIGH, qualifier: 'StatisticalInfo' }]
      }
      _QltyControlChartTypeTrack._Text[1:Language=$session.system_language].QltyControlChartTypeTrackText,
      @UI:{
          lineItem: [{position:20,importance: #HIGH, qualifier: 'StatisticalInfo' }]
      }
      _QualityControlChartTrack.CtrlChartMeanValue,

      @UI:{
          lineItem: [{position:30,importance: #HIGH, qualifier: 'StatisticalInfo' }]
      }
      _QualityControlChartTrack.CtrlChartUpperActionLimit,
      @UI:{
          lineItem: [{position:40,importance: #HIGH, qualifier: 'StatisticalInfo' }]
      }
      _QualityControlChartTrack.CtrlChartLowerActionLimit,
      @UI:{
          lineItem: [{position:50,importance: #HIGH, qualifier: 'StatisticalInfo' }]
      }
      _QualityControlChartTrack.CtrlChartUpperWarningLimit,
      @UI:{
          lineItem: [{position:60,importance: #HIGH, qualifier: 'StatisticalInfo'}]
      }
      _QualityControlChartTrack.CtrlChartLowerWarningLimit,

      _QualityControlChartTrack.CtrlChartHasMeanValue,
      _QualityControlChartTrack.CtrlChartHasUpperActionLimit,
      _QualityControlChartTrack.CtrlChartHasLowerActionLimit,
      _QualityControlChartTrack.CtrlChartHasUpperWarningLimit,
      _QualityControlChartTrack.CtrlChartHasLowerWarningLimit,


      /*fields are exposed for DCL */
      @ObjectModel.readOnly:true
      @UI.hidden: true
      _QualityControlChartTrack.Plant,
      @ObjectModel.readOnly:true
      @UI.hidden: true
      _QualityControlChartTrack.QltyCtrlChartAggrgnCriterion,

      //Associations

      _ControlChartTrackValue
}

Learn More