C_QltyTaskProcessDefectInfo

@AbapCatalog.sqlViewName: 'CQLTYTSKPRCDINFO'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Defect Information for Quality Task'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    semanticKey:  [ 'Defect' ],
    representativeKey: 'DefectInternalID',
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #S,
        serviceQuality: #C },

// Begin Draft 2.0

    compositionRoot: false,
    transactionalProcessingDelegated: true, //true get field control calculation from I_Defect_TP

    draftEnabled:  false,
    createEnabled: false,
    updateEnabled: false,
    deleteEnabled: false
}

@Consumption.semanticObject: 'QualityTask'
@Metadata.allowExtensions: true

define view C_QltyTaskProcessDefectInfo as select from I_Defect_TP 

    association [0..1] to C_QltyTaskProcDefectInfoLongT as _QltyTaskProcDefectInfoLongT on  $projection.DefectInternalID  = _QltyTaskProcDefectInfoLongT.DefectInternalID and
                                                                                            $projection.MasterLanguage    = _QltyTaskProcDefectInfoLongT.Language                                                                

{
// Keys

key DefectInternalID,

// Fields

    @ObjectModel:{  readOnly: true,
                    text.element:  [ 'DefectText' ]     
    }
    @Consumption:{ semanticObject: 'Defect' }
    // UX Inc

    @Consumption.valueHelpDefinition: [ 
    { entity: { name:    'I_DefectVH',
                element: 'Defect' }
    }]
    Defect,
    
    @ObjectModel.text.element: [ 'DefectCategoryText' ]
    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    DefectCategory,
    
    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    _DefectCategory._Text[1: Language = $session.system_language].DefectCategoryText,

    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    @Semantics.text: true
    DefectText,

    @ObjectModel.text.element: [ 'DefectLifecycleStatusText' ]
    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    DefectLifecycleStatus,
    
    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    _DefectStatus._DefectStatusText[1: Language = $session.system_language].DefectLifecycleStatusText,

    @ObjectModel.text.element: [ 'DefectCodeGroupText' ]
    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    DefectCodeGroup,
    
    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    _DefectCodeGroup._Text[1: Language = $session.system_language].DefectCodeGroupText,

    @ObjectModel.text.element: [ 'DefectCodeText' ]
    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    DefectCode,
    
    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    _DefectCode._Text[1: Language = $session.system_language].DefectCodeText,

    @ObjectModel: { readOnly: true,
                    enabled: 'EXTERNAL_CALCULATION' }
    @Consumption.filter.hidden: true
    QualityIssueReference,

    @Consumption.hidden: true
    Plant,

    @Consumption.hidden: true
    MasterLanguage,
    
    @ObjectModel.readOnly: true
    @Consumption.filter.hidden: true
    _QltyTaskProcDefectInfoLongT.DefectLongText,

//  Fields for authorization check

    @Consumption.hidden: true
    WorkCenterTypeCode,
    @Consumption.hidden: true
    MainWorkCenterInternalID,
    @Consumption.hidden: true
    MainWorkCenter,
    @Consumption.hidden: true
    MainWorkCenterPlant,
    @Consumption.hidden: true
    InspectionLot,

//  Associations

    @Consumption.filter.hidden: true
    _DefectCategory, 
    @Consumption.filter.hidden: true
    _DefectCodeGroup,
    @Consumption.filter.hidden: true
    _DefectCode,
    @Consumption.filter.hidden: true    
    _DefectStatus,
    @Consumption.filter.hidden: true
    _Plant,
    @Consumption.filter.hidden: true
    @Consumption.hidden: true
    _InspectionLot,
    @Consumption.filter.hidden: true
    _QltyTaskProcDefectInfoLongT
}