C_QA_BPIdentificationType

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Qatar BP identification'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #D,
    sizeCategory: #L,
    dataClass: #MIXED
}
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@VDM.viewType: #CONSUMPTION
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity C_QA_BPIdentificationType
  as select from           I_BusinessPartner
    left outer to one join C_QA_BPIdentificationTypeNmbr as idtype_1 on  I_BusinessPartner.BusinessPartner = idtype_1.BusinessPartner
                                                                     and idtype_1.BPIdentificationType     = 'YTIN'

    left outer to one join I_BuPaIdentification          as idtype_2 on  I_BusinessPartner.BusinessPartner = idtype_2.BusinessPartner
                                                                     and idtype_2.BPIdentificationType     = 'SE30'

    left outer to one join I_BuPaIdentification          as idtype_3 on  I_BusinessPartner.BusinessPartner = idtype_3.BusinessPartner
                                                                     and idtype_3.BPIdentificationType     = 'SE40'

    left outer to one join I_BuPaIdentification          as idtype_4 on  I_BusinessPartner.BusinessPartner = idtype_4.BusinessPartner
                                                                     and idtype_4.BPIdentificationType     = 'FS0002'

{
  key I_BusinessPartner.BusinessPartner,
      case
      when I_BusinessPartner.BusinessPartner is not null then
      coalesce( idtype_1.BPIdentificationType,
              coalesce( idtype_2.BPIdentificationType, coalesce( idtype_3.BPIdentificationType, idtype_4.BPIdentificationType)))
      end                                 as BPIdentificationType,

      case
       when I_BusinessPartner.BusinessPartner is not null then
        coalesce( idtype_1.BPIdentificationNumber,
                  coalesce( idtype_2.BPIdentificationNumber, coalesce( idtype_3.BPIdentificationNumber, idtype_4.BPIdentificationNumber)))
      end                                 as BPIdentificationNumber,
      I_BusinessPartner.DataControllerSet as DataControllerSet,
      I_BusinessPartner.DataController1   as DataController1,
      I_BusinessPartner.DataController2   as DataController2,
      I_BusinessPartner.DataController3   as DataController3,
      I_BusinessPartner.DataController4   as DataController4,
      I_BusinessPartner.DataController5   as DataController5,
      I_BusinessPartner.DataController6   as DataController6,
      I_BusinessPartner.DataController7   as DataController7,
      I_BusinessPartner.DataController8   as DataController8,
      I_BusinessPartner.DataController9   as DataController9,
      I_BusinessPartner.DataController10  as DataController10
}