C_PurgSpendOffContract

@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality:  #D
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.sqlViewName: 'CMMSPNDCNTRCT'
//Commented by VDM CDS Suite Plugin:@ClientDependent: true

@VDM.viewType: #CONSUMPTION
@Analytics.query: true
@OData.publish: true
@EndUserText.label: 'Off Contract Spend'
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations:true 
@ObjectModel.supportedCapabilities: [#ANALYTICAL_QUERY]
@ObjectModel.modelingPattern: #ANALYTICAL_QUERY
define view C_PurgSpendOffContract

  with parameters
    @Consumption.defaultValue: 'EUR' 
    @Consumption.valueHelpDefinition: [{
      entity: {
        name:'I_Currency',
        element:'Currency'
      }
    }]
    P_DisplayCurrency           : displaycurrency,

    @Consumption.hidden : true
    @Environment.systemField : #SYSTEM_LANGUAGE
    P_Language                  : sylangu,

    @Consumption.derivation: { lookupEntity: 'C_SglGregorianCalDateFunction', 
    resultElement: 'DateFunctionStartDate', binding: [ {
      targetParameter: 'P_DateFunction', type: #PARAMETER, value : 'P_DateFunction' },
       { targetParameter : 'P_Language' , type : #SYSTEM_FIELD, value : '#SYSTEM_LANGUAGE'  } ] 
    } 
    @Consumption.hidden: true
    P_StartDate: bedat,
    
    @Consumption.derivation: { lookupEntity: 'C_SglGregorianCalDateFunction', 
    resultElement: 'DateFunctionEndDate', binding: [ {
      targetParameter: 'P_DateFunction', type: #PARAMETER, value : 'P_DateFunction' },
       { targetParameter : 'P_Language' , type : #SYSTEM_FIELD, value : '#SYSTEM_LANGUAGE'  } ] 
    } 
    @Consumption.hidden: true
    P_EndDate: bedat,
    @Consumption.defaultValue: 'PREVIOUSYEARTODATE'
    @Consumption.valueHelpDefinition: [{
      entity: {
        name:'C_GregorianCalDateFuncVH',
        element:'DateFunction'
      }
    }]
    P_DateFunction              : datefunctionid 
    
  as select from C_PurgSpendOffContract2(
                 P_DisplayCurrency : $parameters.P_DisplayCurrency,
                 P_StartDate  : $parameters.P_StartDate,
                 P_EndDate   : $parameters.P_EndDate )

{
      /* keys */
  key PurchaseOrder,
  key PurchaseOrderItem,
  key AccountAssignmentNumber,
  
  
  
  @Consumption: {
                  filter: {                    -- Usage of derviation.lookupEntity requires a filter definition too!
                            mandatory: false,
                            hidden: true,
                            selectionType: #SINGLE,
                            multipleSelections: false
                          },                  
                  derivation: {
                                lookupEntity: 'F_ProcmtAnalyticsDataSelMeth',
                                resultElement: 'PurgDocMigrtnIsCmpltdForAnlyts'
                              }
                }
 
  @Consumption.hidden : true
  PurgDocMigrtnIsCmpltdForAnlyts,
      /* Supplier */

      Supplier,
      _Supplier.SupplierName,
      
      SupplierCountry,
      @Semantics.text: true
      _Country._Text[1: Language = $parameters.P_Language].CountryName,

      /* Order Date */
      @EndUserText.label: 'Purchase Order Date'
      PurchaseOrderDate,
      CalendarYear,
      CalendarMonth,
      CalendarQuarter,
      CalendarWeek,

      CreatedByUser,

      /* Header */
      PurchasingOrganization,
      _PurchasingOrganization.PurchasingOrganizationName,
      PurchasingGroup,
      _PurchasingGroup.PurchasingGroupName,
    
      @EndUserText.label: 'Receiving Plant Company Code'
      @EndUserText.quickInfo: 'Receiving Plant Company Code'           
      CompanyCode,  
      @EndUserText.label: 'Receiving Plant Company Code Name'
      @EndUserText.quickInfo: 'Receiving Plant Company Code Name'                                         
      @Semantics.text: true                                 
      _CompanyCode.CompanyCodeName as ReceivingCompanyCode,                         
      
      @EndUserText.label: 'Company Code'  
      @EndUserText.quickInfo: 'Company Code'            
      PurgDocHdrCompanyCode,                                          
      @Semantics.text: true  
      @EndUserText.label: 'Company Code Name'  
      @EndUserText.quickInfo: 'Company Code Name'                               
      _CompanyCode.CompanyCodeName, 
      
      @EndUserText.label: 'Document Type'
      PurchaseOrderType,
      @Semantics.text: true
      _PurchasingDocumentType._Text[1: Language = $session.system_language].PurchasingDocumentTypeName as PurchasingDocumentTypeName,
      
      @EndUserText.label: 'Item Category'
      PurchaseOrderItemCategory,
      @Semantics.text: true
      _PurgDocumentItemCategory._Text[1: Language = $session.system_language].PurgDocItemCategoryName, 
      

      /* Line Item Data */
            
      //@ObjectModel.text.element: ['MaterialName'] //Inserted by VDM CDS Suite Plugin


      //Commented by VDM CDS Suite Plugin:@Consumption.labelElement: 'MaterialName'

      //Commented by VDM CDS Suite Plugin:

      Material,
      @Semantics.text: true
      _Material._Text[1: Language = $session.system_language].MaterialName,

//      @ObjectModel.text.element: ['MaterialGroupName'] //Inserted by VDM CDS Suite Plugin


      //Commented by VDM CDS Suite Plugin:@Consumption.labelElement: 'MaterialGroupName'

      //Commented by VDM CDS Suite Plugin:

      MaterialGroup,
      @Semantics.text: true
      _MaterialGroup._Text[1: Language = $session.system_language].MaterialGroupName as MaterialGroupName,

 //     @ObjectModel.text.element: ['PlantName'] //Inserted by VDM CDS Suite Plugin


      //Commented by VDM CDS Suite Plugin:@Consumption.labelElement: 'PlantName'

      //Commented by VDM CDS Suite Plugin:

      Plant,
      @Semantics.text: true
      _Plant.PlantName,

      @ObjectModel.text.element: ['PurgCatName']
      @Consumption.labelElement: 'PurgCatName'
      PurchasingCategory,
      @Semantics.text: true
      PurgCatName,

      CostCenter,
      WBSElementInternalID,

      @Semantics.currencyCode: true
      DisplayCurrency,

      /* Measures */
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      PurchaseOrderAmount,

      @Semantics.amount.currencyCode: 'DisplayCurrency'
      AmtWithContractRefInDspCrcy,

      @Semantics.amount.currencyCode: 'DisplayCurrency'
      AmtWithoutContractRefInDspCrcy,
      
//      Below annotation has been commented out since the field representation term is 'Ratio' and annotation mismatches.      

//      @Semantics.amount.currencyCode: 'DisplayCurrency'

      @DefaultAggregation: #FORMULA
      @AnalyticsDetails.query.formula: 'CASE WHEN $projection.PurchaseOrderAmount > 0 THEN  $projection.AmtWithoutContractRefInDspCrcy / $projection.PurchaseOrderAmount ELSE 0 END'
      @EndUserText.label: 'Off Contract Spend %'
      1                                                                            as NonContractPurchaseRatio,
      
      @AnalyticsDetails.query.decimals: 0
//      Below annotation has been commented out since the field representation term is 'Rate' and annotation mismatches.

//      @Semantics.amount.currencyCode: 'DisplayCurrency'

      @DefaultAggregation: #FORMULA
      @AnalyticsDetails.query.formula:  '$projection.NonContractPurchaseRatio * 100 '
      @EndUserText.label: 'Off Contract Spend In Percentage'
      1                                                                            as NonContractPurchaseRateInPct

}