C_PurchaseOrderSpend

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #CONSUMPTION
@Analytics.dataCategory: #CUBE
@Metadata.allowExtensions: true
@Analytics.technicalName: 'CMMPURORDSPND'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Purchase Order Spend'
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_PROVIDER  ]
@ObjectModel.modelingPattern: #ANALYTICAL_CUBE
define view entity C_PurchaseOrderSpend

  with parameters

    P_DisplayCurrency : displaycurrency,

    P_StartDate       : bedat,

    P_EndDate         : bedat

  as select from    P_PurOrdItemAcctAssgmt( P_DisplayCurrency: $parameters.P_DisplayCurrency,
                                            P_StartDate : $parameters.P_StartDate,
                                            P_EndDate : $parameters.P_EndDate ) as PurchaseOrder

    left outer join I_PurchasingCategoryMatlGroup                               as PurchasingCategoryMatlGroup on PurchaseOrder.MaterialGroup = PurchasingCategoryMatlGroup.MaterialGroup

  association [1..1] to P_Purordmaintaincustproj   as _WBSElement               on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [1..1] to I_PurchasingOrganization   as _PurchasingOrganization   on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
  //association [1..1] to I_Material                 as _MaterialText             on $projection.Material = _MaterialText.Material

  association [1..1] to I_MaterialGroup            as _MaterialGroup            on $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [1..1] to I_PurchasingDocumentStatus as _PurchasingDocumentStatus on $projection.PurchasingDocumentStatus = _PurchasingDocumentStatus.PurchasingDocumentStatus

{
      /* Keys */
  key PurchaseOrder.PurchaseOrder,
  key PurchaseOrder.PurchaseOrderItem,
  key PurchaseOrder.AccountAssignmentNumber,

      PurchasingCategoryMatlGroup.PurgCatUUID,
      //@Analytics.internalName: #LOCAL

      //@ObjectModel.foreignKey.association: '_Supplier'

      PurchaseOrder.Supplier,
      //@Analytics.internalName: #LOCAL

      //@ObjectModel.foreignKey.association: '_Country'

      PurchaseOrder.SupplierCountry,

      /* Order Date */

      PurchaseOrder.PurchaseOrderDate,
      @Semantics.calendar.year: true
      PurchaseOrder.CalendarYear,
      PurchaseOrder.CalendarQuarter,
      PurchaseOrder.CalendarMonth,
      PurchaseOrder.CalendarWeek,
      PurchaseOrder.YearQuarter,

      /* Header */
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchaseOrder.PurchasingOrganization,
      PurchaseOrder.CompanyCode,

      //@Analytics.internalName: #LOCAL

      //@ObjectModel.foreignKey.association: '_PurchasingGroup'

      PurchaseOrder.PurchasingGroup,
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_PurchasingDocumentStatus'
      PurchaseOrder.PurchasingDocumentStatus,

      /* Item Data */
      //@Analytics.internalName: #LOCAL

      //@ObjectModel.foreignKey.association: '_MaterialText'

      PurchaseOrder.Material,
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      PurchaseOrder.MaterialGroup,
      //@Analytics.internalName: #LOCAL

      //@ObjectModel.foreignKey.association: '_Plant'

      PurchaseOrder.Plant,

      PurchaseOrder.ProductType                                           as ProductTypeCode,

      PurchaseOrder.ServicePerformer,

      PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory  as PurchasingCategory,
      PurchasingCategoryMatlGroup._PurchasingCategory.PurgCatName         as PurgCatName,

      PurchaseOrder.WBSElementInternalID,
      PurchaseOrder.WBSElement,
      PurchaseOrder.WBSDescription,
      _WBSElement.CustomerProjectName,
      _WBSElement.CustProjWorkPackageName,

      PurchaseOrder.CostCenter,

      cast( $parameters.P_DisplayCurrency as displaycurrency )            as DisplayCurrency,

      /* Order Amount*/
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      @DefaultAggregation: #SUM
      cast(PurchaseOrder.PurOrdNetAmountInDisplayCrcy as abap.curr(21,2)) as PurOrdNetAmountInDisplayCrcy,

      _PurchasingOrganization,
      _PurchasingDocumentStatus,
      _MaterialGroup
}