@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CPURORDCOMMIT'
@EndUserText.label: 'Commitments of Purchase Order'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ObjectModel: {
transactionalProcessingDelegated: false,
semanticKey: ['PurchaseOrder', 'PurchaseOrderItem', 'AccountAssignmentNumber' ],
createEnabled: false,
updateEnabled: false,
deleteEnabled: false
}
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.text.control:#ASSOCIATED_TEXT_UI_HIDDEN
@Search.searchable: false
@UI.headerInfo:{
typeName: 'Commitment',
typeNamePlural: 'Commitments',
title: {value: 'Purchase Order Commitments'}
}
define view C_PurchaseOrderCommitment
as select from P_PurchaseOrderCommitment as PurchaseOrderCommitment
association [0..1] to I_MM_GLAccountVH as _GLAccount on $projection.GLAccount = _GLAccount.GLAccount
and $projection.CompanyCode = _GLAccount.CompanyCode
association [0..1] to I_MM_ControllingAreaVH as _ControllingAreaValueHelp on $projection.ControllingArea = _ControllingAreaValueHelp.ControllingArea
association [0..1] to I_PubSecBudgetAccountStdVH as _PubSecBudgetAccountStd on _PubSecBudgetAccountStd.PubSecBudgetAccount = $projection.PubSecBudgetAccount
and _PubSecBudgetAccountStd.PubSecBudgetAccountCoCode = $projection.PubSecBudgetAccountCoCode
association [0..1] to I_PubSecBdgtCnsmpnType as _PubSecBdgtCnsmpnType on _PubSecBdgtCnsmpnType.PubSecBudgetCnsmpnType = $projection.PubSecBudgetCnsmpnType
{
@UI.hidden: true
@Consumption.filter.hidden: true
@ObjectModel.foreignKey.association: '_PurchaseOrderTP'
key cast (PurchasingDocument as vdm_purchaseorder preserving type) as PurchaseOrder,
@UI.lineItem: [{position: 20 }]
key PurchasingDocumentItem as PurchaseOrderItem,
@UI.lineItem: [{position: 30 }]
key cast(AccountAssignmentNumber as dzekkn_ll preserving type ) as AccountAssignmentNumber,
key SourceReferenceDocSubitem,
@ObjectModel.text.element: [ 'SegmentName' ]
key Segment,
@UI.lineItem: [{position: 60 }]
@ObjectModel.foreignKey.association: '_GLAccount'
@Consumption.valueHelpDefinition: [{ entity:{ name : 'I_MM_GLAccountVH', element: 'GLAccount'},
additionalBinding: [{ localElement: 'CompanyCode',
element: 'CompanyCode' }]
}]
key PurchaseOrderCommitment.GLAccount,
@UI.lineItem: [{position: 70 }]
@Consumption.valueHelp: '_ControllingAreaValueHelp'
@ObjectModel.foreignKey.association: '_ControllingAreaValueHelp'
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
key ControllingArea,
@UI.lineItem: [{position: 80}]
@ObjectModel.foreignKey.association: '_FunctionalArea'
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_FNDSMGMTFUNCNLAREASTDVH', element: 'FunctionalArea' } }]
key PurchaseOrderCommitment.FunctionalArea,
@UI.lineItem: [{position: 90,importance: #HIGH}]
@ObjectModel.text.element: [ 'CompanyCodeName' ]
key PurchaseOrderCommitment.CompanyCode,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_MM_GLAccountVH',
element: 'GLAccount' },
additionalBinding: [{ localElement: 'CompanyCode',
element: 'CompanyCode' }]
}]
@ObjectModel.text.element: [ 'GLAccountName' ]
key PurchaseOrderCommitment.CashLedgerAccount,
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_FundStdVH', element: 'Fund' } }]
@ObjectModel.text.element: [ 'FundName' ]
key PurchaseOrderCommitment.Fund,
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_GrantStdVH', element: 'GrantID' } }]
@ObjectModel.text.element: [ 'GrantName' ]
key PurchaseOrderCommitment.GrantID,
@Consumption.valueHelpDefinition: [{ entity: { name : 'I_BudgetPeriodStdVH', element: 'BudgetPeriod' } }]
@ObjectModel.text.element: [ 'BudgetPeriodName' ]
key PurchaseOrderCommitment.BudgetPeriod,
key PurchaseOrderCommitment.FiscalYearPeriod,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_PubSecBudgetAccountStdVH',
element: 'PubSecBudgetAccount' },
additionalBinding: [{ localElement: 'PubSecBudgetAccountCoCode',
element: 'PubSecBudgetAccountCoCode' }]
}]
@ObjectModel.text.element: [ 'BudgetAccountName' ]
key PurchaseOrderCommitment.PubSecBudgetAccount,
@UI.hidden: true
@Consumption.filter.hidden: true
key PurchaseOrderCommitment.PubSecBudgetAccountCoCode,
key PurchaseOrderCommitment.PubSecBudgetIsRelevant,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'I_PubSecBdgtCnsmpnType',
element: 'PubSecBudgetCnsmpnType' }
}]
@ObjectModel.text.element: [ 'PubSecBudgetCnsmpnTypeText' ]
key PurchaseOrderCommitment.PubSecBudgetCnsmpnType,
@ObjectModel.text.element: [ 'CostCenterName' ]
key PurchaseOrderCommitment.CostCenter,
@ObjectModel.text.element: [ 'ProfitCenterName' ]
key PurchaseOrderCommitment.ProfitCenter,
@UI.hidden
@Consumption.filter.hidden: true
key PurchaseOrderCommitment.WBSElementInternalID,
@ObjectModel.text.element: [ 'WBSDescription' ]
key PurchaseOrderCommitment.WBSElement,
@ObjectModel.text.element: [ 'AccountAssignmentTypeName' ]
key PurchaseOrderCommitment.AccountAssignmentType,
key PurchaseOrderCommitment.AccountAssignment,
@ObjectModel.text.element: [ 'SponsoredProgramName' ]
key PurchaseOrderCommitment.SponsoredProgram,
@ObjectModel.text.element: [ 'SponsoredClassName' ]
key PurchaseOrderCommitment.SponsoredClass,
@Semantics.currencyCode: true
key TransactionCurrency,
@UI.hidden: true
@Consumption.filter.hidden: true
_CompanyCodeText .CompanyCodeName,
@UI.hidden: true
@Consumption.filter.hidden: true
_FundText [1: Language = $session.system_language].FundName,
@UI.hidden: true
@Consumption.filter.hidden: true
_Grant._Text [1: Language = $session.system_language].GrantName,
@UI.hidden: true
@Consumption.filter.hidden: true
_SponsoredClass._Text [1: Language = $session.system_language].SponsoredClassName,
@UI.hidden: true
@Consumption.filter.hidden: true
_SponsoredProgram._Text [1: Language = $session.system_language].SponsoredProgramName,
@UI.hidden: true
@Consumption.filter.hidden: true
_PubSecBudgetAccount._BudgetAccountText[1: Language = $session.system_language].BudgetAccountName,
@UI.hidden: true
@Consumption.filter.hidden: true
_BudgetPeriodText [1: Language = $session.system_language].BudgetPeriodName,
@UI.hidden: true
@Consumption.filter.hidden: true
_PubSecBudgetCnsmpnType._Text [1: Language = $session.system_language].PubSecBudgetCnsmpnTypeText,
@UI.hidden: true
@Consumption.filter.hidden: true
_CostCenterText [1: Language = $session.system_language and ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date].CostCenterName,
@UI.hidden: true
@Consumption.filter.hidden: true
_ProfitCenterText [1: Language = $session.system_language and ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date].ProfitCenterName ,
@UI.hidden: true
@Consumption.filter.hidden: true
_SegmentText [1: Language = $session.system_language].SegmentName,
@UI.hidden: true
@Consumption.filter.hidden: true
_WBSElementBasicDataText .WBSDescription,
@UI.hidden: true
@Consumption.filter.hidden: true
_AccountAssignmentType._Text [1: Language = $session.system_language].AccountAssignmentTypeName,
@UI.hidden: true
@Consumption.filter.hidden: true
_CashLedgerAccount._Text [1: Language = $session.system_language].GLAccountName,
@Consumption.hidden: true
PurchasingOrganization,
@Consumption.hidden: true
PurchasingGroup,
@Consumption.hidden: true
PurchaseOrderType,
@UI.lineItem: [{position: 40 }]
PurchaseOrderCommitment.PurchaseOrderItemText as DocumentItemText,
@UI.lineItem: [{position: 50 }]
@Semantics.amount.currencyCode: 'TransactionCurrency'
cast (AmountInTransactionCurrency as fis_wsl_ll preserving type ) as AmountInTransactionCurrency,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
cast(AmountInCompanyCodeCurrency as fis_hsl_ll preserving type ) as AmountInCompanyCodeCurrency,
@Semantics.currencyCode: true
CompanyCodeCurrency,
// @Semantics: { unitOfMeasure: true }
// BaseUnit,
// @UI.lineItem: [{position: 60 }]
// @Semantics: { quantity.unitOfMeasure: 'BaseUnit' }
// @ObjectModel.readOnly: true
// @ObjectModel.mandatory: true
// cast (PlannedQuantity as poacctassgmtplannedquantity preserving type ) as PlannedQuantity,
@Semantics.amount.currencyCode: 'GlobalCurrency'
cast(AmountInGlobalCurrency as fis_ksl_ll preserving type ) as AmountInGlobalCurrency,
@Semantics.currencyCode: true
GlobalCurrency,
@UI.hidden: true
IsCommitment,
@Consumption.filter.hidden: true
_ControllingAreaValueHelp,
@Consumption.filter.hidden: true
PurchaseOrderCommitment._FunctionalArea,
@Consumption.filter.hidden: true
_PubSecBudgetAccountStd,
@Consumption.filter.hidden: true
_PubSecBdgtCnsmpnType,
@Consumption.filter.hidden: true
_GLAccount
}