C_PurOrderPartnerFactSheet

DDL: C_PURORDERPARTNERFACTSHEET SQL: CPURORDFPTNR Type: view CONSUMPTION Package: ODATA_MM_PUR_ORDER_FS

Purchase Order Partner Fact Sheet

C_PurOrderPartnerFactSheet is a Consumption CDS View that provides data about "Purchase Order Partner Fact Sheet" in SAP S/4HANA. It reads from 1 data source (R_PurchaseOrderPartner) and exposes 23 fields with key fields PurchaseOrder, PartnerFunction, PurchasingOrganization, SupplierSubrange, Plant. Part of development package ODATA_MM_PUR_ORDER_FS.

1 data source(s) 23 fields

Data Sources (1)

SourceAliasJoin Type
R_PurchaseOrderPartner PurchaseOrderPartner from

Annotations (12)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #CONSUMPTION view
AbapCatalog.sqlViewName CPURORDFPTNR view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.representativeKey PurchaseOrder view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MIXED view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Purchase Order Partner Fact Sheet view

Fields (23)

KeyFieldSource TableSource FieldDescription
KEY PurchaseOrder R_PurchaseOrderPartner PurchaseOrder
KEY PartnerFunction R_PurchaseOrderPartner PartnerFunction
KEY PurchasingOrganization R_PurchaseOrderPartner PurchasingOrganization
KEY SupplierSubrange R_PurchaseOrderPartner SupplierSubrange
KEY Plant R_PurchaseOrderPartner Plant
KEY PartnerCounter R_PurchaseOrderPartner PartnerCounter
CreatedByUser R_PurchaseOrderPartner CreatedByUser
CreationDate R_PurchaseOrderPartner CreationDate
PartnerFunctionName
PurchasingDocumentPartnerType R_PurchaseOrderPartner PurchasingDocumentPartnerType
Supplier R_PurchaseOrderPartner Supplier
SupplierHierarchyCategory R_PurchaseOrderPartner SupplierHierarchyCategory
SupplierContact R_PurchaseOrderPartner SupplierContact
PersonWorkAgreement R_PurchaseOrderPartner PersonWorkAgreement
DefaultPartner R_PurchaseOrderPartner DefaultPartner
_PartnerFunction R_PurchaseOrderPartner _PartnerFunction
_PartnerFunctionText R_PurchaseOrderPartner _PartnerFunctionText
_PersonWorkAgreement R_PurchaseOrderPartner _PersonWorkAgreement
_Plant R_PurchaseOrderPartner _Plant
_PurchasingOrganization R_PurchaseOrderPartner _PurchasingOrganization
_Supplier R_PurchaseOrderPartner _Supplier
_SupplierContact R_PurchaseOrderPartner _SupplierContact
_PurchaseOrder _PurchaseOrder 
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CPURORDFPTNR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel: {
    semanticKey: [ 'PurchaseOrder' ],
    representativeKey: 'PurchaseOrder',
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #M,
    usageType.dataClass: #MIXED
}
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Purchase Order Partner Fact Sheet'
define view C_PurOrderPartnerFactSheet
  as select from R_PurchaseOrderPartner as PurchaseOrderPartner
{
             @UI.hidden: true
  key        PurchaseOrderPartner.PurchaseOrder,
             @ObjectModel.readOnly: true
             @Consumption.valueHelpDefinition: [{entity: {name: 'I_PurOrderPartnerFunctionVH', element: 'PartnerFunction'} }]
             @UI: {
             identification: [{position: 10, qualifier: 'PartnerItem'}],
             lineItem: [ {position: 10, importance: #HIGH, qualifier: 'PartnerItem'} ]
             }
             @ObjectModel.text.association: '_PartnerFunctionText'
  key        PurchaseOrderPartner.PartnerFunction,
             @UI.hidden: true
  key        PurchaseOrderPartner.PurchasingOrganization,
             @UI.hidden: true
  key        PurchaseOrderPartner.SupplierSubrange,
             @UI.hidden: true
  key        PurchaseOrderPartner.Plant,
             @UI.hidden: true
  key        PurchaseOrderPartner.PartnerCounter,
             @UI.hidden: true
             PurchaseOrderPartner.CreatedByUser,
             @UI.hidden: true
             PurchaseOrderPartner.CreationDate,
             @ObjectModel: { readOnly: true }
             @UI.hidden: true
             PurchaseOrderPartner._PartnerFunctionText[Language = $session.system_language].PartnerFunctionName as PartnerFunctionName,
             @ObjectModel: { readOnly: true }
             @UI.hidden: true
             PurchaseOrderPartner.PurchasingDocumentPartnerType,
             @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
             @UI.hidden: true
             PurchaseOrderPartner.Supplier,
             @UI.hidden: true
             PurchaseOrderPartner.SupplierHierarchyCategory,
             @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
             @UI.hidden: true
             PurchaseOrderPartner.SupplierContact,
             @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
             @UI.hidden: true
             PurchaseOrderPartner.PersonWorkAgreement,
             @ObjectModel: { readOnly: true }
             PurchaseOrderPartner.DefaultPartner,
             @UI: {
             identification: [{position: 20, qualifier: 'PartnerItem'}],
             lineItem: [ {position: 20, importance: #HIGH, qualifier: 'PartnerItem'} ]
             }
             @ObjectModel.text.element: ['PurchasingDocumentPartnerName']
             cast( case PurchasingDocumentPartnerType
               when 'LI' then PurchaseOrderPartner.Supplier
               when 'AP' then PurchaseOrderPartner.SupplierContact
               when 'PE' then PurchaseOrderPartner.PersonWorkAgreement
             end as mm_pur_partner )                                                                            as PurchasingDocumentPartner,

             cast( case PurchasingDocumentPartnerType
               when 'LI' then PurchaseOrderPartner._Supplier.SupplierFullName
               when 'AP' then PurchaseOrderPartner._SupplierContact.BusinessPartnerName
               when 'PE' then PurchaseOrderPartner._PersonWorkAgreement.PersonFullName
             end as mm_pur_partnername )                                                                        as PurchasingDocumentPartnerName,
             /* Associations */
             PurchaseOrderPartner._PartnerFunction,
             PurchaseOrderPartner._PartnerFunctionText,
             PurchaseOrderPartner._PersonWorkAgreement,
             PurchaseOrderPartner._Plant,
             PurchaseOrderPartner._PurchasingOrganization,
             PurchaseOrderPartner._Supplier,
             PurchaseOrderPartner._SupplierContact,
             _PurchaseOrder
}

Learn More