C_PurOrdDeliveryAddressTP

DDL: C_PURORDDELIVERYADDRESSTP Type: view CONSUMPTION Package: ODATA_MM_PUR_PO_MAINTAIN_V2

Purchase Order Delivery Address

C_PurOrdDeliveryAddressTP is a Consumption CDS View that provides data about "Purchase Order Delivery Address" in SAP S/4HANA. It reads from 1 data source (I_PurOrdDeliveryAddressTP) and exposes 20 fields with key fields PurchaseOrder, PurchaseOrderItem. It has 4 associations to related views. Part of development package ODATA_MM_PUR_PO_MAINTAIN_V2.

1 data source(s) 20 fields

Data Sources (1)

SourceAliasJoin Type
I_PurOrdDeliveryAddressTP PurOrdDeliveryAddressTP from

Associations (4)

CardinalityTargetAliasCondition
[1..1] C_PurchaseOrderTP _PurchaseOrderTP _PurchaseOrderTP.PurchaseOrder = $projection.PurchaseOrder
[1..1] C_PurchaseOrderItemTP _PurchaseOrderItemTP _PurchaseOrderItemTP.PurchaseOrder = $projection.PurchaseOrder and _PurchaseOrderItemTP.PurchaseOrderItem = $projection.PurchaseOrderItem
[0..1] C_MM_CountryValueHelp _CountryValueHelp _CountryValueHelp.Country = $projection.Country
[0..1] C_MM_RegionValueHelp _RegionValueHelp _RegionValueHelp.Country = $projection.Country and _RegionValueHelp.Region = $projection.Region

Annotations (12)

NameValueLevelField
VDM.viewType #CONSUMPTION view
AbapCatalog.sqlViewName CPODELADDTP view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Purchase Order Delivery Address view
AccessControl.authorizationCheck #CHECK view
ObjectModel.transactionalProcessingDelegated true view
ObjectModel.representativeKey PurchaseOrderItem view
ObjectModel.updateEnabled true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #ORGANIZATIONAL view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view

Fields (20)

KeyFieldSource TableSource FieldDescription
KEY PurchaseOrder PurchaseOrder
KEY PurchaseOrderItem PurchaseOrderItem
ItemDeliveryAddressID ItemDeliveryAddressID
FullName FullName
StreetName StreetName
HouseNumber HouseNumber
PostalCode PostalCode
CityName CityName
PhoneNumber PhoneNumber
FaxNumber FaxNumber
Region Region
RegionName _RegionValueHelp RegionName
Country Country
CountryName _CountryValueHelp CountryName
CorrespondenceLanguage CorrespondenceLanguage
TaxCalculationProcedure TaxCalculationProcedure
_PurchaseOrderTP _PurchaseOrderTP
_PurchaseOrderItemTP _PurchaseOrderItemTP
_CountryValueHelp _CountryValueHelp
_RegionValueHelp _RegionValueHelp 
@VDM.viewType: #CONSUMPTION
@AbapCatalog: { sqlViewName: 'CPODELADDTP' }
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Purchase Order Delivery Address'
@AccessControl.authorizationCheck: #CHECK

@ObjectModel: {
    transactionalProcessingDelegated: true,
    semanticKey: ['PurchaseOrder', 'PurchaseOrderItem'],
    representativeKey: 'PurchaseOrderItem',
    updateEnabled: true
}

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #ORGANIZATIONAL
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

define view C_PurOrdDeliveryAddressTP
  as select from I_PurOrdDeliveryAddressTP as PurOrdDeliveryAddressTP

  association [1..1] to C_PurchaseOrderTP     as _PurchaseOrderTP     on  _PurchaseOrderTP.PurchaseOrder = $projection.PurchaseOrder
  association [1..1] to C_PurchaseOrderItemTP as _PurchaseOrderItemTP on  _PurchaseOrderItemTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                      and _PurchaseOrderItemTP.PurchaseOrderItem = $projection.PurchaseOrderItem
  association [0..1] to C_MM_CountryValueHelp as _CountryValueHelp    on  _CountryValueHelp.Country = $projection.Country
  association [0..1] to C_MM_RegionValueHelp  as _RegionValueHelp     on  _RegionValueHelp.Country = $projection.Country
                                                                      and _RegionValueHelp.Region  = $projection.Region


{
      @ObjectModel.foreignKey.association: '_PurchaseOrderTP'
  key PurchaseOrder,

      @ObjectModel.foreignKey.association: '_PurchaseOrderItemTP'
  key PurchaseOrderItem,

      @UI.hidden:true
      ItemDeliveryAddressID,

//      

//      @UI.fieldGroup: [ { position: 10, qualifier: 'DeliveryAddress1' } ]

//      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }

////      @Consumption.hidden: true

//      PurOrdDeliveryAddressTP.ReferenceDeliveryAddressID,

      @UI.fieldGroup: [ { position: 10, qualifier: 'DeliveryAddress1' } ]
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      FullName,
      @UI.fieldGroup: [ { position: 20, qualifier: 'DeliveryAddress1' } ]
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      StreetName,
      @UI.fieldGroup: [ { position: 30, qualifier: 'DeliveryAddress1' } ]
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      HouseNumber,
      @UI.fieldGroup: [ { position: 10, qualifier: 'DeliveryAddress2' } ]
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      PostalCode,
      @UI.fieldGroup: [ { position: 20, qualifier: 'DeliveryAddress2' } ]
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      CityName,
      PhoneNumber,
      FaxNumber,
      @UI.fieldGroup: [ { position: 10, qualifier: 'DeliveryAddress2' } ]
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      @Consumption.valueHelp: '_RegionValueHelp'
      @ObjectModel.text.element: ['RegionName']
      Region,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _RegionValueHelp.RegionName,
      @UI.fieldGroup: [ { position: 20, qualifier: 'DeliveryAddress2' } ]
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      @Consumption.valueHelp: '_CountryValueHelp'
      @ObjectModel.text.element: ['CountryName']
      Country,
      // UX 3.0 Improvement

      @ObjectModel.readOnly: true
      @Consumption.filter.hidden: true
      @Semantics.text: true
      //@UI.hidden: true

      _CountryValueHelp.CountryName,
      CorrespondenceLanguage,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      TaxCalculationProcedure,

      @ObjectModel.association.type: #TO_COMPOSITION_ROOT
      _PurchaseOrderTP,

      @ObjectModel.association.type: #TO_COMPOSITION_PARENT
      _PurchaseOrderItemTP,

      _CountryValueHelp,
      _RegionValueHelp

}

Learn More