C_ProjectServiceOrg

@AbapCatalog.sqlViewName: 'CPSRVCORG'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Service Organization'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ClientHandling.algorithm: #SESSION_VARIABLE
// CDS View has been design for Quick View purpose

// And not to be used for other transaction purpose, as the authorization check is partial

define view C_ProjectServiceOrg
  as select from           I_EngagementProjectSrvcOrg
    left outer to one join I_EngagementProjectSrvcOrgText                  on  I_EngagementProjectSrvcOrgText.EngagementProjectServiceOrg = I_EngagementProjectSrvcOrg.EngagementProjectServiceOrg
                                                                           and I_EngagementProjectSrvcOrgText.Language                    = $session.system_language
    left outer to one join I_EngagementProjectSrvcOrgDets as CompanyCode   on  CompanyCode.EngagementProjectServiceOrg = I_EngagementProjectSrvcOrg.EngagementProjectServiceOrg
                                                                           and CompanyCode.AssignedOrganisationType    = 'CC'
    left outer to one join I_EngagementProjectSrvcOrgDets as CostCenter    on  CostCenter.EngagementProjectServiceOrg   = I_EngagementProjectSrvcOrg.EngagementProjectServiceOrg
                                                                           and CostCenter.AssignedOrganisationType      = 'CS'
                                                                           and CostCenter.AssignedOrganisationIsDefault = 'X'
    left outer to one join I_EngagementProjectSrvcOrgDets as PurchasingOrg on  PurchasingOrg.EngagementProjectServiceOrg = I_EngagementProjectSrvcOrg.EngagementProjectServiceOrg
                                                                           and PurchasingOrg.AssignedOrganisationType    = 'PO'
    left outer to one join I_EngagementProjectSrvcOrgDets as SalesOrg      on  SalesOrg.EngagementProjectServiceOrg = I_EngagementProjectSrvcOrg.EngagementProjectServiceOrg
                                                                           and SalesOrg.AssignedOrganisationType    = 'SO'
    left outer to one join I_EngagementProjectSrvcOrgDets as Plant         on  Plant.EngagementProjectServiceOrg = I_EngagementProjectSrvcOrg.EngagementProjectServiceOrg
                                                                           and Plant.AssignedOrganisationType    = 'PL'

    left outer to one join I_CompanyCode                  as CompanyCodeName                on CompanyCodeName.CompanyCode = CompanyCode.AssignedOrganisation
    left outer to one join I_CostCenterText               as CostCenterName              on  CostCenterName.CostCenter      = CostCenter.AssignedOrganisation
                                                                                         and CostCenterName.ControllingArea = 'A000'
                                                                                         and CostCenterName.Language        = $session.system_language
    left outer to one join I_PurchasingOrganization       as PurchasingOrgName   on PurchasingOrgName.PurchasingOrganization = PurchasingOrg.AssignedOrganisation
    left outer to one join I_SalesOrganizationText        as SalesOrgName         on  SalesOrgName.SalesOrganization = SalesOrg.AssignedOrganisation
                                                                                  and SalesOrgName.Language          = $session.system_language
    left outer to one join I_Plant                        as PlantName                            on PlantName.Plant = Plant.AssignedOrganisation
{
  key  I_EngagementProjectSrvcOrg.EngagementProjectServiceOrg,
       @EndUserText.label: 'Service Organization Name'
       I_EngagementProjectSrvcOrgText.EngmtProjectServiceOrgName as EngmtProjectServiceOrgName,
       @EndUserText.label: 'Company Code'
       CompanyCode.AssignedOrganisation                          as EngmntProjectCompanyCode,
       @EndUserText.label: 'Company Code Name'
       CompanyCodeName.CompanyCodeName                           as CompanyCodeName,
       @EndUserText.label: 'Default Cost Center'
       CostCenter.AssignedOrganisation                           as EngagementProjectCostCenter,
       CostCenterName.CostCenterName                             as CostCenterName,
       @EndUserText.label: 'Purchasing Organization'
       PurchasingOrg.AssignedOrganisation                        as EngmntProjectPurchaseOrg,
       PurchasingOrgName.PurchasingOrganizationName              as PurchasingOrganizationName,
       @EndUserText.label: 'Sales Organization'
       SalesOrg.AssignedOrganisation                             as EngagementProjectSalesOrg,
       @EndUserText.label: 'Sales Org. Name'
       SalesOrgName.SalesOrganizationName                        as SalesOrganizationName,
       @EndUserText.label: 'Plant'
       Plant.AssignedOrganisation                                as EngagementProjectPlant,
       PlantName.PlantName                                       as PlantName,

       @EndUserText.label: 'Sales Organization'
       @Semantics.booleanIndicator: true
       I_EngagementProjectSrvcOrg.EngmtProjServiceOrgIsSales,
       @EndUserText.label: 'Delivery Organization'
       @Semantics.booleanIndicator: true
       I_EngagementProjectSrvcOrg.EngmtProjServiceOrgIsDelivery
}