C_ProjDemandActivityTypeVH

DDL: C_PROJDEMANDACTIVITYTYPEVH Type: view CONSUMPTION Package: ODATA_PS_DMND_MAINTAIN

Activity Type Demand for Work

C_ProjDemandActivityTypeVH is a Consumption CDS View that provides data about "Activity Type Demand for Work" in SAP S/4HANA. It reads from 2 data sources (I_CostCenterActivityType, I_UnitOfMeasure) and exposes 9 fields with key fields CostCtrActivityType, ValidityEndDate, ControllingArea. Part of development package ODATA_PS_DMND_MAINTAIN.

2 data source(s) 9 fields

Data Sources (2)

SourceAliasJoin Type
I_CostCenterActivityType ActivityType from
I_UnitOfMeasure UOM inner

Annotations (17)

NameValueLevelField
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
EndUserText.label Activity Type Demand for Work view
AbapCatalog.sqlViewName CPRJDMNDACTVH view
AbapCatalog.dataMaintenance #RESTRICTED view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #NOT_REQUIRED view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.representativeKey CostCtrActivityType view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.sizeCategory #L view
UI.headerInfo.typeName Activitytype view
UI.headerInfo.typeNamePlural Activitytypes view
Search.searchable true view

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY CostCtrActivityType I_CostCenterActivityType CostCtrActivityType Activity Type
KEY ValidityEndDate I_CostCenterActivityType ValidityEndDate Validity End Date
KEY ControllingArea I_CostCenterActivityType ControllingArea
CostCtrActivityTypeDesc Activity Type Description
CostCtrActivityTypeQtyUnit I_CostCenterActivityType CostCtrActivityTypeQtyUnit Activity Type Unit
CostCtrActivityTypeCategory I_CostCenterActivityType CostCtrActivityTypeCategory Cost Center Category
ValidityStartDate I_CostCenterActivityType ValidityStartDate Validity Start Date
_CostCtrActivityTypeCategory I_CostCenterActivityType _CostCtrActivityTypeCategory
_ControllingArea I_CostCenterActivityType _ControllingArea 
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true


@EndUserText.label: 'Activity Type Demand for Work'
@AbapCatalog: {
    sqlViewName: 'CPRJDMNDACTVH',

    dataMaintenance: #RESTRICTED

}

@VDM: {
    viewType: #CONSUMPTION
//    lifecycle.contract.type: #SAP_INTERNAL_API

}

@AccessControl: {
    authorizationCheck:     #NOT_REQUIRED,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   semanticKey:       [ 'CostCtrActivityTypeDesc' ],
   representativeKey: 'CostCtrActivityType',
   dataCategory: #VALUE_HELP,
   usageType: {
     serviceQuality:  #B,
     dataClass:       #MIXED,
     sizeCategory:    #L
    }
}

@UI.headerInfo: {
  typeName:         'Activitytype',
  typeNamePlural:   'Activitytypes'
}

@Search.searchable: true
@Consumption.ranked 
define view C_ProjDemandActivityTypeVH

  as select from I_CostCenterActivityType as ActivityType 
            inner join I_UnitOfMeasure as UOM on ( ActivityType.CostCtrActivityTypeQtyUnit = UOM.UnitOfMeasureISOCode or ActivityType.CostCtrActivityTypeQtyUnit = UOM.UnitOfMeasureSAPCode )  
                                              and UOM.UnitOfMeasureDimension = 'TIME' 
                                              and UOM.SIUnitCnvrsnRateNumerator = 3600

{

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @EndUserText.label: 'Activity Type'
      @UI: {
        lineItem:       [{ position: 10, importance: #HIGH }]
      }    
      @ObjectModel: {
        readOnly: false,
        mandatory: true,
        text: { element: [ 'CostCtrActivityTypeDesc' ] } }
      @UI.textArrangement: #TEXT_FIRST
  key ActivityType.CostCtrActivityType,
  
  
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @EndUserText.label: 'Validity End Date'
      @UI: {
        lineItem:       [{ position: 60, importance: #HIGH }]
      }

  key ActivityType.ValidityEndDate,
  
      @UI.hidden: true
  key ActivityType.ControllingArea,
  

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @EndUserText.label: 'Activity Type Description'
      @UI: {
        lineItem:       [{ position: 20, importance: #HIGH }]
      }
      @Semantics.text: true
      ActivityType._Text[1:Language=$session.system_language].CostCtrActivityTypeDesc,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @EndUserText.label: 'Activity Type Unit'
      @UI: {
        lineItem:       [{ position: 30, importance: #HIGH }]
      }
      ActivityType.CostCtrActivityTypeQtyUnit,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @EndUserText.label: 'Cost Center Category'
      @UI: {
        lineItem:       [{ position: 40, importance: #HIGH }]
      }
      ActivityType.CostCtrActivityTypeCategory as CostCtrActivityTypeCategory,
      
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @EndUserText.label: 'Validity Start Date'
      @UI: {
        lineItem:       [{ position: 50, importance: #HIGH }]
      }

      ActivityType.ValidityStartDate,

      @Consumption.filter.hidden: true
      ActivityType._CostCtrActivityTypeCategory,
      
      @Consumption.filter.hidden: true
      ActivityType._ControllingArea
      

     

}

Learn More