C_ProjBillgReqItemPrpsdNoteTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Proj Billg Req Itm Prpsd Note TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@ObjectModel.usageType:{
       sizeCategory: #XL,
       dataClass:  #TRANSACTIONAL,
       serviceQuality: #C
    }
@AccessControl.personalData.blocking: #NOT_REQUIRED

define view entity C_ProjBillgReqItemPrpsdNoteTP
  provider contract transactional_query
  as projection on R_ProjBillgReqItemPrpsdNoteTP 

{
      @UI.hidden: true
  key ProjectBillingRequestItemUUID,

      @UI.hidden: true
      ProjectBillingRequestUUID,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @UI: { lineItem: [ { position: 60, importance: #HIGH } ] }
      @EndUserText.label: 'Proposed Note'
      @EndUserText.quickInfo: 'Proposed Note'
      @ObjectModel.sort.enabled: true
      PrjBlgReqItmGnrtdLongText,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @EndUserText.label: 'Work Item'
      @EndUserText.quickInfo: 'Work Item'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem.WorkItem,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.60}
      @EndUserText.label: 'Service Date'
      @EndUserText.quickInfo: 'Service Date'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem.ServicesRenderedDate,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @UI: { lineItem: [ { position: 40, importance: #HIGH , cssDefault: { width:'10rem' } } ] }
      @EndUserText.label: 'Performed By'
      @EndUserText.quickInfo: 'Performed By'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem._PersonWorkAgreement_1.PersonFullName                                                 as PersonFullName,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @UI: { lineItem: [ { position: 30, importance: #HIGH , cssDefault: { width:'10rem' } } ] }
      @EndUserText.label: 'Product'
      @EndUserText.quickInfo: 'Product'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem._Material._Text[1:Language = $session.system_language].MaterialName                   as MaterialName,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @EndUserText.label: 'Activity Type'
      @EndUserText.quickInfo: 'Activity Type'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem.CostCtrActivityTypeDesc,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @UI: { lineItem: [ { position: 50, importance: #HIGH } ] }
      @EndUserText.label: 'Existing Note'
      @EndUserText.quickInfo: 'Existing Note'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem.ProjBillingRequestItemLongText,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @UI.hidden: true
      @EndUserText.label: 'Journal Entry/Item/Fiscal Year'
      @EndUserText.quickInfo: 'Journal Entry/Item/Fiscal Year'
      @UI.textArrangement: #TEXT_ONLY
      @Consumption.semanticObject: 'AccountingDocument'
      _ProjectBillingRequestItem.AccountingDocument,

      @UI: { lineItem: [ { position: 10, importance: #HIGH , cssDefault: { width:'13rem' } } ] }
      @EndUserText.label: 'Journal Entry/Item/Fiscal Year'
      @EndUserText.quickInfo: 'Journal Entry/Item/Fiscal Year'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem.JournalEntrySemanticKey,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @UI: { lineItem: [ { position: 20, importance: #HIGH , cssDefault: { width:'10rem' } } ] }
      @EndUserText.label: 'Work Package'
      @EndUserText.quickInfo: 'Work Package'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem._ProjectBillingElementEntryTP._WBSElement.WBSElementExternalID                        as WBSElement,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @EndUserText.label: 'Work Package Name'
      @EndUserText.quickInfo: 'Work Package Name'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem._ProjectBillingElementEntryTP._WBSElement.WBSDescription,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @EndUserText.label: 'Billing Element'
      @EndUserText.quickInfo: 'Billing Element'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem._ProjectBillingElementEntryTP._ProjectBillingElement._WBSElement.WBSElementExternalID as BillingWBSElementExternalID,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @EndUserText.label: 'Billing Element Description'
      @EndUserText.quickInfo: 'Billing Element Description'
      @ObjectModel.sort.enabled: true
      _ProjectBillingRequestItem._ProjectBillingElementEntryTP._ProjectBillingElement._WBSElement.WBSDescription       as BillingWBSElementDescription,
      
      _ProjectBillingRequestTP : redirected to C_ProjectBillingRequestTP

}