C_ProfitCenterUserContactCard

DDL: C_PROFITCENTERUSERCONTACTCARD Type: view_entity CONSUMPTION Package: RAP_FIN_GL_PROFIT_CENTER_UI

Profit Center User Contact Card

C_ProfitCenterUserContactCard is a Consumption CDS View that provides data about "Profit Center User Contact Card" in SAP S/4HANA. It reads from 1 data source (I_UserContactCard) and exposes 8 fields with key field ContactCardID. It has 1 association to related views. It is exposed through 1 OData service (UI_PROFITCENTER_MANAGE). Part of development package RAP_FIN_GL_PROFIT_CENTER_UI.

1 data source(s) Exposed by 1 service(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
I_UserContactCard I_UserContactCard from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_ProfitCenter _ProfitCenter _ProfitCenter.ProfitCenterCreatedByUser = $projection.ContactCardID

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #REQUIRED view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.representativeKey ContactCardID view
Search.searchable true view
VDM.viewType #CONSUMPTION view
EndUserText.label Profit Center User Contact Card view
Metadata.ignorePropagatedAnnotations true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_PROFITCENTER_MANAGE UI_PROFITCENTER_MANAGE V4 C1 NOT_RELEASED

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY ContactCardID ContactCardID
FullName FullName
UserDescription UserDescription
PhoneNumber PhoneNumber
MobilePhoneNumber MobilePhoneNumber
EmailAddress
Department Department
_ProfitCenter _ProfitCenter 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.usageType:{
    dataClass: #MIXED,
    serviceQuality: #C,
    sizeCategory: #XL
}
@ObjectModel.representativeKey: 'ContactCardID'

@Search.searchable: true
@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Profit Center User Contact Card'
@Metadata.ignorePropagatedAnnotations: true
define view entity C_ProfitCenterUserContactCard
  as select from I_UserContactCard

  association [0..*] to I_ProfitCenter as _ProfitCenter on _ProfitCenter.ProfitCenterCreatedByUser = $projection.ContactCardID

{
      @UI: {
        facet: [{
          targetQualifier: 'UserQuickView',
          type: #FIELDGROUP_REFERENCE,
          purpose: #QUICK_VIEW }],
        fieldGroup: [{
          importance: #HIGH,
          position: 1,
          qualifier: 'UserQuickView' }],
        textArrangement: #TEXT_LAST }
      @ObjectModel: { text.element: ['FullName'] }
      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.8 }
  key ContactCardID,

      @UI.fieldGroup: [{
        importance: #HIGH,
        position: 2,
        qualifier: 'UserQuickView' }]
      @Semantics.text: true
      FullName,

      @UI.fieldGroup: [{
        importance: #HIGH,
        position: 3,
        qualifier: 'UserQuickView' }]
      UserDescription,

      @UI.fieldGroup: [{
        importance: #LOW,
        position: 4,
        qualifier: 'UserQuickView' }]
      PhoneNumber,

      @UI.fieldGroup: [{
        importance: #LOW,
        position: 5,
        qualifier: 'UserQuickView' }]
      MobilePhoneNumber,

      @UI.fieldGroup: [{
        importance: #LOW,
        position: 6,
        qualifier: 'UserQuickView' }]
      cast( EmailAddress as ad_smtpadr ) as EmailAddress,

      @UI.fieldGroup: [{
        importance: #LOW,
        position: 7,
        qualifier: 'UserQuickView' }]
      Department,

      @Consumption.hidden: true
      _ProfitCenter
}

Learn More