C_ProfitCenterToWBSElement

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@Metadata.allowExtensions: true
@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Assgmt of PrftCtr to WBS Element'
define view entity C_ProfitCenterToWBSElement
  as select from I_ProfitCenterToWBSElement as _ProfitCenterToWBSElement
  association [0..*] to I_ProfitCenterText    as _ProfitCenterBfrOrglChangeText on  _ProfitCenterToWBSElement.ControllingArea      = _ProfitCenterBfrOrglChangeText.ControllingArea
                                                                                and _ProfitCenterToWBSElement.ProfitCenterBeforeOrglChange        = _ProfitCenterBfrOrglChangeText.ProfitCenter
                                                                                and _ProfitCenterBfrOrglChangeText.ValidityEndDate = '99991231'
  association [0..*] to I_ProfitCenterText    as _ProfitCenterByOrglChangeText  on  _ProfitCenterToWBSElement.ControllingArea     = _ProfitCenterByOrglChangeText.ControllingArea
                                                                                and _ProfitCenterToWBSElement.ProfitCenter        = _ProfitCenterByOrglChangeText.ProfitCenter
                                                                                and _ProfitCenterByOrglChangeText.ValidityEndDate = '99991231'

  association [0..1] to I_WBSElementBasicData as _SourceWBSElement              on  _ProfitCenterToWBSElement.SourceWBSElementInternalID = _SourceWBSElement.WBSElementInternalID

  association [0..1] to I_ProjectBasicData    as _SourceProjectBasicData        on  _ProfitCenterToWBSElement.SourceProjectInternalID = _SourceProjectBasicData.ProjectInternalID

{
  key  'PR'                                       as OrganizationalChangeObjectType,
  key  WBSElementInternalID,
  key  ValidityStartDate,

       @ObjectModel.text.element: ['WBSDescription']
       _WBSElement.WBSElementExternalID           as WBSElementExternalID,
       @Semantics.text:true
       _WBSElement.WBSDescription                 as WBSDescription,

       @ObjectModel.text.element:    ['CompanyCodeName']
       CompanyCode,

       ValidityEndDate,

       @ObjectModel.text.element:    ['ControllingAreaName']
       ControllingArea,
       @Semantics.text:true
       _ControllingArea.ControllingAreaName       as ControllingAreaName,

       @Semantics.text:true
       _CompanyCode.CompanyCodeName               as CompanyCodeName,

       @ObjectModel.text.element:    ['ProfitCenterBfrOrglChangeName']
       ProfitCenterBeforeOrglChange,

       @Semantics.text:true
       case when _ProfitCenterBfrOrglChangeText[1:Language=$session.system_language].ProfitCenterName is null
              then  _ProfitCenterBfrOrglChangeText[1:Language='E'].ProfitCenterName
              else  _ProfitCenterBfrOrglChangeText[1:Language=$session.system_language].ProfitCenterName
       end                                        as ProfitCenterBfrOrglChangeName,

       @ObjectModel.text.element:    ['ProfitCenterByOrglChangeName']
       ProfitCenter                               as ProfitCenterByOrglChange,

       @Semantics.text:true
       case when _ProfitCenterByOrglChangeText[1:Language=$session.system_language].ProfitCenterName is null
              then  _ProfitCenterByOrglChangeText[1:Language='E'].ProfitCenterName
              else  _ProfitCenterByOrglChangeText[1:Language=$session.system_language].ProfitCenterName
       end                                        as ProfitCenterByOrglChangeName,

       OrganizationalChange,

       @ObjectModel.text.element:    ['OrglChgReassignmentStatusName']
       @Consumption.valueHelp:'_OrglChgReassignmentStatus'
       OrglChangeReassignmentStatus,

       @Semantics.text:true
       case when _OrglChgReassignmentStatus._Text[1:Language=$session.system_language].OrglChgReassignmentStatusName is null
              then  _OrglChgReassignmentStatus._Text[1:Language='E'].OrglChgReassignmentStatusName
              else  _OrglChgReassignmentStatus._Text[1:Language=$session.system_language].OrglChgReassignmentStatusName
       end                                        as OrglChgReassignmentStatusName,

       @Consumption.valueHelp:'_ProfitCtrDerivationSrceType'
       @ObjectModel.text.element:    ['ProfitCenterDrvtnSrceTypeName']
       ProfitCenterDerivationSrceType,

       @Semantics.text:true
       case when _ProfitCtrDerivationSrceType._Text[1:Language=$session.system_language].ProfitCenterDrvtnSrceTypeName is null
                     then  _ProfitCtrDerivationSrceType._Text[1:Language='E'].ProfitCenterDrvtnSrceTypeName
                     else  _ProfitCtrDerivationSrceType._Text[1:Language=$session.system_language].ProfitCenterDrvtnSrceTypeName
       end                                        as ProfitCenterDrvtnSrceTypeName,
       //       SourceWBSElementInternalID,

       @ObjectModel.text.element:    ['SourceWBSElementDescription']
       _SourceWBSElement.WBSElementExternalID     as SourceWBSElementExternalID,
       @Semantics.text:true
       _SourceWBSElement.WBSDescription           as SourceWBSElementDescription,

       SourceProjectInternalID,
       @ObjectModel.text.element:    ['SourceProjectDescription']
       _SourceProjectBasicData.ProjectExternalID  as SourceProjectExternalID,
       @Semantics.text:true
       _SourceProjectBasicData.ProjectDescription as SourceProjectDescription,
       _OrglChgReassignmentStatus,
       _ProfitCtrDerivationSrceType,
       _WBSElement,
       _OrglChange,
       _CompanyCode,
       _ControllingArea,
       _ProfitCtr,
       _ProfitCenterBeforeOrglChange
}
where
  OrganizationalChange is not initial