C_ProductTCCClassificationTP

@AccessControl.authorizationCheck:  #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label:                 'Classify Product with Commodity Code'
@Metadata.allowExtensions:          true
@ObjectModel.semanticKey:           ['Product','TrdClassfctnNmbrSchm']
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory:   #L,
  dataClass:      #MIXED
}
@VDM.usage.type:                    [#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.viewType:                      #CONSUMPTION

define root view entity C_ProductTCCClassificationTP
  as select from I_ProductTCCClassification as _Product
  association [0..1] to C_ProductHasTCC   as _Classified       on  _Classified.Product         = $projection.Product
                                                                            and _Classified.TrdClassfctnNmbrSchm = $projection.TrdClassfctnNmbrSchm
  association [0..1] to C_TrdClassfctnProduct          as _ReferenceProduct on  _ReferenceProduct.Product = $projection.Product
  association [0..*] to C_TrdClassfctnProdPlantCountry as _ProductCountry   on  $projection.Product = _ProductCountry.Product
  association [1..1] to I_ProductHasTCCClassification  as _ProductTCCSchemeClfnStatus on $projection.ProductTCCSchemeClfnStatus = _ProductTCCSchemeClfnStatus.ProductTCCSchemeClfnStatus
  composition [*] of C_ProductTCCValidityClfnTP        as _ClassifyTCC
{
      @Consumption.valueHelpDefinition: [{
            entity: {
                name: 'I_ProductVH' , element: 'Product'
            },
            additionalBinding: [{
                localElement: 'ProductType',
                element: 'ProductType',
                usage: #FILTER
            },{
                localElement: 'ProductCategory',
                element: 'ArticleCategory',
                usage: #FILTER
            },{
                localElement: 'ProductGroup',
                element: 'ProductGroup',
                usage: #FILTER
            },{
                localElement: 'IndustrySector',
                element: 'IndustrySector',
                usage: #FILTER
            }]
          }]
  key _Product.Product as Product,
      @Consumption.valueHelpDefinition: [{
            entity: {
              name:     'C_TranspClsfctnNmbrSchmVH',
              element:  'TrdClassfctnNmbrSchm'
            }
          }]
      @Consumption.filter: { mandatory :          true,
                             selectionType :      #SINGLE,
                             multipleSelections : false     }
      @ObjectModel.text.association: '_TrdClassfctnNmbrSchmText'
  key _Product.TrdClassfctnNmbrSchm,
     @Consumption.valueHelpDefinition: [{
            entity: {
              name:     'I_ProdHasTCCClassfctnVH',
              element:  'ProductTCCSchemeClfnStatus'
            }            
          }]
      @ObjectModel.foreignKey.association: '_ProductTCCSchemeClfnStatus'
      @Semantics.text: true
      cast(case
          when _Classified.TrdClassfctnNmbrSchm is not null then '1'
          else '2' end as /scmtms/vdm_prd_tccns_clfn_sts ) as ProductTCCSchemeClfnStatus,
      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_ProductCategoryVH' , element: 'ProductCategory'
        }
      }]
      _Product.ProductCategory,
      
      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_ProductGroup_2' , element: 'ProductGroup'
        }
      }]
      @ObjectModel.text.association: '_ProductGroupText'
      _Product.ProductGroup,
      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_Division' , element: 'Division'
        }
      }]
      @ObjectModel.text.association: '_DivisionText'
      _Product.Division,
      
      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_ProductHierarchy' , element: 'ProductHierarchy'
        }
      }]
      _Product.ProductHierarchy,
      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_ProductTypeVH' , element: 'ProductType'
        }
      }]
      _Product.ProductType,
      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_Extprodgrpvh' , element: 'ExternalProductGroup'
        }
      }]
      _Product.ExternalProductGroup,
      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_Industrysectorvh' , element: 'IndustrySector'
        }
      }]
      _Product.IndustrySector,
      _Product.CreationDate,
      _Product.IsMarkedForDeletion,
      _Product._TrdClassfctnNmbrSchmText,
      @Consumption.filter.hidden: true
      _ReferenceProduct,
      @Consumption.hidden: true
      _Product._Product,
      _Product._ProductCategory,
      _Product._ProductGroup,
      _Product._Division,
      _Product._ProductHierarchy,
      _Product._ProductType,
      _Product._ExternalProductGroup,
      _Product._IndustrySector,

      _ProductCountry,

      _Product._Text,
      _Product._ProductCategoryText,
      @Semantics.text: true
      _Product._ProductGroupText,
      @Semantics.text: true
      _Product._DivisionText,
      _Product._ProductHierarchyText,
      _Product._ProductTypeText,
      _Product._ExternalProductGroupText,
      _Product._IndustrySectorText,
      _ProductTCCSchemeClfnStatus,
      _ClassifyTCC
}