C_ProductObjPgVariant

@AbapCatalog.sqlViewName: 'CPRODOBJPGVAR'
@EndUserText.label: 'Product Object Page - Variant'

@VDM.viewType: #CONSUMPTION
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #NOT_REQUIRED,
    privilegedAssociations: ['_Text']
}
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    semanticKey: ['CrossPlantConfigurableProduct', 'Product'],
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #MASTER
   }
}

@Consumption.semanticObject: 'Material'

@UI.presentationVariant.sortOrder: {
    by: 'Product',
    direction: #ASC
}

define view C_ProductObjPgVariant
  as select from I_Product
  association [1..1] to C_ProductObjPg                 as _ProductObjPg                 on $projection.CrossPlantConfigurableProduct = _ProductObjPg.Product
  association [0..*] to C_ProductObjPgVariantCharcValn as _ProductObjPgVariantCharcValn on $projection.Product = _ProductObjPgVariantCharcValn.Product
{
      @UI.hidden: true
  key CrossPlantConfigurableProduct,
      @EndUserText: {
          label: 'Variant',
          quickInfo: 'Variant'
      }
      @Consumption.semanticObject: 'Material'
      @UI.lineItem: [{position: 20, importance: #HIGH}]
  key Product,

      ProductStandardID,
      @UI.hidden: true
      InternationalArticleNumberCat,

      LastChangeDate,
      @UI.hidden: true
      case _LastChangedByUser.UserDescription
        when '' then _LastChangedByUser.UserID
        else         _LastChangedByUser.UserDescription
      end                                               as LastChangedByUser,

      @Semantics.imageUrl: true
      @EndUserText.quickInfo: 'Image'
      @UI.lineItem: [{position: 10, importance: #MEDIUM}]
      cast('' as productimageurl)                       as ProductImageURL,

      @Consumption.hidden: true
      AuthorizationGroup,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _ProductObjPg,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _ProductObjPgVariantCharcValn,
      _Text,
      _InternationalArticleNumberCat,
      _CrossPlantConfigurableProduct
}