C_ProductObjPgRetailPromotion

@AbapCatalog.sqlViewName: 'CPRODOBJPGRTLPRM'
@EndUserText.label: 'Product Object Page - Retail Promotion'

@VDM.viewType: #CONSUMPTION
@AccessControl: {
    authorizationCheck: #CHECK
}
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    semanticKey: ['Product', 'RetailPromotion'],
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #TRANSACTIONAL
   }
}

@UI.presentationVariant.sortOrder: [{
    by: 'RetailPromotionSalesToDate',
    direction: #DESC
}, {
    by: 'RetailPromotionSalesFromDate',
    direction: #DESC
}]

define view C_ProductObjPgRetailPromotion
  as select from I_RetailPromotionByProduct
  association [1..1] to C_ProductObjPg as _ProductObjPg on $projection.Product = _ProductObjPg.Product
{
      @UI.hidden: true
  key Product,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_RetailPromotionStdVH',
                     element: 'RetailPromotion' }
        }]
      @Consumption.semanticObject: 'RetailPromotion'
      @UI.textArrangement: #TEXT_LAST
      @ObjectModel.text.element: ['RetailPromotionName']
      @UI.lineItem: [{position: 10, importance: #HIGH}]
  key RetailPromotion,

      @UI.hidden: true
      _RetailPromotion._Text[1:Language=$session.system_language].RetailPromotionName,

      @EndUserText.label: 'Start'
      @UI.lineItem: [{position: 20, importance: #HIGH}]
      _RetailPromotion.RetailPromotionSalesFromDate,
      @EndUserText.label: 'End'
      @UI.lineItem: [{position: 30, importance: #MEDIUM}]
      _RetailPromotion.RetailPromotionSalesToDate,

      @EndUserText.label: 'Sales Price Activation'
      @UI.textArrangement: #TEXT_ONLY
      @UI.lineItem: [{position: 40, importance: #MEDIUM}]
      @ObjectModel.text.element: [ 'SalesPriceActivationStatusName' ]
      _RetailPromotion.SalesPriceActivationStatus,

      @UI.lineItem: [{position: 50, importance: #MEDIUM}]
      @ObjectModel.text.element: [ 'SalesOrganizationName' ]
      _RetailPromotion.SalesOrganization,

      @UI.lineItem: [{position: 60, importance: #MEDIUM}]
      @ObjectModel.text.element: [ 'DistributionChannelName' ]
      _RetailPromotion.DistributionChannel,

      @UI.lineItem: [{position: 70, importance: #LOW}]
      @ObjectModel.text.element: [ 'PurchasingOrganizationName' ]
      _RetailPromotion.PurchasingOrganization,

      @UI.lineItem: [{position: 80, importance: #LOW}]
      @ObjectModel.text.element: [ 'PurchasingGroupName' ]
      _RetailPromotion.PurchasingGroup,

      @UI.lineItem: [{position: 90, importance: #MEDIUM}]
      @ObjectModel.text.element: [ 'RetailPromotionTypeName' ]
      _RetailPromotion.RetailPromotionType,

      @EndUserText.label: 'Promotion Announcement'
      @UI.textArrangement: #TEXT_ONLY
      @UI.lineItem: [{position: 100, importance: #LOW}]
      @ObjectModel.text.element: [ 'PromotionAnnouncementStsName' ]
      _RetailPromotion.PromotionAnnouncementStatus,

      _ProductObjPg,
      _RetailPromotion,
      @UI.hidden: true
      _RetailPromotion._RtlPromnSalesPriceActvtnSts,
      @UI.hidden: true
      _RetailPromotion._RtlPromnSalesPriceActvtnSts._Text[1: Language = $session.system_language ].SalesPriceActivationStatusName,
      @UI.hidden: true
      _RetailPromotion._RtlPromotionAnnouncementSts,
      @UI.hidden: true
      _RetailPromotion._RtlPromotionAnnouncementSts._Text[1: Language = $session.system_language ].PromotionAnnouncementStsName,
      @UI.hidden: true
      _RetailPromotion._SalesOrganization,
      @UI.hidden: true
      _RetailPromotion._SalesOrganization._Text[1: Language =  $session.system_language ].SalesOrganizationName,
      @UI.hidden: true
      _RetailPromotion._DistributionChannel._Text[1: Language = $session.system_language ].DistributionChannelName,
      @UI.hidden: true
      _RetailPromotion._DistributionChannel,
      @UI.hidden:true
      _RetailPromotion._PurchasingOrganization,
      @UI.hidden:true
      _RetailPromotion._PurchasingOrganization.PurchasingOrganizationName,
      @UI.hidden: true
      _RetailPromotion._PurchasingGroup,
      @UI.hidden: true
      _RetailPromotion._PurchasingGroup.PurchasingGroupName,
      @UI.hidden: true
      _RetailPromotion._RetailPromotionType,
      @UI.hidden: true
      _RetailPromotion._RetailPromotionType._Text[1: Language = $session.system_language ].RetailPromotionTypeName

}