C_ProdStrucVariant

@AbapCatalog.sqlViewName: 'CPSVARIANT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:  #CHECK
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
@VDM.lifecycle: {
//  contract: {

//    type: #PUBLIC_LOCAL_API

//  },

  status: #DEPRECATED,
  successor: 'I_ProductStructureVariant_2'
}
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #C
@EndUserText.label: 'Product Structure Variant List'
define view C_ProdStrucVariant as select from I_ProductStructureVariant_2    as _Variant
  association [1..1] to C_ProdStrucMaterialVH  as _Material on $projection.Material = _Material.Material
  association [0..1] to C_ProdStrucVariantType as _VarType on $projection.ProductStructureVariantType = _VarType.ProductStructureVariantType
  association [1..1] to I_ProductStructureNode_2 as _Node on $projection.ProdStructureVariantParentUUID = _Node.ProductStructureNodeUUID
  association [0..1] to I_ProdStrucLogAccMActive  as _LogAccMObjectTypeActive  on  $projection.ProductStructureGnrcObjType   = _LogAccMObjectTypeActive.LogAccMObjectType
  association [0..1] to I_ProdStrucObjSecureIDAssgmt as _LogAccMObjSecureIDAssgmt on  $projection.ProdStrucVariantUniqueID              = _LogAccMObjSecureIDAssgmt.LogAccMObjectID
                                                                                and $projection.ProductStructureGnrcObjType             = _LogAccMObjSecureIDAssgmt.LogAccMObjectType
  association [0..1] to I_ProdStrucObjectUserAuthzn  as _LogAccMObjectUserAuthzn  on  $projection.ProdStrucVariantUniqueID              = _LogAccMObjectUserAuthzn.LogAccMObjectID
                                                                                and _LogAccMObjectUserAuthzn.LogAccMObjectType          = $projection.ProductStructureGnrcObjType
                                                                                and _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject    = $projection.ProductStructureGnrcObjType
                                                                                /*and (
                                                                                   _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject    = 'PLM_PPEPV'
                                                                                   or _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject = 'PLM_PPEPIV'
                                                                                 )
                                                                                and (
                                                                                   _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom      = '03'
                                                                                   or _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom   = '*'
                                                                                 )
                                                                                and _LogAccMObjectUserAuthzn.LogAccMUserAuthznField    = 'ACTVT'
                                                                                and (
                                                                                   _LogAccMObjectUserAuthzn.LogAccMUserEntityID        = $session.user
                                                                                   or _LogAccMObjectUserAuthzn.UserID                  = $session.user
                                                                                 )*/
{

  key ProductStructureVariantUUID,
  key ProdStrucVariantChgStateIntID,
      ProdStrucVariantUniqueID,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #HIGH
      ProductStructureVariantName,
      ProdStructureVariantParentUUID,
      ProductStructureVariantType,
      ProductStructureCreationDate,
      ProductStructureCreatedByUser,
      ProductStrucLastChangedDate,
      ProductStrucLastChangedByUser,
      _Text[1:Language = $session.system_language].ProdStrucVariantDescription,
      _VarType.ProdStrucVarTypeDescription,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      ProdStrucVariantChangeNumber,
      @UI.hidden: true
      AuthorizationGroup, //for authorization check

      ProdStrucVarIsMrkdForDeletion,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.4
      ProdStrucVarChgNmbrDescription,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.4
      Material,
      _Material.MaterialName,
      ProductStructureVariantQty,
      ProductStructureVariantUnit,
      @UI.hidden: true
      MaterialAuthorizationGroup, //for authorization check

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      _Node.ProductStructureNodeName,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.4
      _Node._Text[1:Language = $session.system_language].ProdStrucNodeDescription,
      _Node.ProductStructureNodeType,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      _Node._Class.Class,
      _Node._Class._ClassDescription[1:Language = $session.system_language].ClassDescription as ClassName,
      @UI.hidden: true
      _Variant.ProductStructureGnrcObjType,
      
      _LogAccMObjectTypeActive,
      _LogAccMObjSecureIDAssgmt,
      _LogAccMObjectUserAuthzn
}