C_ProcurementSmartFilter

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality:#C
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.sqlViewName: 'CPROCMTSMRTFLT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Global Filter for Procurement Overview Page'
//@OData.publish: true

@Metadata.allowExtensions: true
@VDM.viewType: #CONSUMPTION
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
define view C_ProcurementSmartFilter

with parameters
  @Consumption.defaultValue: 'EUR'
    @Consumption.valueHelpDefinition: [{
      entity: {
        name:'I_Currency',
        element:'Currency'
      }
    }]
  P_DisplayCurrency : displaycurrency

  as select from           I_PurchasingDocument          as PurchasingDocument

    inner join             I_PurchasingDocumentItem      as _PurchasingDocumentItem      on PurchasingDocument.PurchasingDocument = _PurchasingDocumentItem.PurchasingDocument

    left outer to one join I_PurchasingCategoryMatlGroup as _PurchasingCategoryMatlGroup on _PurchasingDocumentItem.MaterialGroup = _PurchasingCategoryMatlGroup.MaterialGroup

  association [0..1] to C_PurchasingGroupValueHelp    as _PurchasingGroup        on  PurchasingDocument.PurchasingGroup = _PurchasingGroup.PurchasingGroup

  association [0..1] to C_PurchasingOrgValueHelp      as _PurchasingOrganization on  PurchasingDocument.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization //and

  //PurchasingDocument.Supplier = _PurchasingOrganization.Supplier


  association [0..1] to C_MM_CompanyCodeValueHelp     as _CompanyCode            on  PurchasingDocument.CompanyCode = _CompanyCode.CompanyCode //and

  //PurchasingDocument.Supplier = _CompanyCode.Supplier


  association [0..1] to C_MM_PlantValueHelp           as _Plant                  on  _PurchasingDocumentItem.Plant             = _Plant.Plant
                                                                                 and PurchasingDocument.PurchasingOrganization = _Plant.PurchasingOrganization

  association [0..1] to C_MM_SupplierValueHelp        as _Supplier               on  PurchasingDocument.Supplier = _Supplier.Supplier
                                                                                 and $projection.CompanyCode     = _Supplier.CompanyCode

  association [1..1] to C_MM_MaterialValueHelp        as _Material               on  _PurchasingDocumentItem.Material = _Material.Material
                                                                                 and _PurchasingDocumentItem.Plant    = _Material.Plant

  association [0..1] to C_MM_MaterialGroupValueHelp   as _MaterialGroup          on  _PurchasingDocumentItem.MaterialGroup = _MaterialGroup.MaterialGroup

  association [0..1] to C_PurchasingCategoryValueHelp as _PurchasingCategory     on  _PurchasingCategoryMatlGroup.PurgCatUUID = _PurchasingCategory.PurgCatUUID
                                                                                 and $projection.purchasingcategory           = _PurchasingCategory.PurchasingCategory
  association [0..1] to I_Currency                    as _DocumentCurrency                  on  $projection.DocumentCurrency = _DocumentCurrency.Currency

//  association [0..1] to C_MM_CountryValueHelp         as _Country                on  $projection.Country = _Country.Country


{
       @Consumption.valueHelp: '_Supplier'
       @UI.selectionField.element: 'Supplier'
       @UI.selectionField.position: '10'
  key  PurchasingDocument.Supplier,
       @Consumption.hidden: true                            //3293265

       _Supplier,

       @Consumption.valueHelp: '_Material'
       @UI.selectionField.element: 'Material'
       @UI.selectionField.position: '20'
  key  _PurchasingDocumentItem.Material,
       @Consumption.hidden: true                            //3293265

       _Material,

       @Consumption.valueHelp: '_MaterialGroup'
       @UI.selectionField.element: 'MaterialGroup'
       @UI.selectionField.position: '30'
  key  _PurchasingDocumentItem.MaterialGroup,
       @Consumption.hidden: true                            //3293265

       _MaterialGroup,

       @Consumption.valueHelp: '_PurchasingCategory'
       @UI.selectionField.element: 'PurchasingCategory'
       @UI.selectionField.position: '40'
       @ObjectModel.text.element: null
  key  _PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory,

       @Consumption.valueHelp: '_PurchasingGroup'
       @UI.selectionField.element: 'PurchasingGroup'
       @UI.selectionField.position: '50'
  key  PurchasingDocument.PurchasingGroup,
       @Consumption.hidden: true                            //3293265

       _PurchasingGroup,

       @Consumption.valueHelp: '_PurchasingOrganization'
       @UI.selectionField.element: 'PurchasingOrganization'
       @UI.selectionField.position: '60'
       @EndUserText.label: 'Purchasing Organization'
  key  PurchasingDocument.PurchasingOrganization,
       @Consumption.hidden: true                            //3293265

       _PurchasingOrganization,

       @Consumption.valueHelp: '_CompanyCode'
       @UI.selectionField.element: 'CompanyCode'
       @UI.selectionField.position: '70'
  key  PurchasingDocument.CompanyCode,
       @Consumption.hidden: true                            //3293265

       _CompanyCode,

       @Consumption.valueHelp: '_Plant'
       @UI.selectionField.element: 'Plant'
       @UI.selectionField.position: '80'
  key  _PurchasingDocumentItem.Plant,
       @Consumption.hidden: true                            //3293265

       _Plant,

//       @UI.selectionField.element: 'Country'

//       @UI.selectionField.position: '90'

//  key  cast( cast( PurchasingDocument._Supplier._StandardAddress.Country as abap.char(30) )  as odata_mm_country_name ) as Country,

//       _Country,


       //           @Consumption.valueHelp: '_PurchasingCategory'

       //           @UI.selectionField.element: 'PurchasingCategory'

       //           @UI.selectionField.position: '90'

       @DefaultAggregation: #SUM
//       @Consumption.hidden: true

       1 as NumberOfItems,
      // @Consumption.hidden: true

       _PurchasingCategoryMatlGroup.PurgCatUUID,
       @Consumption.hidden: true                            //3293265

       _PurchasingCategory,
       @Semantics.currencyCode: true
       @Consumption.hidden:'true'
       $parameters.P_DisplayCurrency as DisplayCurrency,    //3483301

       @Semantics.currencyCode: true
        _PurchasingDocumentItem.DocumentCurrency,
       @Consumption.hidden: true                            //3293265

       _DocumentCurrency,

       @Consumption.hidden: true
       _PurchasingCategoryMatlGroup._PurchasingCategory.PurgCatName



}
  where PurchasingDocument.IsEndOfPurposeBlocked = ''