C_ProcessOrderEnhancedVH

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'ProcessOrder'
@ObjectModel.supportedCapabilities: [#VALUE_HELP_PROVIDER, #SEARCHABLE_ENTITY]
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

@Search.searchable: true
@Consumption:{
  ranked: true,
  valueHelpDefault.fetchValues:#ON_EXPLICIT_REQUEST
}

@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Process Order'

define view entity C_ProcessOrderEnhancedVH as select from I_ManufacturingOrder as OrdHeader
inner join   I_MfgOrderWithStatus as OrdData on OrdHeader.ManufacturingOrder = OrdData.ManufacturingOrder  
association [0..*] to I_OrderTypeText   as _ProcessOrderTypeText   on  $projection.ProcessOrderType = _ProcessOrderTypeText.OrderType                                                                    
{
  @Search.defaultSearchElement: true
  @Search.ranking: #HIGH
  @Search.fuzzinessThreshold: 0.9
  @EndUserText.label: 'Process Order'
  //@ObjectModel.text.element: ['ProcessOrderText']  

  //@UI.textArrangement:#TEXT_FIRST

  key cast(OrdHeader.ManufacturingOrder as manufacturingorder preserving type) as ProcessOrder,
  @UI.hidden: true
  @Consumption.filter.hidden: true 
  @Semantics.text:true
  OrdHeader.ManufacturingOrderText as ProcessOrderText,
  @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProcessOrderTypeStdVH', element: 'ProcessOrderType' } } ]
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  @Search.fuzzinessThreshold: 0.8
  @ObjectModel.text.element: ['ProcessOrderTypeName']
  @UI.textArrangement:#TEXT_FIRST
  cast(OrdHeader.ManufacturingOrderType as processordertype preserving type) as ProcessOrderType,
  @Consumption.filter.hidden: true 
  @Semantics.text:true
  _ProcessOrderTypeText[ 1: Language = $session.system_language ].OrderTypeName as ProcessOrderTypeName, 
  @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  @Search.fuzzinessThreshold: 0.8
  @ObjectModel.text.element: ['PlantName']
  @UI.textArrangement:#TEXT_FIRST
  cast(OrdHeader.ProductionPlant as pwwrk preserving type) as ProductionPlant,
  @Consumption.filter.hidden: true 
  @Semantics.text:true
  OrdHeader._ProductionPlant[ 1: Language = $session.system_language ].PlantName as PlantName,
  @Consumption.valueHelpDefinition: [ { entity: { name : 'I_MaterialStdVH', element: 'Material' } } ]
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  @Search.fuzzinessThreshold: 0.8
  @ObjectModel.text.element: ['MaterialName']
  @UI.textArrangement:#TEXT_FIRST
  //cast(Product as productnumber preserving type) as Product,

  OrdHeader.Material,
  @Consumption.filter.hidden: true 
  @Semantics.text:true
  OrdHeader._MaterialText[ 1: Language = $session.system_language ].ProductName as MaterialName,
  @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderMRPControllerStdVH', element: 'MRPController' } } ]
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  @Search.fuzzinessThreshold: 0.8
  @ObjectModel.text.element: ['MRPControllerName']
  @UI.textArrangement:#TEXT_FIRST
  OrdHeader.MRPController,
  @Consumption.filter.hidden: true 
  @Semantics.text:true
  OrdHeader._MRPController.MRPControllerName as MRPControllerName,
  @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderProdnSupervisorStdVH', element: 'ProductionSupervisor' } } ]
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  @Search.fuzzinessThreshold: 0.8
  @ObjectModel.text.element: ['ProductionSupervisorName']
  @UI.textArrangement:#TEXT_FIRST
  OrdHeader.ProductionSupervisor,
  @Consumption.filter.hidden: true 
  @Semantics.text:true
  OrdHeader._ProductionSupervisor.ProductionSupervisorName,
  
  @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderStdVH', element: 'SalesOrder' } } ]
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  @Search.fuzzinessThreshold: 0.8
  cast(OrdHeader.SalesOrder as co_kdauf preserving type) as SalesOrder,
  
  OrdHeader._MfgOrderType,
  _ProcessOrderTypeText,
  OrdHeader._ProductionPlant,
  OrdHeader._MaterialText,
  OrdHeader._MRPController,
  OrdHeader._ProductionSupervisor 
 }
 where OrdHeader.ManufacturingOrderCategory = '40'  //only 'open' process orders

   and OrdData.OrderIsTechnicallyCompleted <> 'X'
   and OrdData.OrderIsDelivered            <> 'X'
   and OrdData.OrderIsDeleted              <> 'X'
   and OrdData.OrderIsClosed               <> 'X'
   and OrdData.OrderIsMarkedForDeletion    <> 'X'