C_ProcessFlowResources

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Resources'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@Metadata.allowExtensions: true

define view entity C_ProcessFlowResources
  as select from R_WorkCenterTP           as _WrkCtr
    inner join   I_WorkCenterCategoryAppl as _WrkCtrAppl on  _WrkCtr.WorkCenterCategoryCode          = _WrkCtrAppl.WorkCenterCategoryCode
                                                         and _WrkCtrAppl.BillOfOperationsApplication = 'C'

  association [0..1] to I_WorkCenterCategoryText      as _WorkCenterCategoryText on  _WrkCtr.WorkCenterCategoryCode   = _WorkCenterCategoryText.WorkCenterCategoryCode
                                                                                 and _WorkCenterCategoryText.Language = $session.system_language

  association [0..1] to I_WorkCenterGroupObjectCount  as _ObjectCount            on  _ObjectCount.ObjectTypeCode   = 'A'
                                                                                 and _ObjectCount.ObjectInternalID = _WrkCtr.WorkCenterInternalID

  association [0..*] to C_MassMaintCapWrkCtrGrpAggrgn as _WrkCtrGrp              on  _WrkCtrGrp.WorkCenterInternalID = _WrkCtr.WorkCenterInternalID

  association [1..1] to I_Plant                       as _Plant                  on  _Plant.Plant = _WrkCtr.Plant
  
  association [0..*] to C_WorkCenterCostCenter         as _CostCenter            on  _CostCenter.WorkCenterTypeCode   = _WrkCtr.WorkCenterTypeCode
                                                                                 and _CostCenter.WorkCenterInternalID = _WrkCtr.WorkCenterInternalID
{

  key _WrkCtr.WorkCenterInternalID,
  key _WrkCtr.WorkCenterTypeCode,
      _WrkCtr.WorkCenter,
      _WrkCtr.WorkCenterDesc,
      @ObjectModel.text.element: ['PlantName']
      _WrkCtr.Plant,

      @ObjectModel.text.element: ['WorkCenterResponsibleName']
      _WrkCtr.WorkCenterResponsible,

      @ObjectModel.text.element: ['WorkCenterCategoryName']
      _WrkCtr.WorkCenterCategoryCode,
      _WrkCtr.WorkCenterUsage,
      _WrkCtr.StandardWorkFormulaParamGroup,
      _WrkCtr.OperationControlProfile,
      _WrkCtr._CostCtrCount.NmbrOfCostCtrAssgdToWorkCenter                              as NmbrOfCostCtrAssgdToWorkCenter,

      //Virtual Filter

      @ObjectModel.filter.transformedBy:'CL_PP_WORKCENTER_FLTR'
      cast( cast( '0000000000'  as abap.char(10) ) as cr_hname preserving type )        as WorkCenterGroup,
      @ObjectModel.filter.transformedBy:'CL_PP_WORKCENTER_FLTR'
      cast( cast( '0000000000' as abap.char(10) ) as  cr_wrkctrgrptyp preserving type ) as WorkCenterGroupType,
      @ObjectModel.filter.transformedBy:'CL_PP_WORKCENTER_FLTR'
      cast( cast( '0000000000' as abap.char(10) ) as  kostl preserving type )           as CostCenter,
      
      @ObjectModel.filter.transformedBy:'ABAP:CL_PP_WORKCENTER_FLTR'
      cast( cast( '0000' as abap.char(4) ) as  fis_kokrs preserving type )              as ControllingArea,
      
      @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_CostCenterHierarchyVH', element: 'CostCenterHierarchy' } }]
      @Consumption.filter.selectionType: #SINGLE
      @ObjectModel.filter.transformedBy: 'ABAP:CL_PP_WORKCENTER_FLTR'
      cast('' as fis_cctr_hryid_42)                                                     as CostCenterHierarchy,

//      @Consumption.filter.hidden: true

//      @Consumption.valueHelpDefinition: [{ entity:{ name: 'C_CostCtrHierarchyInnerNodeVH', element: 'HierarchyNode' } }]

//      @Consumption.filter.selectionType: #SINGLE

//      @ObjectModel.filter.transformedBy: 'ABAP:CL_PP_WORKCENTER_FLTR'

//      cast('' as fis_cctr_hrynid_50)                                                    as CostCenterHierarchyNode,


      _ObjectCount.WorkCenterGroupObjectCount,

      @Semantics.text: true
      _Plant.PlantName,
      @Semantics.text: true
      _WrkCtr.WorkCenterResponsibleName,
      @Semantics.text: true
      _WorkCenterCategoryText.WorkCenterCategoryName,

      _WrkCtr.WorkCenterLocation,
      _WrkCtr.SupplyArea,
      _WrkCtr.ShiftNoteType,
      _WrkCtr.ShiftReportType,

      /* Associations */
      _WorkCenterCategoryText,
      _ObjectCount,
      _WrkCtrGrp,
      _CostCenter

}