C_PT_SAFTPaymentLineC

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #CONSUMPTION
@Analytics.internalName:#LOCAL
@Metadata.allowExtensions:true
@Analytics: { dataCategory: #CUBE }
@EndUserText.label: 'Payment Lines for SAFT PT - Cube'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity C_PT_SAFTPaymentLineC
  as select distinct from C_PT_SAFTPaymentDocumentC as Document
{
  key Document.CompanyCode,
  key Document.ClearingAccountingDocument,
  key Document.FiscalYear                         as ClearingFiscalYear,
  key Document._Clearing.ClearingInformationIndex as DocumentItemNumber,

      Document._Clearing.AccountingDocument,
      Document._Clearing.FiscalYear               as FiscalYear,
      Document.PostingDate,
      Document._Clearing.CompanyCodeCurrency      as CompanyCurrency,
      Document._Clearing.TransactionCurrency,
      @Semantics.amount.currencyCode: 'CompanyCurrency'
      case
        when Document._Clearing.DebitCreditCode = 'H'
        then
          case
            when Document._Clearing.DifferenceAmtInCoCodeCrcy is initial
            then abs(Document._Clearing.AmountInCompanyCodeCurrency - Document._Clearing.CashDiscountAmtInCoCodeCrcy )
            else abs(Document._Clearing.AmountInCompanyCodeCurrency + Document._Clearing.DifferenceAmtInCoCodeCrcy - Document._Clearing.CashDiscountAmtInCoCodeCrcy )
          end
      else cast(0 as fis_dr_hsl)
      end                                         as DebitAmountInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCurrency'
      case
        when Document._Clearing.DebitCreditCode = 'S'
        then
          case
            when Document._Clearing.DifferenceAmtInCoCodeCrcy is initial
            then abs(Document._Clearing.AmountInCompanyCodeCurrency - Document._Clearing.CashDiscountAmtInCoCodeCrcy )
            else abs(Document._Clearing.AmountInCompanyCodeCurrency - Document._Clearing.DifferenceAmtInCoCodeCrcy - Document._Clearing.CashDiscountAmtInCoCodeCrcy )
          end
      else cast(0 as fis_dr_hsl)
      end                                         as CreditAmountInCoCodeCrcy,

      //      Document.AbsoluteExchangeRate  as ExchangeRate,


      //Amount Foreign Currency

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case
        when Document._Clearing.DebitCreditCode = 'H'
        then
          case
            when Document._Clearing.DifferenceAmtInTransCrcy is initial
            then abs(Document._Clearing.AmountInTransactionCurrency - Document._Clearing.CashDiscountAmount )
            else abs(Document._Clearing.AmountInTransactionCurrency + Document._Clearing.DifferenceAmtInTransCrcy - Document._Clearing.CashDiscountAmount )
          end
      else cast(0 as fis_dr_hsl)
      end                                         as DebitAmountInTransCrcy,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      case
        when Document._Clearing.DebitCreditCode = 'S'
        then
          case
            when Document._Clearing.DifferenceAmtInTransCrcy is initial
            then abs(Document._Clearing.AmountInTransactionCurrency - Document._Clearing.CashDiscountAmount )
            else abs(Document._Clearing.AmountInTransactionCurrency - Document._Clearing.DifferenceAmtInTransCrcy - Document._Clearing.CashDiscountAmount )
          end
      else cast(0 as fis_dr_hsl)
      end                                         as CreditAmountInTransCrcy,

      @Semantics.amount.currencyCode: 'CompanyCurrency'
      case
        when Document._Clearing._JournalEntry._OperationalAcctgDocItem[FinancialAccountType = 'D'   //Partial Payment, Invoice not cleared

                                                        and ClearingJournalEntry is initial ].AccountingDocument is not initial
          or Document._Clearing.DifferenceAmtInTransCrcy is initial   //or Partial Payment, Invoice clearing line

        then Document._Clearing.CashDiscountAmtInCoCodeCrcy
      else cast(0 as fis_dr_hsl)
      end                                         as CashDiscountAmtInCoCodeCrcy,

      cast( '' as farp_schzw_bseg )               as PaymentMethod,

      @Semantics.booleanIndicator:true
      case
        when Document.DownPaymentType = '2'  or
        ( Document.ReverseDocument is not initial and Document.IsReversed <> '' )
        then 'X'
        else 'I'
      end                                         as SelectedValueIsExcluded,

      Document._CompanyCode,
      Document._Clearing._JournalEntry.AccountingDocumentType,
      Document._Clearing._JournalEntry.DocumentDate
}