C_OrglChangeWBSElementTP

DDL: C_ORGLCHANGEWBSELEMENTTP Type: view_entity CONSUMPTION Package: ODATA_ORGL_CHANGE_MANAGE

Org.Change WBS Elements

C_OrglChangeWBSElementTP is a Consumption CDS View that provides data about "Org.Change WBS Elements" in SAP S/4HANA. It reads from 1 data source (R_OrglChangeWBSElementTP) and exposes 17 fields with key fields OrganizationalChange, WBSElementInternalID. It is exposed through 1 OData service (UI_ORGANIZATIONALCHANGE). Part of development package ODATA_ORGL_CHANGE_MANAGE.

1 data source(s) Exposed by 1 service(s) 17 fields

Data Sources (1)

SourceAliasJoin Type
R_OrglChangeWBSElementTP R_OrglChangeWBSElementTP projection

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
VDM.viewType #CONSUMPTION view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view

OData Services (1)

ServiceBindingVersionContractRelease
UI_ORGANIZATIONALCHANGE UI_ORGANIZATIONALCHANGE_O2 V2 C1 NOT_TO_BE_RELEASED_STABLE

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY OrganizationalChange OrganizationalChange
KEY WBSElementInternalID WBSElementInternalID
WBSDescription _WBSElementExternalID WBSDescription
WBSElementExternalID WBSElementExternalID
ControllingArea ControllingArea
ProfitCenter ProfitCenter
ProfitCenterByOrglChange ProfitCenterByOrglChange
CompanyCode _WBSElementExternalID CompanyCode
CompanyCodeName
ProjectExternalID
ProjectDescription
ProjectProfileCode
ProjectProfileCodeTextlocalized
ProjectType _WBSElementExternalID ProjectType
WBSElementIsBillingElement _WBSElement WBSElementIsBillingElement
LastChangeDateTime LastChangeDateTime
LastChangedByUser LastChangedByUser 
//@EndUserText.label:                      'Org.Change WBS Element'

@AccessControl.authorizationCheck:       #CHECK
@VDM.viewType:                           #CONSUMPTION
@VDM.usage.type:                         [#TRANSACTIONAL_PROCESSING_SERVICE]

@Metadata.allowExtensions:               true
@Metadata.ignorePropagatedAnnotations:   true
//@Search.searchable:                      true


@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
//------------------------------------------------------------------






define view entity C_OrglChangeWBSElementTP
  as projection on R_OrglChangeWBSElementTP


{
            @ObjectModel.foreignKey.association: '_OrganizationalChange'
  key       OrganizationalChange,


  key       WBSElementInternalID,


            @Semantics.text:true
            _WBSElementExternalID.WBSDescription                 as WBSDescription,


            @ObjectModel.text.element: ['WBSDescription']
            WBSElementExternalID,


            ControllingArea,



            @ObjectModel.text.element: ['ProfitCenterBfrOrglChangeName']
            ProfitCenter,


            @Semantics.text:true

            _ProfitCenterBfrOrglChangeText.ProfitCenterName      as ProfitCenterBfrOrglChangeName : localized,



            @ObjectModel.text.element: ['ProfitCenterByOrglChangeName']
            ProfitCenterByOrglChange,

            @Semantics.text:true
            _ProfitCenterByOrglChangeText.ProfitCenterName       as ProfitCenterByOrglChangeName  : localized,

            @Consumption: {semanticObject:      'CompanyCode'}
            @ObjectModel.text.element: ['CompanyCodeName']
            _WBSElementExternalID.CompanyCode,


            @Semantics.text:true
            _WBSElementExternalID._CompanyCode.CompanyCodeName   as CompanyCodeName,


            @ObjectModel.text.element: ['ProjectDescription']
            _WBSElementExternalID._Project.ProjectWithCodingMask as ProjectExternalID,


            @Semantics.text:true
            _WBSElementExternalID._Project.ProjectDescription    as ProjectDescription,


            @ObjectModel.text.element: ['ProjectProfileCodeText']
            _WBSElementExternalID._Project.ProjectProfileCode    as ProjectProfileCode,



            @Semantics.text:true
            _WBSElementExternalID._Project._ProjectProfileCode._Text.ProjectProfileCodeText       : localized,



            @ObjectModel.text.element: ['ProjectTypeName']
            _WBSElementExternalID.ProjectType                    as ProjectType,
            @Semantics.text:true
            _WBSElementExternalID._ProjectType._Text.ProjectTypeName as ProjectTypeName : localized,


            _WBSElement.WBSElementIsBillingElement               as WBSElementIsBillingElement,

            LastChangeDateTime,

            LastChangedByUser,


            _OrganizationalChange : redirected to parent C_OrganizationalChangeTP


}

Learn More