C_ObjPgMaintNotificationTask

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Notification Task'
@Metadata.allowExtensions: true
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #CONSUMPTION
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view entity C_ObjPgMaintNotificationTask
  as select from I_MaintNotificationTaskTP
{
      @UI.hidden: true
  key I_MaintNotificationTaskTP.MaintenanceNotification,
      @UI: {lineItem: [ { position: 10, importance: #HIGH }]}
      @ObjectModel.text.element:  [ 'MaintNotifTaskTxt' ]
      @UI.textArrangement: #TEXT_FIRST
      @EndUserText:{label: 'Task', quickInfo: 'Task'}
  key I_MaintNotificationTaskTP.MaintenanceNotificationTask,
      @UI.hidden: true
      I_MaintNotificationTaskTP.MaintenanceNotificationItem,
      @UI: {lineItem: [ { position: 20, importance: #HIGH }]}
      @EndUserText.label: 'Task Code Group'
      @ObjectModel.text.element:  [ 'MaintNotifTaskCodeGroupName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationTaskTP.MaintNotifTaskCodeGroup,
      @EndUserText.label: 'Task Code Group Name'
      @Semantics.text: true
      replace(I_MaintNotificationTaskTP._MaintNotifTaskCodeGroup._Text[1:Language=$session.system_language].InspSpecAddlCodeGroupText, '&', ' ')  as MaintNotifTaskCodeGroupName,
      @UI: {lineItem: [ { position: 30, importance: #HIGH }]}
      @EndUserText.label: 'Task Code'
      @ObjectModel.text.element:  [ 'MaintNotifTaskCodeName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationTaskTP.MaintNotifTaskCode,
      @Semantics.text: true
      @EndUserText:{label: 'Task Code Name', quickInfo: 'Task Code Name'}
      I_MaintNotificationTaskTP._MaintNotificationTaskCode._Text[1:Language=$session.system_language].InspectionCodeText                          as MaintNotifTaskCodeName,
      @Semantics.text: true
      I_MaintNotificationTaskTP.MaintNotifTaskTxt,
      @UI: {lineItem: [ { position: 60, importance: #HIGH }]}
      @EndUserText.label: 'System Status'
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_NTFTSK_STS_EXIT'
      cast ('' as vdm_j_system_status_concat_t)                                                                                                   as ConcatenatedActiveSystStsName,
      @UI: {lineItem: [ { position: 70, importance: #HIGH }]}
      @EndUserText.label: 'User Status'
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_NTFTSK_STS_EXIT'
      cast ('' as vdm_j_user_status_concat_t)                                                                                                     as ConcatenatedActiveUserStsName,
      @UI: {lineItem: [ { position: 80, importance: #HIGH }]}
      @ObjectModel.text.element:  [ 'MaintNotifTaskPartFuncName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationTaskTP.ResponsiblePersonFunctionCode,
      @EndUserText:{label: 'Task Processor Text', quickInfo: 'Task Processor Text'}
      @Semantics.text: true
      I_MaintNotificationTaskTP._PartnerFunction._Text[1:Language=$session.system_language].PartnerFunctionName                                   as MaintNotifTaskPartFuncName,
      @UI: {lineItem: [ { position: 90, importance: #HIGH }]}
      @ObjectModel.text.element:  [ 'ResponsiblePersonName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationTaskTP.ResponsiblePerson,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_OBJPG_NTFTASK_PART_EXIT'
      @EndUserText.label: 'Responsible Name'
      cast('' as eams_person_responsible_name)                                                                                                    as ResponsiblePersonName,
      
      @UI.hidden: true
      @UI: {lineItem: [ { position: 100, importance: #HIGH }]}
      I_MaintNotificationTaskTP.PlannedStartDate,
      @UI: {lineItem: [ { position: 110, importance: #HIGH }]}
      
      @UI.hidden: true
      @EndUserText.label: 'Planned Start Time'
      I_MaintNotificationTaskTP.PlannedStartTime,
      @UI.hidden: true
      @UI: {lineItem: [ { position: 120, importance: #HIGH }]}
      @EndUserText.label: 'Planned Finish Date'
      I_MaintNotificationTaskTP.PlannedEndDate,
      
      @UI.hidden: true
      @UI: {lineItem: [ { position: 130, importance: #HIGH }]}
      @EndUserText.label: 'Planned Finish Time'
      I_MaintNotificationTaskTP.PlannedEndTime,
      @UI: {lineItem: [ { position: 100, importance: #HIGH }]}
      @EndUserText.label: 'Planned Start Date'
      cast (dats_tims_to_tstmp( PlannedStartDate, PlannedStartTime, I_MaintNotificationTaskTP._MaintenanceNotification.NotificationTimeZone , $session.client, 'NULL') as  tzntstmps preserving type ) as MaintNotifItmTskPlndStrtDteTme,
      @UI: {lineItem: [ { position: 120, importance: #HIGH }]}
      @EndUserText.label: 'Planned Finish Date'
      cast (dats_tims_to_tstmp( PlannedEndDate, PlannedEndTime, I_MaintNotificationTaskTP._MaintenanceNotification.NotificationTimeZone , $session.client, 'NULL') as  tzntstmps preserving type )     as MaintNotifItmTskPlndEndDteTime,
      /* Technical Fields */
      @UI.hidden: true
      I_MaintNotificationTaskTP.MaintNotifTaskInternalID,
      
      @UI.hidden: true // n3086741

      I_MaintNotificationTaskTP.IsDeleted, // n3086741


      /* Associations - DPP */
      I_MaintNotificationTaskTP._MaintenanceNotification,
      I_MaintNotificationTaskTP._PartnerFunction,
      I_MaintNotificationTaskTP._ContactPerson,
      I_MaintNotificationTaskTP._Customer,
      I_MaintNotificationTaskTP._Employee,
      I_MaintNotificationTaskTP._OrganizationalUnitText,
      I_MaintNotificationTaskTP._PositionText,
      I_MaintNotificationTaskTP._Supplier,
      I_MaintNotificationTaskTP._User

}