C_NO_SAFTBusPartAcctBalanceC

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED
@Analytics.internalName: #LOCAL
@VDM.viewType: #CONSUMPTION
@Analytics.dataCategory: #CUBE
@Metadata.allowExtensions:true
@Consumption.dbHints: ['USE_HEX_PLAN']
@EndUserText.label: 'SAFT Norway BP Account Balance - Cube'

define view entity C_NO_SAFTBusPartAcctBalanceC
  with parameters
    P_FromPostingDate : budat,
    P_ToPostingDate   : budat,
    P_FiscalYear      : gjahr

  as select from I_NO_SAFTBusPartAcctBalance( P_FromPostingDate: $parameters.P_FromPostingDate,
                                              P_ToPostingDate: $parameters.P_ToPostingDate,
                                              P_FiscalYear: $parameters.P_FiscalYear ) as Balance
    inner join   I_CompanyCode                                                         as Company on Company.CompanyCode = Balance.CompanyCode

{
  key Balance.CompanyCode,
  key Balance.Customer,
  key Balance.Supplier,
  key Balance.Ledger,
  key Balance.GLAccount,

      case
        when Balance.Customer is initial
        then cast ('S' as bu_bpkind )
        else cast ('C' as bu_bpkind )
      end as BusinessPartnerType,

      Balance.CompanyCodeCurrency,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      case when Balance.StartingBalanceAmtInCoCodeCrcy > 0
        then Balance.StartingBalanceAmtInCoCodeCrcy
        else cast( 0 as abap.curr(23,2) )
      end as DebitStartingBalAmtInCCCrcy,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      case when Balance.StartingBalanceAmtInCoCodeCrcy < 0
        then abs(Balance.StartingBalanceAmtInCoCodeCrcy)
        else cast( 0 as abap.curr(23,2) )
      end as CreditStartingBalAmtInCCCrcy,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      case when Balance.EndingBalanceAmtInCoCodeCrcy > 0
       then Balance.EndingBalanceAmtInCoCodeCrcy
       else cast( 0 as abap.curr(23,2) )
      end as DebitEndingBalAmtInCCCrcy,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      case when Balance.EndingBalanceAmtInCoCodeCrcy < 0
       then abs(Balance.EndingBalanceAmtInCoCodeCrcy)
       else cast( 0 as abap.curr(23,2) )
      end as CreditEndingBalAmtInCCCrcy,

      'X' as ItemIsReportingRelevant
}
where  //Select only GL accounts with the same company code currency

       Balance.CompanyCodeCurrency            =  Company.Currency
  and( //Select only GL accounts with openning/closing balances

       Balance.StartingBalanceAmtInCoCodeCrcy <> 0
    or Balance.EndingBalanceAmtInCoCodeCrcy   <> 0
  )