C_MnllyCreatedJournalEntry

@AbapCatalog.sqlViewName: 'CGRCMNLLYCRTJREN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Manual Postings created by dialog IDs'
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
define view C_MnllyCreatedJournalEntry
  with parameters
    @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_CompanyCodeStdVH',
                         element: 'CompanyCode' }}]
    @EndUserText.label: 'Company Code'
    P_CompanyCode            :bukrs,
    @EndUserText.label: 'Fiscal Year'
    P_FiscalYear             :gjahr,
    @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_AccountingDocumentTypeStdVH',
                   element: 'AccountingDocumentType' }
      }]
    @EndUserText.label: 'Accounting Document Type'
    P_AccountingDocumentType :blart


  as select from I_GLAccountLineItemRawData
  association [0..1] to I_User as _User on $projection.AccountingDocCreatedByUser = _User.UserID
{
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key FiscalYear,
      @ObjectModel.foreignKey.association: '_JournalEntry'
  key AccountingDocument                           as JournalEntry,
      @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_LedgerStdVH', element: 'Ledger' } }]
      @ObjectModel.foreignKey.association: '_Ledger'
  key cast(SourceLedger as rldnr preserving type ) as Ledger,

      FiscalYearPeriod,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      sum(case DebitCreditCode  when 'S' then cast( AmountInCompanyCodeCurrency as fis_dr_hsl preserving type )
                                                                else cast( cast( 0 as abap.curr( 23,2) ) as fis_dr_hsl preserving type )
      end)                                         as DebitAmountInCoCodeCrcy,

      AccountingDocCreatedByUser,
      _JournalEntry.AccountingDocumentCreationDate,

      @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_AccountingDocumentTypeStdVH',
               element: 'AccountingDocumentType' }
      }]
      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      AccountingDocumentType,

      _JournalEntry.ReverseDocument,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BusTransTypeStdVH',
                     element: 'BusinessTransactionType' }
        }]
      @ObjectModel.foreignKey.association: '_BusinessTransactionType'
      BusinessTransactionType,
      DocumentDate,
      PostingDate,
      _JournalEntry.LastChangeDate,

      _JournalEntry.TransactionCode,
      _JournalEntry.DocumentReferenceID,
      AccountingDocumentCategory,
      @ObjectModel.foreignKey.association: '_ReferenceDocumentType'
      ReferenceDocumentType,
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      @Semantics.currencyCode:true
      CompanyCodeCurrency,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      sum(case DebitCreditCode  when 'H' then cast( AmountInCompanyCodeCurrency as fis_cr_hsl preserving type )
                                                                else cast( cast( 0 as abap.curr( 23,2) ) as fis_cr_hsl preserving type )
      end)                                         as CreditAmountInCoCodeCrcy,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      sum(AmountInCompanyCodeCurrency)             as AmountInCompanyCodeCurrency,

      _CompanyCode,
      _FiscalYear,
      _JournalEntry,
      _Ledger,
      _AccountingDocumentType,
      _AccountingDocumentCategory,
      _BusinessTransactionType,
      _ReferenceDocumentType,
      _CompanyCodeCurrency


}

where
      _User.IsTechnicalUser = ''
  and AccountingDocumentType      = $parameters.P_AccountingDocumentType
  and CompanyCode                 = $parameters.P_CompanyCode
  and FiscalYear                  = $parameters.P_FiscalYear
  and IsReversal                  = ''
  and IsReversed                  = ''

group by

  CompanyCode,
  FiscalYear,
  AccountingDocument,
  SourceLedger,
  FiscalPeriod,
  AccountingDocumentType,
  CompanyCodeCurrency,
  PostingDate,
  _JournalEntry.ReverseDocument,
  BusinessTransactionType,
  DocumentDate,
  _JournalEntry.AccountingDocumentCreationDate,
  _JournalEntry.LastChangeDate,
  AccountingDocCreatedByUser,
  _JournalEntry.TransactionCode,
  _JournalEntry.DocumentReferenceID,
  AccountingDocumentCategory,
  ReferenceDocumentType,
  FiscalYearPeriod