C_MngProdnOrderMfgOrder

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Manufacturing Order'
@ObjectModel.representativeKey: 'ManufacturingOrder'
@ObjectModel.semanticKey: ['ManufacturingOrder']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
// private consumption view for manufacturing orders based on I_MfgOrder

// to be used as helper view in other consumption views only

define view entity C_MngProdnOrderMfgOrder as select from I_ManufacturingOrder as ord
{
// Key

      @ObjectModel.text.element: ['ManufacturingOrderText']
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key ord.ManufacturingOrder,

      // Category and Type

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      ord.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      ord.ManufacturingOrderType,

      // Short Text

      @Semantics.text: true
      ord.ManufacturingOrderText,

      // Attributes

      ord.ManufacturingOrderHasLongText,
      ord.ManufacturingOrderImportance,
      ord.IsMarkedForDeletion as MfgOrderIsToBeDeleted,
      ord.MfgOrderHasMultipleItems,
      ord.MfgOrderIsPartOfCollvOrder,
      ord.MfgOrderHierarchyLevel,
      ord.IsCompletelyDelivered,

      // Admin

      @Semantics.systemDate.createdAt: true
      ord.MfgOrderCreationDate,
      @Semantics.systemTime.createdAt: true
      ord.MfgOrderCreationTime,
      ord.CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      ord.LastChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      ord.LastChangeTime,
      ord.LastChangedByUser,

      // Assignments

      @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
      ord.MfgOrderInternalID as OrderInternalBillOfOperations,
--    @ObjectModel.foreignKey.association: '_ReferenceOrder'
      ord.ReferenceOrder,
--    @ObjectModel.foreignKey.association: '_LeadingOrder'
      ord.LeadingOrder,
--    @ObjectModel.foreignKey.association: '_SuperiorOrder'
      ord.SuperiorOrder as MfgOrderSuperiorMfgOrder,
      @ObjectModel.foreignKey.association: '_Currency'
      ord.Currency,
      @ObjectModel.foreignKey.association: '_Plant'
      ord.ProductionPlant,
      @ObjectModel.foreignKey.association: '_Material'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      ord.Material,
      @ObjectModel.foreignKey.association: '_MRPPlant'
      ord.PlanningPlant as MRPPlant,
      @ObjectModel.foreignKey.association: '_MRPArea'
      ord.MRPArea,
      @ObjectModel.foreignKey.association: '_MRPController'
      ord.MRPController,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      ord.ProductionSupervisor,
      @ObjectModel.foreignKey.association: '_ProductionSchedulingProfile'
      ord.ProductionSchedulingProfile,
      @ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
      ord.ResponsiblePlannerGroup,
      @ObjectModel.foreignKey.association: '_ProductionVersion'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductionVersionStdVH', element: 'ProductionVersion' } } ]
      ord.ProductionVersion,
      @ObjectModel.foreignKey.association: '_PlannedOrder'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlannedOrderStdVH', element: 'PlannedOrder' } } ]
      ord.PlannedOrder,
      @ObjectModel.foreignKey.association: '_SalesDocument'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesDocumentStdVH', element: 'SalesDocument' } } ]
      cast(ord.SalesOrder    as vdm_vbeln preserving type)                             as SalesDocument,
      @ObjectModel.foreignKey.association: '_SalesDocumentItem'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesDocumentItemStdVH', element: 'SalesDocumentItem' } } ]
      cast(ord.SalesOrderItem  as vdm_posnr preserving type)                           as SalesDocumentItem,
      @ObjectModel.foreignKey.association: '_WBSElement'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElmntByIntKeyStdVH', element: 'WBSElementInternalID' } } ]
      ord.WBSElementInternalID,
      @ObjectModel.foreignKey.association: '_Reservation'
      ord.Reservation,
      @ObjectModel.foreignKey.association: '_ConfirmationGroup'
      ord.MfgOrderConfirmation,
      ord.NumberOfMfgOrderConfirmations as MfgOrderConfirmationCount,
      @ObjectModel.foreignKey.association: '_CapacityRequirement'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CapacityRequirementStdVH', element: 'CapacityRequirement' } } ]
      ord.CapacityRequirement,
      @ObjectModel.foreignKey.association: '_InspectionLot'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_InspectionLotStdVH', element: 'InspectionLot' } } ]
      ord.InspectionLot,
      @ObjectModel.foreignKey.association: '_ChangeNumber'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ChangeMasterStdVH', element: 'ChangeNumber' } } ]
      ord.ChangeNumber,
      @ObjectModel.foreignKey.association: '_BasicSchedulingType'
      ord.BasicSchedulingType,
      @ObjectModel.foreignKey.association: '_ForecastSchedulingType'
      ord.ForecastSchedulingType,
      cast(ord.ObjectInternalID       as pph_objnr preserving type)                   as ManufacturingObject,
      ord.ProductConfiguration,
      ord.ConditionApplication,

      // Assignments BOO

      @ObjectModel.foreignKey.association: '_BillOfOperationsMaterial'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      ord.BillOfOperationsMaterial,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      ord.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      @VDM.lifecycle.status: #DEPRECATED           // default data element change -> deprecated to avoid RTT2 error in ATC

      @VDM.lifecycle.successor: 'BillOfOperationsGroup'
      ord.BillOfOperations,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup2'
      ord.BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]
      ord.BillOfOperationsVariant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsChangeState'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BOOChgStateStdVH', element: 'BOOInternalVersionCounter' } } ]
      ord.BOOInternalVersionCounter,
      @ObjectModel.foreignKey.association: '_BillOfOperationsUsage'
      ord.BillOfOperationsUsage,
      @Semantics.businessDate.at: true
      ord.BOOExplosionDate,
      @Semantics.calendarItem.dtStart: true
      ord.BOOValidityStartDate,
      // Assignments BOM

      ord.BillOfMaterialCategory,
      ord.BillOfMaterial,
      ord.BillOfMaterialVariant,
      ord.BillOfMaterialVariantUsage,
      @Semantics.businessDate.at: true
      ord.BOMExplosionDate,
      @Semantics.calendarItem.dtStart: true
      ord.BOMValidityStartDate,

      // Assignments FI/CO

      @ObjectModel.foreignKey.association: '_BusinessArea'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
      ord.BusinessArea,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      ord.CompanyCode,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ControllingArea', element: 'ControllingArea' } } ]
      ord.ControllingArea,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProfitCenterStdVH', element: 'ProfitCenter' } } ]
      ord.ProfitCenter,
      @ObjectModel.foreignKey.association: '_CostCenter'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' } } ]
      ord.CostCenter,
      @ObjectModel.foreignKey.association: '_ResponsibleCostCenter'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' } } ]
      ord.ResponsibleCostCenter,
      ord.CostElement,
      ord.CostingSheet,
      ord.GLAccount,
      ord.ProductCostCollector,
      ord.ActualCostsCostingVariant,
      ord.PlannedCostsCostingVariant,
      @ObjectModel.foreignKey.association: '_ControllingObjectClass'
      ord.ControllingObjectClass,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      ord.FunctionalArea,

      // Dates and Times

      @Semantics.calendarItem.dtStart: true
      ord.MfgOrderPlannedStartDate,
      ord.MfgOrderPlannedStartTime,
      @Semantics.calendarItem.dtEnd: true
      ord.MfgOrderPlannedEndDate,
      ord.MfgOrderPlannedEndTime,
      ord.MfgOrderPlannedReleaseDate,
      @Semantics.calendarItem.dtStart: true
      ord.MfgOrderScheduledStartDate,
      ord.MfgOrderScheduledStartTime,
      @Semantics.calendarItem.dtEnd: true
      ord.MfgOrderScheduledEndDate,
      ord.MfgOrderScheduledEndTime,
      ord.MfgOrderScheduledReleaseDate,
      @Semantics.calendarItem.dtStart: true
      ord.MfgOrderActualStartDate,
      ord.MfgOrderActualStartTime,
      @Semantics.calendarItem.dtEnd: true
      ord.MfgOrderActualEndDate,
      ord.MfgOrderActualReleaseDate,
      @Semantics.calendarItem.dtEnd: true
      ord.MfgOrderConfirmedEndDate,
      ord.MfgOrderConfirmedEndTime,
      @Semantics.businessDate.at: true
      ord.MfgOrderTotalCommitmentDate,
      @Semantics.businessDate.at: true
      ord.MfgOrderItemActualDeliveryDate,

      // Quantities and UoM

      ord.ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @DefaultAggregation: #NONE
      ord.MfgOrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @DefaultAggregation: #NONE
      ord.MfgOrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @DefaultAggregation: #NONE
      ord.MfgOrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @DefaultAggregation: #NONE
      ord.MfgOrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @DefaultAggregation: #NONE
      ord.MfgOrderConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @DefaultAggregation: #NONE
      ord.ExpectedDeviationQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @DefaultAggregation: #NONE
      ord.ActualDeliveredQuantity,
      @UI.hidden: true
      ord.Product,

      // Associations

      _MfgOrderCategory,
      _MfgOrderType,
      _OrderTypeDetails,
      _CreatedByUser,
      _LastChangedByUser,
      _ProductionUnit,
      _Currency,
      _OrderInternalID as _OrdInternalBillOfOperations,
      _BillOfOperationsMaterial,
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperationsGroup2,
      _BillOfOperations,
      _BillOfOperationsChangeState,
      _BillOfOperationsUsage,
      _ConfirmationGroup,
      _Reservation,
      _ProductionPlant as _Plant,
      _Material,
      _ProductPlant as _MaterialPlant,
      _MRPArea,
      _PlanningPlant as _MRPPlant,
      _MRPController,
      _ProductionSupervisor,
      _ProductionSchedulingProfile,
      _ResponsiblePlannerGroup,
      _ProductionVersion,
      _CapacityRequirement,
      _ChangeNumber,
      _InspectionLot,
      _PlannedOrder,
      _SalesDocument,
      _SalesDocumentItem,      
      _WBSElement,
      _BusinessArea,
      _ProfitCenter,
      _CostCenter,
      _ResponsibleCostCenter,
      _CompanyCode,
      _ControllingArea,
      _ControllingObjectClass,
      _FunctionalArea,
      _BasicSchedulingType,
      _ForecastSchedulingType
};