C_MngJrnlEntrPrkdDocTaxItem

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Journal Entry Parked Document Tax Item'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
        dataClass: #MIXED,
        serviceQuality: #C,
        sizeCategory: #XL
}

@UI.headerInfo: {
  typeName: 'Tax',
  typeNamePlural: 'Taxes'
}

@UI.presentationVariant: [{
    sortOrder: [{
      by: 'AccountingDocument',
      direction: #ASC
    }]
}]

@VDM.viewType: #CONSUMPTION

define view entity C_MngJrnlEntrPrkdDocTaxItem
  as select from R_MngJrnlEntrPrkdDocTaxItem
  association [0..1] to I_CompanyCode as _CompanyCode on  $projection.SourceCompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_TaxCodeText as _TaxCodeText on  $projection.TaxCode                 = _TaxCodeText.TaxCode
                                                      and $projection.TaxCalculationProcedure = _TaxCodeText.TaxCalculationProcedure
                                                      and _TaxCodeText.Language               = $session.system_language

{
      @ObjectModel.text.element:  [ 'CompanyCodeName' ]
      @UI.textArrangement: #TEXT_LAST
  key SourceCompanyCode,
      @Consumption.semanticObject: 'AccountingDocument'
  key AccountingDocument,
  key FiscalYear,
  key ParkedAccountingDocumentItem,
      @EndUserText.label: 'Debit/Credit Indicator'
      DebitCreditCode,
      @UI: {
      lineItem: [{ position: 10 }]
      }
      @ObjectModel.text.element:  [ 'TaxCodeName' ]
      @UI.textArrangement: #TEXT_LAST
      TaxCode,
      TaxJurisdiction,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @EndUserText.label: 'Tax Amount in Transaction Currency'
      @UI.hidden: true
      TaxAmountInTransCrcy,
      @UI: {
      lineItem: [{ position: 20 }]
      }
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @EndUserText.label: 'Tax Amount in Company Code Currency'
      @UI.hidden: true
      TaxAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      @EndUserText.label: 'Tax Amount in Additional Currency 1'
      @UI.hidden: true
      TaxAmountInAdditionalCurrency1,
      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      @EndUserText.label: 'Tax Amount in Additional Currency 2'
      @UI.hidden: true      
      TaxAmountInAdditionalCurrency2,
      CompanyCodeCurrency,
      TransactionCurrency,
      AdditionalCurrency1,
      AdditionalCurrency2,
      @Semantics.text: true
      cast(_CompanyCode.CompanyCodeName as fis_butxt preserving type) as CompanyCodeName,
      TaxCountry,
      TaxDeterminationDate,
      TaxRateValidityStartDate,      
      TaxCalculationProcedure,
      @Semantics.text: true
      _TaxCodeText.TaxCodeName,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} } 
      @EndUserText.label: 'Credit Tax Amount in Company Code Currency'    
      CreditAmountInCoCodeCrcy,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      @EndUserText.label: 'Debit Tax Amount in Company Code Currency'   
      DebitAmountInCoCodeCrcy,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      @EndUserText.label: 'Credit Tax Amount in Transaction Currency'
      CreditAmountInTransCrcy,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      @EndUserText.label: 'Debit Tax Amount in Transaction Currency'
      DebitAmountInTransCrcy,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} } 
      @EndUserText.label: 'Credit Tax Amount in Additional Currency 1'
      CreditAmountInAddlCrcy1,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      @EndUserText.label: 'Debit Tax Amount in Additional Currency 1' 
      DebitAmountInAddlCrcy1,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      @EndUserText.label: 'Credit Tax Amount in Additional Currency 2'
      CreditAmountInAddlCrcy2,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      @EndUserText.label: 'Debit Tax Amount in Additional Currency 2'
      DebitAmountInAddlCrcy2      
}