C_MfgStdTextVersWhereUsedList
View for ST Where Used List
C_MfgStdTextVersWhereUsedList is a Consumption CDS View that provides data about "View for ST Where Used List" in SAP S/4HANA. It reads from 6 data sources and exposes 17 fields with key fields MfgWorkInstruction, MfgWorkInstructionVersCounter, MfgStandardText, MfgStandardTextVersion, Language. Part of development package MPE_ST.
Data Sources (6)
| Source | Alias | Join Type |
|---|---|---|
| I_BOOOperationChgStOANBasic | BillOfOperationChg | inner |
| I_BillOfOperationsOpBasic | BillOfOperationOpBasic | inner |
| I_BillOfOperationsVersion | BillOfOperationsVersion | inner |
| I_BOOSqncOperationAssgmtChgSt | BooSqncOpAssgmt | inner |
| I_OpActyNtwkElement | OAN | inner |
| I_OpActyWorkInstructionAssgmt | OpActyWI | inner |
Annotations (13)
| Name | Value | Level | Field |
|---|---|---|---|
| AbapCatalog.sqlViewName | CSTWHEREUSED | view | |
| AbapCatalog.compiler.compareFilter | true | view | |
| AbapCatalog.preserveKey | true | view | |
| AccessControl.authorizationCheck | #CHECK | view | |
| EndUserText.label | View for ST Where Used List | view | |
| VDM.viewType | #CONSUMPTION | view | |
| ObjectModel.usageType.serviceQuality | #C | view | |
| ObjectModel.usageType.sizeCategory | #M | view | |
| ObjectModel.usageType.dataClass | #TRANSACTIONAL | view | |
| ClientHandling.algorithm | #SESSION_VARIABLE | view | |
| Search.searchable | true | view | |
| UI.headerInfo.typeName | Operation Activity | view | |
| UI.headerInfo.typeNamePlural | Operation Activities | view |
Fields (17)
| Key | Field | Source Table | Source Field | Description |
|---|---|---|---|---|
| KEY | MfgWorkInstruction | MfgWorkInstruction | ||
| KEY | MfgWorkInstructionVersCounter | MfgWorkInstructionVersCounter | ||
| KEY | MfgStandardText | MfgStandardText | ||
| KEY | MfgStandardTextVersion | MfgStandardTextVersion | ||
| KEY | Language | Language | ||
| KEY | BillOfOperationsGroup | I_BillOfOperationsVersion | BillOfOperationsGroup | |
| KEY | BOOOpInternalVersionCounter | I_BillOfOperationsOpBasic | BOOOpInternalVersionCounter | |
| KEY | BillOfOperationsVariant | I_BillOfOperationsVersion | BillOfOperationsVariant | |
| BillOfOperationsDisplayKey | Routing Group | |||
| BOOVersionStatusText | Status | |||
| OperationActivity | I_OpActyWorkInstructionAssgmt | OperationActivity | ||
| OperationText | I_BillOfOperationsOpBasic | OperationText | Operation | |
| Operation | ||||
| OperationActivityName | Operation Activity | |||
| OpActyNtwkElementExternalID | I_OpActyNtwkElement | OpActyNtwkElementExternalID | ||
| BillOfOperationsType | I_BillOfOperationsOpBasic | BillOfOperationsType | ||
| BillOfOperationsVersion | I_BillOfOperationsVersion | BillOfOperationsVersion |
@AbapCatalog.sqlViewName: 'CSTWHEREUSED'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'View for ST Where Used List'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType:{
serviceQuality: #C,
sizeCategory: #M,
dataClass: #TRANSACTIONAL
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@UI.headerInfo:{
typeName: 'Operation Activity',
typeNamePlural: 'Operation Activities'
}
@UI.presentationVariant.requestAtLeast: ['Language_Text','BillOfOperationsGroup', 'BillOfOperationsVersion','BillOfOperationsVariant','BillOfOperationsType']
define view C_MfgStdTextVersWhereUsedList
as select distinct from I_MfgWorkInstructionStdTextRef as STRef
inner join I_OpActyWorkInstructionAssgmt as OpActyWI on STRef.MfgWorkInstruction = OpActyWI.WorkInstruction
and STRef.MfgWorkInstructionVersCounter = OpActyWI.WorkInstructionVersionCounter
inner join I_OpActyNtwkElement as OAN on OpActyWI.OperationActivity = OAN.OpActyNtwkElementElement
and OpActyWI.OperationActyVersionCounter = OAN.OpActyNtwkElementElmntVersCntr
and OAN.OpActyNtwkElementType = 3
inner join I_BOOOperationChgStOANBasic as BillOfOperationChg on(
(
OAN.OperationActivityNetwork = BillOfOperationChg.ProduceOpActyNtwk
and OAN.OpActyNtwkVersionCounter = BillOfOperationChg.ProduceOpActyNtwkVersCounter
)
or(
OAN.OperationActivityNetwork = BillOfOperationChg.SetupOpActyNtwk
and OAN.OpActyNtwkVersionCounter = BillOfOperationChg.SetupOpActyNtwkVersCounter
)
or(
OAN.OperationActivityNetwork = BillOfOperationChg.TeardownOpActyNtwk
and OAN.OpActyNtwkVersionCounter = BillOfOperationChg.TeardownOpActyNtwkVersCounter
)
)
inner join I_BillOfOperationsOpBasic as BillOfOperationOpBasic on BillOfOperationChg.BillOfOperationsGroup = BillOfOperationOpBasic.BillOfOperationsGroup
and BillOfOperationChg.BillOfOperationsType = BillOfOperationOpBasic.BillOfOperationsType
and BillOfOperationChg.BOOOperationInternalID = BillOfOperationOpBasic.BOOOperationInternalID
and BillOfOperationChg.BOOOpInternalVersionCounter = BillOfOperationOpBasic.BOOOpInternalVersionCounter
inner join I_BOOSqncOperationAssgmtChgSt as BooSqncOpAssgmt on BillOfOperationOpBasic.BillOfOperationsGroup = BooSqncOpAssgmt.BillOfOperationsGroup
and BillOfOperationOpBasic.BillOfOperationsType = BooSqncOpAssgmt.BillOfOperationsType
and BillOfOperationOpBasic.BOOOperationInternalID = BooSqncOpAssgmt.BOOOperationInternalID
and BillOfOperationOpBasic.BillOfOperationsVersion = BooSqncOpAssgmt.BillOfOperationsVersion
and BillOfOperationOpBasic.BOOOpInternalVersionCounter = BooSqncOpAssgmt.BOOSqncOpAssgmtIntVersionCntr
inner join I_BillOfOperationsVersion as BillOfOperationsVersion on BillOfOperationOpBasic.BillOfOperationsGroup = BillOfOperationsVersion.BillOfOperationsGroup
and BooSqncOpAssgmt.BillOfOperationsVariant = BillOfOperationsVersion.BillOfOperationsVariant
and BillOfOperationOpBasic.BillOfOperationsType = BillOfOperationsVersion.BillOfOperationsType
and BillOfOperationOpBasic.BillOfOperationsVersion = BillOfOperationsVersion.BillOfOperationsVersion
// inner join I_BOOMaterialAssignment as BooMaterialAssgmt on BillOfOperationChg.BillOfOperationsGroup = BooMaterialAssgmt.BillOfOperationsGroup
// and BillOfOperationChg.BillOfOperationsType = BooMaterialAssgmt.BillOfOperationsType
// and BooSqncOpAssgmt.BillOfOperationsVariant = BooMaterialAssgmt.BillOfOperationsVariant
{
@UI.hidden: true
key MfgWorkInstruction,
@UI.hidden: true
key MfgWorkInstructionVersCounter,
@UI.hidden: true
key MfgStandardText,
@UI.hidden: true
key MfgStandardTextVersion,
@UI.hidden: true
key Language as Language,
@Search.defaultSearchElement: true
key BillOfOperationsVersion.BillOfOperationsGroup,
@UI.hidden: true
key BillOfOperationOpBasic.BOOOpInternalVersionCounter,
//@Consumption.hidden: true
// @UI: {
// lineItem:
// {
// position: 40,
// importance: #HIGH
// },
// identification : {position:40}
// }
@Search.defaultSearchElement: true
key BillOfOperationsVersion.BillOfOperationsVariant,
@UI: {
lineItem:
{
position: 20,
importance: #HIGH
},
identification : {position:20}
}
// @Search.defaultSearchElement: true
@Consumption.semanticObject:'ShopFloorRouting'
@EndUserText.label: 'Routing Group'
concat(concat(BillOfOperationsVersion.BillOfOperationsGroup, ('-')), concat(BillOfOperationsVersion.BillOfOperationsVariant, concat(('-'), BillOfOperationsVersion.BillOfOperationsVersion))) as BillOfOperationsDisplayKey,
@UI: {
lineItem:
{
position: 50,
importance: #HIGH
},
identification : {position:50}
}
@EndUserText.label: 'Status'
// @Search.defaultSearchElement: true
BillOfOperationsVersion._BOOVersionStatus._Text[1:Language = $session.system_language].BOOVersionStatusText,
@UI.hidden: true
OpActyWI.OperationActivity,
@UI: {
lineItem:
{
position: 60,
importance: #HIGH
},
identification : {position:60}
}
@ObjectModel.text.element: [ 'Operation' ]
@UI.textArrangement: #TEXT_LAST
@Search.defaultSearchElement: true
@EndUserText.label: 'Operation'
BillOfOperationOpBasic.OperationText,
@UI.hidden: true
cast(BillOfOperationOpBasic.Operation as pph_vornr preserving type) as Operation,
@UI: {
lineItem:
{
position: 70,
importance: #HIGH
},
identification : {position:70}
}
@ObjectModel.text.element: [ 'OpActyNtwkElementExternalID' ]
@UI.textArrangement: #TEXT_LAST
@Search.defaultSearchElement: true
@EndUserText.label: 'Operation Activity'
OAN._OperationActivityText[1:Language = $session.system_language].OperationActivityName,
@UI.hidden: true
OAN.OpActyNtwkElementExternalID,
@UI.hidden: true
BillOfOperationOpBasic.BillOfOperationsType,
//@UI.hidden: true
// @UI: {
// lineItem:
// {
// position: 30,
// importance: #HIGH
// },
// identification : {position:30}
// }
@Search.defaultSearchElement: true
BillOfOperationsVersion.BillOfOperationsVersion
}
Learn More
- What Is a CDS View in SAP S/4HANA?
- Types of CDS Views: Basic, Composite, Consumption, and Transactional
- SAP Tables vs CDS Views — Key Differences
- Understanding Data Lineage in SAP S/4HANA
- VDM (Virtual Data Model) in SAP S/4HANA Explained
- CDS View Annotations — A Complete Guide
- CDS View Field Mapping and Associations
- Understanding the SAP S/4HANA Data Model
- CDS View Extensions and Custom Fields in SAP S/4HANA
- Released APIs and Stability Contracts in SAP S/4HANA