C_MfgOrderOperationPRT

@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@Analytics:{dataCategory:#DIMENSION }
@ObjectModel.representativeKey: 'MfgOrderOpProdnRsceToolIntID'
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #CONSUMPTION
@Analytics.internalName:#LOCAL 
@EndUserText.label: 'Production Resource Tools for Order and Operation'
define view entity C_MfgOrderOperationPRT as select from I_MfgOrderOperationPRT

association [1..1] to I_OrdInternalBillOfOperations as _OrdInternalBillOfOperations   on  $projection.OrderInternalBillOfOperations = _OrdInternalBillOfOperations.OrderInternalBillOfOperations  
 {
  // Key

       @UI.hidden
       @EndUserText.label: 'Operation Task List No.'
       @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
  key  MfgOrderInternalID as OrderInternalBillOfOperations,
       @EndUserText.label: 'PRT Item Counter'
       @UI.lineItem: [{position:10, exclude: true }]
       
       
  key  MfgOrderOpProdnRsceToolIntID,
       @UI.hidden
       ManufacturingOrder,
       @UI.lineItem: [{position:20}]
       @ObjectModel.text.element: ['ProdnRsceToolCategoryName']
       ProdnRsceToolCategory_2 as ProdnRsceToolCategory,                     // no conversion exit

       _ProdnRsceToolCategory_2._Text[1: Language=$session.system_language].ProdnRsceToolCategoryName,
       PlannedProdnRsceToolQtyUnit,
//       @DefaultAggregation: #SUM

       @UI.lineItem: [{position:30}]
       @Semantics.quantity.unitOfMeasure: 'PlannedProdnRsceToolQtyUnit'
       PlannedTotalProdnRsceToolQty,
       ConfirmedProdnRsceToolQtyUnit,
       @UI.lineItem: [{position:40}]
       @Semantics.quantity.unitOfMeasure: 'ConfirmedProdnRsceToolQtyUnit'
//       @DefaultAggregation: #SUM

       ConfirmedProdnRsceToolQty,
       ProdnRsceToolUsageQuantityUnit,
       @UI.lineItem: [{position:50}]
       @Semantics.quantity.unitOfMeasure: 'ProdnRsceToolUsageQuantityUnit'
//       @DefaultAggregation: #SUM

       ProdnRsceToolUsageQuantity,
       @Semantics.calendarItem.dtEnd: true
       @UI.lineItem: [{position:60}]
       EarliestSchedldUsageStartDate,
       EarliestSchedldUsageStartTime,
       @Semantics.calendarItem.dtEnd: true
       @UI.lineItem: [{position:70}]
       EarliestSchedldUsageEndDate,
       EarliestSchedldUsageEndTime,
       @Semantics.calendarItem.dtEnd: true
       @UI.lineItem: [{position:80}]
       LatestSchedldUsageStartDate,
       LatestSchedldUsageStartTime,
       @Semantics.calendarItem.dtEnd: true
       @UI.lineItem: [{position:90}]
       LatestSchedldUsageEndDate,
       LatestSchedldUsageEndTime,
       @ObjectModel.foreignKey.association: '_MfgOrderType'
       ManufacturingOrderType,
       @ObjectModel.foreignKey.association: '_MfgOrderCategory'
       ManufacturingOrderCategory,
       @ObjectModel.foreignKey.association: '_ProductionPlant'
       ProductionPlant,        
       ProductionResourceTool,
       @EndUserText.label:'Operation'
       @UI.lineItem: [{position:5}]
       cast( ManufacturingOrderOperation as vdm_vornr preserving type) as ManufacturingOrderOperation,
       ProdnRsceToolControlProfile,
       @EndUserText.label:'Phase'
       MfgOrderOperationIsPhase,
       @UI.hidden
       OrderOperationInternalID,
       
       _ProdnRsceToolCategory_2 as _ProdnRsceToolCategory,
       _MfgOrderCategory,
       _MfgOrderType,
       _ProductionPlant,
       _OrdInternalBillOfOperations
}
where
  IsDeleted != 'X';