C_MfgOrderConfirmation

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Manufacturing Order Confirmation'
@Search.searchable: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType:  #CONSUMPTION
@UI.headerInfo: {
    title : { type: #STANDARD, value: 'MfgOrderConfirmationGroup' },
    description : { type: #STANDARD, value: 'MfgOrderConfirmation' },
    typeName: 'Manufacturing Order Confirmation',
    typeNamePlural: 'Manufacturing Order Confirmations'   
}
define view entity C_MfgOrderConfirmation 
as select from I_MfgOrderConfirmation
//association [1..*] to I_MfgOrderHeaderConfirmation           as _headerConfirmation                  

//                                                             on  $projection.MfgOrderConfirmationGroup = _headerConfirmation.MfgOrderConfirmation



  {
        @UI.hidden: true
  key   MfgOrderConfirmationGroup,
        @UI.hidden: true
  key   MfgOrderConfirmation as MfgOrderConfirmationCount,
        @UI.hidden: true
        @Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
        ManufacturingOrder,
        @UI.hidden: true
        ConfirmationText,
        @UI.hidden: true
        _LongText.PlainLongText,
        @UI.hidden: true
        IsFinalConfirmation,
        @UI.hidden: true
        EnteredByUser,
        @UI.hidden: true
        ConfirmationUnit,
        @UI.hidden: true
        @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
        case IsReversal when '' then ConfirmationYieldQuantity  else -ConfirmationYieldQuantity  end as 
        ConfirmationYieldQuantity,
        @UI.hidden: true
        @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
        case IsReversal when '' then ConfirmationScrapQuantity  else -ConfirmationScrapQuantity  end as 
        ConfirmationScrapQuantity,
        @UI.hidden: true
        @Semantics.quantity.unitOfMeasure: 'ConfirmationUnit'
        case IsReversal when '' then ConfirmationReworkQuantity else -ConfirmationReworkQuantity end as 
        ConfirmationReworkQuantity,
        @UI.hidden: true
        cast( case OrderConfirmationRecordType                 
                when 'R10' then ConfirmedExecutionStartDate
                when 'N10' then ConfirmedExecutionStartDate
                when 'W10' then ConfirmedExecutionStartDate
                when 'R20' then ConfirmedSetupEndDate
                when 'R30' then ConfirmedSetupEndDate
                when 'R40' then ConfirmedSetupEndDate
                when 'B10' then ConfirmedProcessingStartDate
                when 'B20' then ConfirmedProcessingEndDate
                when 'B30' then ConfirmedProcessingEndDate
                when 'B40' then ConfirmedProcessingEndDate
                when 'A10' then ConfirmedTeardownStartDate
                else            ConfirmedExecutionEndDate 
              end as ru_ersda preserving type ) as MfgOrderConfirmationEntryDate,  // Logical Date  

        @UI.hidden: true
        cast( case OrderConfirmationRecordType                
                when 'R10' then ConfirmedExecutionStartTime
                when 'N10' then ConfirmedExecutionStartTime
                when 'W10' then ConfirmedExecutionStartTime
                when 'R20' then ConfirmedSetupEndTime
                when 'R30' then ConfirmedSetupEndTime
                when 'R40' then ConfirmedSetupEndTime
                when 'B10' then ConfirmedProcessingStartTime
                when 'B20' then ConfirmedProcessingEndTime
                when 'B30' then ConfirmedProcessingEndTime
                when 'B40' then ConfirmedProcessingEndTime
                when 'A10' then ConfirmedTeardownStartTime
                else            ConfirmedExecutionEndTime 
              end as ru_erzet preserving type) as MfgOrderConfirmationEntryTime,  // Logical Time

        @UI.hidden: true
        Plant,
        @UI.hidden: true
        ManufacturingOrderType,
        @UI.hidden: true
        IsReversed,
        @UI.hidden: true
        IsReversal,
        @UI.hidden: true
        CancldMfgOrderConfCount,
        @UI.hidden: true
        ManufacturingOrderOperation,
        @UI.hidden: true
        ConfirmationTotalQuantity
}