C_MaterialStockChangeDP

// for C0 release ? @AbapCatalog.extensibility: { extensible: true, elementSuffix: 'EXT' }


@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@Analytics.internalName: #LOCAL

@DataIntegration.deltaReplication.intended: true

@EndUserText.label: 'Material Stock Changes Data Provider'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.sapObjectNodeType.name: 'MaterialStockChange'
@ObjectModel.semanticKey: [ 'MaterialDocumentYear', 'MaterialDocument', 'MaterialDocumentItem' ]
@ObjectModel.supportedCapabilities: [ #EXTERNAL_DATA_PROVIDER ]
@ObjectModel.usageType: { sizeCategory: #XXL, serviceQuality: #C, dataClass: #TRANSACTIONAL }

@VDM.viewType: #CONSUMPTION

define view entity C_MaterialStockChangeDP
  as select from I_MaterialDocumentRecord

{
      // Technical key fields

      @Consumption.hidden: true
  key MaterialDocumentKey1,

      @Consumption.hidden: true
  key MaterialDocumentKey2,

      @Consumption.hidden: true
  key MaterialDocumentKey3,

      @Consumption.hidden: true
  key MaterialDocumentKey4,

      @Consumption.hidden: true
  key MaterialDocumentKey5,

      @Consumption.hidden: true
  key MaterialDocumentKey6,

      // Semantic key fields      

      @Semantics.calendar.year: true
      MaterialDocumentYear,

      MaterialDocument,
      MaterialDocumentItem,

      // Warehouse stock identifier

      StockIdentifyingMaterial,
      Plant,
      StockIdfgStorageLocation,
      StockIdentifyingBatch,
      SpecialStockIdfgSupplier,
      SpecialStockIdfgSalesOrder,
      SpecialStockIdfgSalesOrderItem,
      -- CAST to get rid of conversion exit
      cast(SpecialStockIdfgWBSElement as nsdm_wbselement_internal_id preserving type) as SpecialStockIdfgWBSElement,
      SpecialStockIdfgCustomer,
      InventorySpecialStockType,
      InventoryStockType,
      SpecialStockIdfgStockOwner,
      cast(ResourceID as nsdm_resourcename preserving type)                           as ResourceID,

      // Warehouse stock grouping fields     

      CostEstimate,

      // Fields of material document     

      StorageLocation,
      Material,
      Batch,
      StockOwner,
      CompanyCode,
      InventorySpecialStockValnType,
      CompanyCodeCurrency,

      MaterialBaseUnit,
      EntryUnit,
      OrderQuantityUnit,
      IsReversalMovementType,
      InventoryTransactionType,
      ConsumptionPosting,
      GoodsReceiptType,

      // Stock Transfers

      IssuingOrReceivingPlant,
      IssuingOrReceivingStorageLoc,
      IssgOrRcvgMaterial,
      IssgOrRcvgBatch,
      IssgOrRcvgSpclStockInd,
      IssuingOrReceivingStockType,
      IssuingOrReceivingValType,

      cast(IssgOrRcvgResourceID as nsdm_transfer_resourcename preserving type)        as IssgOrRcvgResourceID,

      // Cancellation information

      GoodsMovementIsCancelled,
      ReversedMaterialDocument,
      ReversedMaterialDocumentItem,
      ReversedMaterialDocumentYear,

      // Periods & Times

      @Semantics.businessDate.at: true
      DocumentDate,

      AccountingDocumentType,
      CreationDate,
      CreationTime,

      PostingDate,

      @Semantics.fiscal.yearVariant: true
      FiscalYearVariant,

      cast(FiscalYear as fis_gjahr_no_conv preserving type)                                                as FiscalYear,

      @Semantics.fiscal.yearPeriod: true
      FiscalYearPeriod,

      YearDay,

      @Semantics.calendar.yearWeek: true
      YearWeek,

      @Semantics.calendar.yearMonth: true
      YearMonth,

      @Semantics.calendar.yearQuarter: true
      YearQuarter,

      @Semantics.calendar.quarter: true
      CalendarQuarter,

      @Semantics.calendar.month: true
      CalendarMonth,

      @Semantics.calendar.week: true
      CalendarWeek,

      @Semantics.calendar.dayOfYear: true
      // CalendarDay, GTN 2 digits but field 3 digits

      cast(CalendarDay as nsdm_day_of_year preserving type)                           as CalendarDayOfYear,

      WeekDay,

      // Reference Documents

      SalesOrder,
      SalesOrderItem,
      SalesOrderScheduleLine,
      PurchaseOrder,
      cast(PurchaseOrderItem as nsdm_ebelp preserving type)                           as PurchaseOrderItem,
      ProjectNetwork,
      DeliveryDocument,
      cast(DeliveryDocumentItem as nsdm_posnr_vl preserving type)                     as DeliveryDocumentItem,
      -- CAST to get rid of conversion exit
      cast(WBSElementInternalID as nsdm_wbselement preserving type)                   as WBSElementInternalID,
      ManufacturingOrder,
      ManufacturingOrderItem,

      ReferenceDocument,
      GoodsIssueOrReceiptSlipNumber,

      ReferenceDocumentFiscalYear,
      InvtryMgmtRefDocumentItem,
      InvtryMgmtReferenceDocument,

      // Other

      GoodsMovementType,
      InventoryValuationType,
      CreatedByUser,
      Supplier,
      Customer,

      @Semantics.booleanIndicator: true
      IsMaterialDocumentHeader,

      MaterialDocumentHeaderText,
      MaterialDocumentItemText,
      IsCompletelyDelivered,
      GoodsRecipientName,
      UnloadingPointName,
      GoodsMovementRefDocType,
      GoodsMovementReasonCode,
      ShelfLifeExpirationDate,
      ManufactureDate,
      SerialNumbersAreCreatedAutomly,
      VersionForPrintingSlip,

      @Semantics.booleanIndicator: true
      ManualPrintIsTriggered,

      // Accounting information

      AccountAssignmentCategory,
      CostCenter,
      ControllingArea, // required to fulfill requirement to expose the full key (for cost center association)

      CostObject,
      GLAccount,
      FunctionalArea,

      ProfitabilitySegment_2 as ProfitabilitySegment,
      ProfitCenter,
      MasterFixedAsset,
      FixedAsset,
      FundsCenter,
      Fund,
      CommitmentItemShortID,
      GrantID,

      // Reservation

      Reservation,
      ReservationItem,
      ReservationIsFinallyIssued,

      DebitCreditCode,

      // Amounts

      @Aggregation.default: #NONE
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TotalGoodsMvtAmtInCCCrcy,

      @Aggregation.default: #NONE
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      GoodsMovementStkAmtInCCCrcy,

      @Aggregation.default: #NONE
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      GoodsMvtCnsmpnAmtInCCCrcy,

      @Aggregation.default: #NONE
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      GdsMvtExtAmtInCoCodeCrcy,

      @Aggregation.default: #NONE
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      SlsPrcAmtInclVATInCoCodeCrcy,

      @Aggregation.default: #NONE
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      EnteredSlsAmtInCoCodeCrcy,

      // Quantities

      @Aggregation.default: #NONE
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      MatlStkChangeQtyInBaseUnit,

      @Aggregation.default: #NONE
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      MatlCnsmpnQtyInMatlBaseUnit,

      @Aggregation.default: #NONE
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      QuantityInBaseUnit,

      @Aggregation.default: #NONE
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      QuantityInEntryUnit,

      @Aggregation.default: #NONE
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      GoodsReceiptQtyInOrderUnit,

      @Consumption.hidden: true
      TransactionCode,

      @Consumption.hidden: true
      @Semantics.booleanIndicator: true
      IsAutomaticallyCreated,

      @Consumption.hidden: true
      MaterialDocumentLine,

      @Consumption.hidden: true
      MaterialDocumentParentLine,

      @Consumption.hidden: true
      HierarchyNodeLevel,

      _Supplier,
      _BPStockOwner,
      _Customer,
      _SupplierCompanyByPlant,
      _CustomerCompanyByPlant,
      _StorageLocation,
      _IssuingOrReceivingStorageLoc
}